Jump to content



Photo

[SOLVED] GUICtrlCreateGroup

Started by andygo , Mar 05 2011 08:45 PM

  • Please log in to reply
8 replies to this topic

#1 andygo

andygo

    Prodigy

  • Active Members
  • PipPipPip
  • 194 posts

Posted 05 March 2011 - 08:45 PM

Hello,

i know how to set the Textcolor of a "GUICtrlCreateGroup". But is it also possible to set the color of the BorderLines?

Posted Image

Edited by andygo, 06 March 2011 - 01:34 PM.







#2 guinness

guinness

    guinness

  • MVPs
  • 11,066 posts

Posted 05 March 2011 - 09:40 PM

Creates a GUICtrlCreateGroup() with the ability to set the color.

Advanced GUICtrlCreateGroup() with shadows or continue for those interested in a simple GUICtrlCreateGroup() ...

Function:
AutoIt          
#include <StringSize.au3>

Func _GUICtrlCreateGroup($sText, $iLeft, $iTop, $iWidth, $iHeight, $bColor = 0x000000)
    Local $aLabel[6] = [5]
    Local $aStringSize = _StringSize($sText)

    $aLabel[1] = GUICtrlCreateLabel('', $iLeft + 1, $iTop + 1, 1, $iHeight) ; Left Line.
    $aLabel[2] = GUICtrlCreateLabel('', $iLeft + 1, $iTop + 1, 10, 1) ; Top Left Line.
    GUICtrlCreateLabel(' ' & $sText, $iLeft + 7, $iTop - 6, $aStringSize[2] - 3, 15)
    $aLabel[3] = GUICtrlCreateLabel('', $iLeft + $aStringSize[2] + 4, $iTop + 1, $iWidth - $aStringSize[2] - 3, 1) ; Top Right Line.
    $aLabel[4] = GUICtrlCreateLabel('', $iLeft + $iWidth + 1, $iTop + 1, 1, $iHeight) ; Right Line.
    $aLabel[5] = GUICtrlCreateLabel('', $iLeft + 1, $iTop + $iHeight + 1, $iWidth + 1, 1) ; Bottom Line.
    For $i = 1 To $aLabel[0]
        GUICtrlSetBkColor($aLabel[$i], $bColor)
    Next
EndFunc   ;==>_GUICtrlCreateGroup

Func _GUICtrlCreateGroupEx($sText, $iLeft, $iTop, $iWidth, $iHeight, $bColor = 0xC0C0C0, $OutlineColor = 0xFFFFFF)
    Local $aLabel[6] = [5], $aLabelInner[6] = [5]
    Local $aStringSize = _StringSize($sText)
    $aLabel[1] = GUICtrlCreateLabel('', $iLeft + 1, $iTop + 1, 1, $iHeight) ; Left Line.
    $aLabelInner[1] = GUICtrlCreateLabel('', $iLeft + 2, $iTop + 1, 1, $iHeight) ; Inner/Outer Left Line.
    $aLabel[2] = GUICtrlCreateLabel('', $iLeft + 1, $iTop + 1, 10, 1) ; Top Left Line.
    $aLabelInner[2] = GUICtrlCreateLabel('', $iLeft + 2, $iTop + 2, 10 - 1, 1) ; Top Inner/Outer Left Line.
    GUICtrlCreateLabel(' ' & $sText, $iLeft + 7, $iTop - 6, $aStringSize[2] - 3, 15)
    $aLabel[3] = GUICtrlCreateLabel('', $iLeft + $aStringSize[2] + 4, $iTop + 1, $iWidth - $aStringSize[2] - 3, 1) ; Top Right Line.
    $aLabelInner[3] = GUICtrlCreateLabel('', $iLeft + $aStringSize[2] + 4, $iTop + 2, $iWidth - $aStringSize[2] - 3, 1) ; Top Inner/Outer Right Line.
    $aLabel[4] = GUICtrlCreateLabel('', $iLeft + $iWidth + 1, $iTop + 1, 1, $iHeight) ; Right Line.
    $aLabelInner[4] = GUICtrlCreateLabel('', $iLeft + $iWidth + 2, $iTop + 1, 1, $iHeight + 1) ; Right Inner/Outer Line.
    $aLabel[5] = GUICtrlCreateLabel('', $iLeft + 1, $iTop + $iHeight + 1, $iWidth + 1, 1) ; Bottom Line.
    $aLabelInner[5] = GUICtrlCreateLabel('', $iLeft + 1, $iTop + $iHeight + 2, $iWidth + 2, 1) ; Bottom Inner/Outer Line.
    For $i = 1 To $aLabel[0]
        GUICtrlSetBkColor($aLabel[$i], $bColor)
        GUICtrlSetBkColor($aLabelInner[$i], $OutlineColor)
    Next
EndFunc   ;==>_GUICtrlCreateGroupEx

Example use of Function:
AutoIt          
#include <GUIConstantsEx.au3>
#include <StringSize.au3>

Example()

Func Example()
    Local $hGUI = GUICreate('_GUICtrlCreateGroup()')
    _GUICtrlCreateGroupEx('Group 1', 10, 10, 200, 140) ; Default Colors.
    GUICtrlCreateRadio('Radio 1', 15, 25, 60, 20)
    GUICtrlCreateRadio('Radio 2', 15, 45, 60, 20)

    _GUICtrlCreateGroupEx('Group 2', 10, 160, 230, 100, 0x48036F, 0xAD66D5)
    GUICtrlCreateRadio('Radio 3', 15, 175, 60, 20)
    GUICtrlCreateRadio('Radio 4', 15, 195, 60, 20)

    _GUICtrlCreateGroup('Group 3', 10, 275, 100, 50, 0xA64A00)
    GUICtrlCreateRadio('Radio 5', 15, 290, 60, 20)

    GUISetState(@SW_SHOW, $hGUI)

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop

        EndSwitch
    WEnd
    GUIDelete($hGUI)
EndFunc   ;==>Example

Edited by guinness, 08 October 2012 - 01:16 PM.

Example List: _AdapterConnections() • _AlwaysRun() • _AppMon() • _AppMonEx() • _BinaryBin() • _CheckMsgBox() • _CmdLineRaw() • _ContextMenu() • _DesktopDimensions() • _DisplayPassword() • _Fibonacci() • _FileCompare() • _FileCompareContents() • _FileNameByHandle() • _FilePrefix/SRE() • _FindInFile() • _GetBackgroundColor()/_SetBackgroundColor() • _GetConrolID() • _GetCtrlClass() • _GetDirectoryFormat() • _GetDriveMediaType() • _GetFilename()/_GetFilenameExt() • _GetHardwareID() • _GetIP() • _GetIP_Country() • _GetOSLanguage() • _GetSavedSource • _GetStringSize() • _GetSystemPaths() • _GetURLImage() • _GIFImage() • _GoogleWeather() • _GUICtrlCreateGroup() • _GUICtrlListBox_CreateArray() • _GUICtrlListView_CreateArray() • _GUICtrlListView_SaveCSV() • _GUICtrlListView_SaveHTML() • _GUICtrlListView_SaveTxt() • _GUICtrlListView_SaveXML() • _GUICtrlMenu_Recent() • _GUICtrlMenu_SetItemImage() • _GUICtrlTreeView_CreateArray() • _GUIDisable() • _GUIImageList_SetIconFromHandle() • _GUISetIcon() • _Icon_Clear()/_Icon_Set() • _InetGet() • _InetGetGUI() • _InetGetProgress() • _IPDetails() • _IsFileOlder() • _IsGUID() • _IsHex() • _IsPalindrome() • _IsRegKey() • _IsStringRegExp() • _IsUPX() • _IsValidType() • _IsWebColor() • _Language() • _Log() • _MicrosoftInternetConnectivity() • _MSDNDataType() • _PathFull/GetRelative/Split() • _PathSplitEx() • _PrintFromArray() • _ProgressSetMarquee() • _ReDim() • _RockPaperScissors()/_RockPaperScissorsLizardSpock() • _ScrollingCredits • _SelfDelete() • _SelfRename() • _SelfUpdate() • _SendTo() • _ShellAll() • _ShellFile() • _ShellFolder() • _SingletonHWID() • _SingletonPID() • _Startup() • _StringIsValid() • _StringReplaceWholeWord() • _StringStripChar() • _Temperature() • _TrialPeriod() • _UKToUSDate()/_USToUKDate() • _WinAPI_CreateGUID() • _WMIDateStringToDate()/_DateToWMIDateString() • AutoIt Search • AutoIt3 Portable • AutoItWinGetTitle()/AutoItWinSetTitle() • Coding • FileInstallr • GeoIP database • GUI - Only Close Button • GUI Examples • GUICtrlDeleteImage() • GUICtrlGetBkColor() • GUICtrlGetStyle() • GUIGetBkColor() • LockFile() • PasteBin • SciTE Jump • Signature Creator • WM_COPYDATA • More Examples...Updated: 11/04/2013

#3 andygo

andygo

    Prodigy

  • Active Members
  • PipPipPip
  • 194 posts

Posted 06 March 2011 - 11:16 AM

hello,

thanks for the reply. i had a similar idea. will test a bit around. maybe it is combinable with "_GDIPlus_GraphicsMeasureString" to get the
text-string length and create flexible top-left and top-right lines.

regards, andy

#4 Melba23

Melba23

    Yes, me!

  • Moderators
  • 15,758 posts

Posted 06 March 2011 - 12:07 PM

andygo,

If you want to measure the size of text strings, look at the StringSize UDF in my sig. :)

M23
StringSize - Automatically size controls to fit text                                                               ExtMsgBox - A user customisable replacement for MsgBox
Toast - Small GUIs which pop out of the Systray                                                                Marquee - Scrolling tickertape GUIs
Scrollbars - Automatically sized scrollbars with a single command                                   GUIFrame - Subdivide GUIs into many adjustable frames
GUIExtender - Extend and retract multiple sections within a GUI                                      NoFocusLines - Remove the dotted focus lines from buttons, sliders, radios and checkboxes
ChooseFileFolder - Single and multiple selections from specified path tree structure      Notify - Small notifications on the edge of the display
RecFileListToArray- An alternative to _FileListToArray with user-defined include/exclude masks, maximum recursion level, sorting and displayed path options
GUIListViewEx - Insert, delete, move, drag and sort ListView items

#5 andygo

andygo

    Prodigy

  • Active Members
  • PipPipPip
  • 194 posts

Posted 06 March 2011 - 01:32 PM

andygo,

If you want to measure the size of text strings, look at the StringSize UDF in my sig. :)

M23

hello, perfect combination. this is exactly what i want! :)

Posted Image


Plain Text          
#include <GUIConstantsEx.au3>
#include "StringSize.au3"

$sText = "Grouptext flexi color length"
$hGUI = GUICreate("Test", 300, 200)
$aSize = _StringSize($sText)
_GUICtrlCreateGroup($stext, 10, 10, 200, 140)

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

Func _GUICtrlCreateGroup($sText, $iLeft, $iTop, $iWidth, $iHeight, $bColor = 0xff0000)
    Local $aLabel[6] = [5]
    $aLabel[1] = GUICtrlCreateLabel("", $iLeft + 1, $iTop + 1, 1, $iHeight) ; Left Line.
    $aLabel[2] = GUICtrlCreateLabel("", $iLeft + 1, $iTop + 1, 7, 1) ; Top Left Line.
    GUICtrlCreateLabel(" "&$sText, $iLeft + 7, $iTop - 6, $aSize[2]-3, 15);$aSize[3])
    GUICtrlSetColor(-1, 0x0000ff); optional text color
    GUICtrlSetbkColor(-1, 0xffff00); optional text bg color
    $aLabel[3] = GUICtrlCreateLabel("", $iLeft + $aSize[2]+4, $iTop + 1, $iWidth-$aSize[2]-4, 1) ; Top Right Line.
    $aLabel[4] = GUICtrlCreateLabel("", $iLeft + $iWidth, $iTop + 1, 1, $iHeight) ; Right Line.
    $aLabel[5] = GUICtrlCreateLabel("", $iLeft + 1, $iTop + $iHeight + 1, $iWidth, 1) ; Bottom Line.
    For $i = 1 To $aLabel[0]
        GUICtrlSetBkColor($aLabel[$i], $bColor)
    Next
EndFunc   ;==>_GUICtrlCreateGroup

Edited by andygo, 06 March 2011 - 01:33 PM.

#6 guinness

guinness

    guinness

  • MVPs
  • 11,066 posts

Posted 06 March 2011 - 02:23 PM

That was my plan today, :) add StringSize.au3 by Melba23, but andygo you beat me to it. Thanks Melba for suggesting too.

Example List: _AdapterConnections() • _AlwaysRun() • _AppMon() • _AppMonEx() • _BinaryBin() • _CheckMsgBox() • _CmdLineRaw() • _ContextMenu() • _DesktopDimensions() • _DisplayPassword() • _Fibonacci() • _FileCompare() • _FileCompareContents() • _FileNameByHandle() • _FilePrefix/SRE() • _FindInFile() • _GetBackgroundColor()/_SetBackgroundColor() • _GetConrolID() • _GetCtrlClass() • _GetDirectoryFormat() • _GetDriveMediaType() • _GetFilename()/_GetFilenameExt() • _GetHardwareID() • _GetIP() • _GetIP_Country() • _GetOSLanguage() • _GetSavedSource • _GetStringSize() • _GetSystemPaths() • _GetURLImage() • _GIFImage() • _GoogleWeather() • _GUICtrlCreateGroup() • _GUICtrlListBox_CreateArray() • _GUICtrlListView_CreateArray() • _GUICtrlListView_SaveCSV() • _GUICtrlListView_SaveHTML() • _GUICtrlListView_SaveTxt() • _GUICtrlListView_SaveXML() • _GUICtrlMenu_Recent() • _GUICtrlMenu_SetItemImage() • _GUICtrlTreeView_CreateArray() • _GUIDisable() • _GUIImageList_SetIconFromHandle() • _GUISetIcon() • _Icon_Clear()/_Icon_Set() • _InetGet() • _InetGetGUI() • _InetGetProgress() • _IPDetails() • _IsFileOlder() • _IsGUID() • _IsHex() • _IsPalindrome() • _IsRegKey() • _IsStringRegExp() • _IsUPX() • _IsValidType() • _IsWebColor() • _Language() • _Log() • _MicrosoftInternetConnectivity() • _MSDNDataType() • _PathFull/GetRelative/Split() • _PathSplitEx() • _PrintFromArray() • _ProgressSetMarquee() • _ReDim() • _RockPaperScissors()/_RockPaperScissorsLizardSpock() • _ScrollingCredits • _SelfDelete() • _SelfRename() • _SelfUpdate() • _SendTo() • _ShellAll() • _ShellFile() • _ShellFolder() • _SingletonHWID() • _SingletonPID() • _Startup() • _StringIsValid() • _StringReplaceWholeWord() • _StringStripChar() • _Temperature() • _TrialPeriod() • _UKToUSDate()/_USToUKDate() • _WinAPI_CreateGUID() • _WMIDateStringToDate()/_DateToWMIDateString() • AutoIt Search • AutoIt3 Portable • AutoItWinGetTitle()/AutoItWinSetTitle() • Coding • FileInstallr • GeoIP database • GUI - Only Close Button • GUI Examples • GUICtrlDeleteImage() • GUICtrlGetBkColor() • GUICtrlGetStyle() • GUIGetBkColor() • LockFile() • PasteBin • SciTE Jump • Signature Creator • WM_COPYDATA • More Examples...Updated: 11/04/2013

#7 andygo

andygo

    Prodigy

  • Active Members
  • PipPipPip
  • 194 posts

Posted 06 March 2011 - 02:51 PM

That was my plan today, :) add StringSize.au3 by Melba23, but andygo you beat me to it. Thanks Melba for suggesting too.



you anyway could do another modification to your function :) if you take a look to a zoomed "original" guictrlcreategroup,
you will see the main-line and a second white line (on normalsize maybe this is for a shadowlook).

Posted Image

#8 guinness

guinness

    guinness

  • MVPs
  • 11,066 posts

Posted 06 March 2011 - 04:01 PM

Function:
AutoIt          
#include <StringSize.au3>

Func _GUICtrlCreateGroup($sText, $iLeft, $iTop, $iWidth, $iHeight, $bColor = 0x000000)
    Local $aLabel[6] = [5]
    Local $aStringSize = _StringSize($sText)

    $aLabel[1] = GUICtrlCreateLabel('', $iLeft + 1, $iTop + 1, 1, $iHeight) ; Left Line.
    $aLabel[2] = GUICtrlCreateLabel('', $iLeft + 1, $iTop + 1, 10, 1) ; Top Left Line.
    GUICtrlCreateLabel(' ' & $sText, $iLeft + 7, $iTop - 6, $aStringSize[2] - 3, 15)
    $aLabel[3] = GUICtrlCreateLabel('', $iLeft + $aStringSize[2] + 4, $iTop + 1, $iWidth - $aStringSize[2] - 3, 1) ; Top Right Line.
    $aLabel[4] = GUICtrlCreateLabel('', $iLeft + $iWidth + 1, $iTop + 1, 1, $iHeight) ; Right Line.
    $aLabel[5] = GUICtrlCreateLabel('', $iLeft + 1, $iTop + $iHeight + 1, $iWidth + 1, 1) ; Bottom Line.
    For $i = 1 To $aLabel[0]
        GUICtrlSetBkColor($aLabel[$i], $bColor)
    Next
EndFunc   ;==>_GUICtrlCreateGroup

Func _GUICtrlCreateGroupEx($sText, $iLeft, $iTop, $iWidth, $iHeight, $bColor = 0xC0C0C0, $OutlineColor = 0xFFFFFF)
    Local $aLabel[6] = [5], $aLabelInner[6] = [5]
    Local $aStringSize = _StringSize($sText)
    $aLabel[1] = GUICtrlCreateLabel('', $iLeft + 1, $iTop + 1, 1, $iHeight) ; Left Line.
    $aLabelInner[1] = GUICtrlCreateLabel('', $iLeft + 2, $iTop + 1, 1, $iHeight) ; Inner/Outer Left Line.
    $aLabel[2] = GUICtrlCreateLabel('', $iLeft + 1, $iTop + 1, 10, 1) ; Top Left Line.
    $aLabelInner[2] = GUICtrlCreateLabel('', $iLeft + 2, $iTop + 2, 10 - 1, 1) ; Top Inner/Outer Left Line.
    GUICtrlCreateLabel(' ' & $sText, $iLeft + 7, $iTop - 6, $aStringSize[2] - 3, 15)
    $aLabel[3] = GUICtrlCreateLabel('', $iLeft + $aStringSize[2] + 4, $iTop + 1, $iWidth - $aStringSize[2] - 3, 1) ; Top Right Line.
    $aLabelInner[3] = GUICtrlCreateLabel('', $iLeft + $aStringSize[2] + 4, $iTop + 2, $iWidth - $aStringSize[2] - 3, 1) ; Top Inner/Outer Right Line.
    $aLabel[4] = GUICtrlCreateLabel('', $iLeft + $iWidth + 1, $iTop + 1, 1, $iHeight) ; Right Line.
    $aLabelInner[4] = GUICtrlCreateLabel('', $iLeft + $iWidth + 2, $iTop + 1, 1, $iHeight + 1) ; Right Inner/Outer Line.
    $aLabel[5] = GUICtrlCreateLabel('', $iLeft + 1, $iTop + $iHeight + 1, $iWidth + 1, 1) ; Bottom Line.
    $aLabelInner[5] = GUICtrlCreateLabel('', $iLeft + 1, $iTop + $iHeight + 2, $iWidth + 2, 1) ; Bottom Inner/Outer Line.
    For $i = 1 To $aLabel[0]
        GUICtrlSetBkColor($aLabel[$i], $bColor)
        GUICtrlSetBkColor($aLabelInner[$i], $OutlineColor)
    Next
EndFunc   ;==>_GUICtrlCreateGroupEx

Example use of Function:
AutoIt          
#include <GUIConstantsEx.au3>
#include <StringSize.au3>

Example()

Func Example()
    Local $hGUI = GUICreate('_GUICtrlCreateGroup()')
    _GUICtrlCreateGroupEx('Group 1', 10, 10, 200, 140) ; Default Colors.
    GUICtrlCreateRadio('Radio 1', 15, 25, 60, 20)
    GUICtrlCreateRadio('Radio 2', 15, 45, 60, 20)

    _GUICtrlCreateGroupEx('Group 2', 10, 160, 230, 100, 0x48036F, 0xAD66D5)
    GUICtrlCreateRadio('Radio 3', 15, 175, 60, 20)
    GUICtrlCreateRadio('Radio 4', 15, 195, 60, 20)

    _GUICtrlCreateGroup('Group 3', 10, 275, 100, 50, 0xA64A00)
    GUICtrlCreateRadio('Radio 5', 15, 290, 60, 20)

    GUISetState(@SW_SHOW, $hGUI)

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop

        EndSwitch
    WEnd
    GUIDelete($hGUI)
EndFunc   ;==>Example

Edited by guinness, 08 October 2012 - 01:17 PM.

Example List: _AdapterConnections() • _AlwaysRun() • _AppMon() • _AppMonEx() • _BinaryBin() • _CheckMsgBox() • _CmdLineRaw() • _ContextMenu() • _DesktopDimensions() • _DisplayPassword() • _Fibonacci() • _FileCompare() • _FileCompareContents() • _FileNameByHandle() • _FilePrefix/SRE() • _FindInFile() • _GetBackgroundColor()/_SetBackgroundColor() • _GetConrolID() • _GetCtrlClass() • _GetDirectoryFormat() • _GetDriveMediaType() • _GetFilename()/_GetFilenameExt() • _GetHardwareID() • _GetIP() • _GetIP_Country() • _GetOSLanguage() • _GetSavedSource • _GetStringSize() • _GetSystemPaths() • _GetURLImage() • _GIFImage() • _GoogleWeather() • _GUICtrlCreateGroup() • _GUICtrlListBox_CreateArray() • _GUICtrlListView_CreateArray() • _GUICtrlListView_SaveCSV() • _GUICtrlListView_SaveHTML() • _GUICtrlListView_SaveTxt() • _GUICtrlListView_SaveXML() • _GUICtrlMenu_Recent() • _GUICtrlMenu_SetItemImage() • _GUICtrlTreeView_CreateArray() • _GUIDisable() • _GUIImageList_SetIconFromHandle() • _GUISetIcon() • _Icon_Clear()/_Icon_Set() • _InetGet() • _InetGetGUI() • _InetGetProgress() • _IPDetails() • _IsFileOlder() • _IsGUID() • _IsHex() • _IsPalindrome() • _IsRegKey() • _IsStringRegExp() • _IsUPX() • _IsValidType() • _IsWebColor() • _Language() • _Log() • _MicrosoftInternetConnectivity() • _MSDNDataType() • _PathFull/GetRelative/Split() • _PathSplitEx() • _PrintFromArray() • _ProgressSetMarquee() • _ReDim() • _RockPaperScissors()/_RockPaperScissorsLizardSpock() • _ScrollingCredits • _SelfDelete() • _SelfRename() • _SelfUpdate() • _SendTo() • _ShellAll() • _ShellFile() • _ShellFolder() • _SingletonHWID() • _SingletonPID() • _Startup() • _StringIsValid() • _StringReplaceWholeWord() • _StringStripChar() • _Temperature() • _TrialPeriod() • _UKToUSDate()/_USToUKDate() • _WinAPI_CreateGUID() • _WMIDateStringToDate()/_DateToWMIDateString() • AutoIt Search • AutoIt3 Portable • AutoItWinGetTitle()/AutoItWinSetTitle() • Coding • FileInstallr • GeoIP database • GUI - Only Close Button • GUI Examples • GUICtrlDeleteImage() • GUICtrlGetBkColor() • GUICtrlGetStyle() • GUIGetBkColor() • LockFile() • PasteBin • SciTE Jump • Signature Creator • WM_COPYDATA • More Examples...Updated: 11/04/2013

#9 andygo

andygo

    Prodigy

  • Active Members
  • PipPipPip
  • 194 posts

Posted 06 March 2011 - 04:40 PM

Something like this? >>

AutoIt          
#include <StringSize.au3>

_Main()

Func _Main()
    GUICreate("_GUICtrlCreateGroup()")
    _GUICtrlCreateGroup("Group 1", 10, 10, 200, 140) ; Default Colors.
    GUICtrlCreateRadio("Radio 1", 15, 25, 60, 20)
    GUICtrlCreateRadio("Radio 2", 15, 45, 60, 20)

    _GUICtrlCreateGroup("Group 2", 10, 160, 230, 100, 0x48036F, 0xAD66D5)
    GUICtrlCreateRadio("Radio 3", 15, 175, 60, 20)
    GUICtrlCreateRadio("Radio 4", 15, 195, 60, 20)

    _GUICtrlCreateGroup("Group 3", 10, 275, 100, 50, 0xA64A00, 0xFFB173)
    GUICtrlCreateRadio("Radio 5", 15, 290, 60, 20)

    GUISetState(@SW_SHOW)

    While 1
        Switch GUIGetMsg()
            Case -3
                Exit
        EndSwitch
    WEnd
EndFunc   ;==>_Main

Func _GUICtrlCreateGroup($sText, $iLeft, $iTop, $iWidth, $iHeight, $bColor = 0xC0C0C0, $OutlineColor = 0xFFFFFF)
    Local $aLabel[6] = [5], $aLabelInner[6] = [5]
    Local $aStringSize = _StringSize($sText)
    $aLabel[1] = GUICtrlCreateLabel("", $iLeft + 1, $iTop + 1, 1, $iHeight) ; Left Line.
    $aLabelInner[1] = GUICtrlCreateLabel("", $iLeft + 2, $iTop + 1, 1, $iHeight) ; Inner/Outer Left Line.
    $aLabel[2] = GUICtrlCreateLabel("", $iLeft + 1, $iTop + 1, 10, 1) ; Top Left Line.
    $aLabelInner[2] = GUICtrlCreateLabel("", $iLeft + 2, $iTop + 2, 10 - 1, 1) ; Top Inner/Outer Left Line.
    GUICtrlCreateLabel(" " & $sText, $iLeft + 7, $iTop - 6, $aStringSize[2] - 3, 15)
    $aLabel[3] = GUICtrlCreateLabel("", $iLeft + $aStringSize[2] + 4, $iTop + 1, $iWidth - $aStringSize[2] - 3, 1) ; Top Right Line.
    $aLabelInner[3] = GUICtrlCreateLabel("", $iLeft + $aStringSize[2] + 4, $iTop + 2, $iWidth - $aStringSize[2] - 3, 1) ; Top Inner/Outer Right Line.
    $aLabel[4] = GUICtrlCreateLabel("", $iLeft + $iWidth + 1, $iTop + 1, 1, $iHeight) ; Right Line.
    $aLabelInner[4] = GUICtrlCreateLabel("", $iLeft + $iWidth + 2, $iTop + 1, 1, $iHeight + 1) ; Right Inner/Outer Line.
    $aLabel[5] = GUICtrlCreateLabel("", $iLeft + 1, $iTop + $iHeight + 1, $iWidth + 1, 1) ; Bottom Line.
    $aLabelInner[5] = GUICtrlCreateLabel("", $iLeft + 1, $iTop + $iHeight + 2, $iWidth + 2, 1) ; Bottom Inner/Outer Line.
    For $i = 1 To $aLabel[0]
        GUICtrlSetBkColor($aLabel[$i], $bColor)
        GUICtrlSetBkColor($aLabelInner[$i], $OutlineColor)
    Next
EndFunc   ;==>_GUICtrlCreateGroup

That's it, here we go :)
Back to Graphical User Interface (GUI) Help and Support


0 user(s) are reading this topic

0 members, 0 guests, 0 anonymous users




  1. AutoIt Forums
  2. → AutoIt v3
  3. → Graphical User Interface (GUI) Help and Support
  4. Privacy and Cookie Policy
  5. Forum Rules ·