Function Reference

_GUICtrlEdit_GetSel

Retrieves the starting and ending character positions of the current selection

#include <GuiEdit.au3>
_GUICtrlEdit_GetSel ( $hWnd )

Parameters

$hWnd Control ID/Handle to the control

Return Value

Returns an array in the following format:
    [0] - Starting position
    [1] - Ending position

Related

_GUICtrlEdit_ReplaceSel, _GUICtrlEdit_SetSel

Example

#include <GUIConstantsEx.au3>
#include <GuiEdit.au3>
#include <GuiStatusBar.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
        Local $sWow64 = ""
        If @AutoItX64 Then $sWow64 = "\Wow6432Node"
        Local $sFile = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE" & $sWow64 & "\AutoIt v3\AutoIt", "InstallDir") & "\include\_ReadMe_.txt"
        Local $aPartRightSide[3] = [190, 378, -1], $aSel

        ; Create GUI
        Local $hGUI = GUICreate("Edit Get/Set Sel (v" & @AutoItVersion & ")", 400, 300)
        Local $idEdit = GUICtrlCreateEdit("", 2, 2, 394, 268, BitOR($ES_WANTRETURN, $WS_VSCROLL))
        Local $hStatusBar = _GUICtrlStatusBar_Create($hGUI, $aPartRightSide)
        _GUICtrlStatusBar_SetIcon($hStatusBar, 2, 97, "shell32.dll")
        GUISetState(@SW_SHOW)

        ; Set Margins
        _GUICtrlEdit_SetMargins($idEdit, BitOR($EC_LEFTMARGIN, $EC_RIGHTMARGIN), 10, 10)

        ; Set Text
        _GUICtrlEdit_SetText($idEdit, FileRead($sFile))

        ; Set Sel
        _GUICtrlEdit_SetSel($idEdit, 15, 20)

        ; Get Sel
        $aSel = _GUICtrlEdit_GetSel($idEdit)
        _GUICtrlStatusBar_SetText($hStatusBar, "Start: " & $aSel[0])
        _GUICtrlStatusBar_SetText($hStatusBar, "End: " & $aSel[1], 1)

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
        GUIDelete()
EndFunc   ;==>Example