Javascript Disabled Detected

You currently have javascript disabled. Several functions may not work. Please re-enable javascript to access full functionality.

_GUICtrlListView_SaveXML() - Exports the details of a ListView to a .xml file.

Started by guinness , Jun 06 2011 03:55 PM

Please log in to reply

10 replies to this topic

#1 guinness

guinness

MVPs
10,439 posts

Posted 06 June 2011 - 03:55 PM

For those who enjoy using ListViews and wish to export the data to a XML file, then this Function is for you.

Thanks to Mat for the optimised XML format.

This is an Example of the output for a ListView with 2 rows and 2 columns.

<?xml version="1.0" encoding="UTF-8" ?>
<listview rows="2" cols="2">
    <item>
        <column01>Row 1: Col 1</column01>
        <column02>Row 1: Col 2</column02>
    </item>
    <item>
        <column01>Row 2: Col 1</column01>
        <column02>Row 2: Col 2</column02>
    </item>
</listview>

Function without Array:

AutoIt

; #AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
; #FUNCTION# =========================================================================================================
; Name...........: _GUICtrlListView_SaveXML()
; Description ...: Exports the details of a ListView to a .xml file.
; Syntax.........: _GUICtrlListView_SaveXML($hListView, $sFile, [$iDetails = 1])
; Parameters ....: $hListView - Handle of the ListView.
;                  $sFile - FilePath, this should ideally use the filetype .xml e.g. @ScriptDir & "\Example.xml"
;                  $iDetails - [Optional] - Print the number of columns & rows. [Default = 1 - Print the number of columns & rows.]
; Requirement(s).: v3.2.12.1 or higher
; Return values .: Success - Returns filepath.
;                  Failure - Returns filepath & sets @error = 1
; Author ........: guinness
; Example........; Yes
;=====================================================================================================================
Func _GUICtrlListView_SaveXML($hListView, $sFile, $iDetails = 1)
    Local $aColumnsText, $hFileOpen, $iError = 0, $sDetails = "", $sItem, $sXMLBody, $sXMLColumns, $sXMLHeader
    Local $iColumnCount = _GUICtrlListView_GetColumnCount($hListView)
    Local $iItemCount = _GUICtrlListView_GetItemCount($hListView)
    Local $aColumns[$iColumnCount]
 
    If $iDetails Then
        $sDetails = ' rows="' & $iItemCount & '" cols="' & $iColumnCount & '"'
    EndIf
    $sXMLHeader = '<?xml version="1.0" encoding="UTF-8" ?>' & @CRLF & '<listview' & $sDetails & '>' & @CRLF
 
    For $A = 0 To $iColumnCount - 1 ; ListView Columns
        $aColumnsText = _GUICtrlListView_GetColumn($hListView, $A)
        $aColumns[$A] = StringStripWS(StringLower($aColumnsText[5]), 8)
    Next
 
    For $A = 0 To $iItemCount - 1 ; ListView Items.
        $sXMLBody &= @TAB & '<item>' & @CRLF
        For $B = 0 To $iColumnCount - 1
            $sItem = _GUICtrlListView_GetItemText($hListView, $A, $B)
            $sXMLBody &= @TAB & @TAB & '<' & $aColumns[$B] & '>' & $sItem & '</' & $aColumns[$B] & '>' & @CRLF
        Next
        $sXMLBody &= @TAB & '</item>' & @CRLF
    Next
    $sXMLBody &= '</listview>' & @CRLF
 
    $hFileOpen = FileOpen($sFile, 2)
    FileWrite($hFileOpen, $sXMLHeader & $sXMLColumns & $sXMLBody)
    FileClose($hFileOpen)
    If @error Then
        $iError = 1
    EndIf
    Return SetError($iError, 0, $sFile)
EndFunc   ;==>_GUICtrlListView_SaveXML

Function with Array: - It uses another Function of mine called _GUICtrlListView_CreateArray()

AutoIt

; #AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
; #FUNCTION# =========================================================================================================
; Name...........: _GUICtrlListView_SaveXML()
; Description ...: Exports the details of a ListView to a .xml file.
; Syntax.........: _GUICtrlListView_SaveXML($aArray, $sFile, [$iDetails = 1])
; Parameters ....: $aArray - Array returned from _GUICtrlListView_CreateArray()
;                  $sFile - FilePath, this should ideally use the filetype .xml e.g. @ScriptDir & "\Example.xml"
;                  $iDetails - [Optional] - Print the number of columns & rows. [Default = 1 - Print the number of columns & rows.]
; Requirement(s).: v3.2.12.1 or higher
; Return values .: Success - Returns filepath.
;                  Failure - Returns filepath & sets @error = 1
; Author ........: guinness
; Example........; Yes
;=====================================================================================================================
Func _GUICtrlListView_SaveXML($aArray, $sFile, $iDetails = 1)
    Local $aColumns, $hFileOpen, $iError = 0, $sDetails = "", $sItem, $sXMLBody, $sXMLColumns, $sXMLHeader
 
    If $iDetails Then
        $sDetails = ' rows="' & $aArray[0][0] & '" cols="' & $aArray[0][1] & '"'
    EndIf
    $sXMLHeader = '<?xml version="1.0" encoding="UTF-8" ?>' & @CRLF & '<listview' & $sDetails & '>' & @CRLF
 
    $aColumns = StringSplit($aArray[0][2], "|") ; ListView Columns
    For $A = 1 To $aColumns[0]
        $aColumns[$A] = StringStripWS(StringLower($aColumns[$A]), 8)
    Next
 
    For $A = 1 To $aArray[0][0] ; ListView Items.
        $sXMLBody &= @TAB & '<item>' & @CRLF
        For $B = 0 To $aArray[0][1] - 1
            $sItem = $aArray[$A][$B]
            $sXMLBody &= @TAB & @TAB & '<' & $aColumns[$B + 1] & '>' & $sItem & '</' & $aColumns[$B + 1] & '>' & @CRLF
        Next
        $sXMLBody &= @TAB & '</item>' & @CRLF
    Next
    $sXMLBody &= '</listview>' & @CRLF
 
    $hFileOpen = FileOpen($sFile, 2)
    FileWrite($hFileOpen, $sXMLHeader & $sXMLColumns & $sXMLBody)
    FileClose($hFileOpen)
    If @error Then
        $iError = 1
    EndIf
    Return SetError($iError, 0, $sFile)
EndFunc   ;==>_GUICtrlListView_SaveXML

Example use of Function without Array:

AutoIt

#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GUIConstantsEx.au3>
#include <GUIListView.au3>
#include <WindowsConstants.au3>
 
_Main()
 
Func _Main()
    Local $hListView, $iButton, $iListView, $sPrintOut
    GUICreate("_GUICtrlListView_SaveXML()", 400, 300, -1, -1, BitOR($GUI_SS_DEFAULT_GUI, $WS_MAXIMIZEBOX, $WS_SIZEBOX))
    $iListView = GUICtrlCreateListView("", 0, 0, 400, 270)
    $hListView = GUICtrlGetHandle($iListView)
    GUICtrlSetResizing(-1, $GUI_DOCKBORDERS)
 
    $iButton = GUICtrlCreateButton("Export XML", 400 - 80, 275, 75, 22.5)
    GUICtrlSetResizing(-1, $GUI_DOCKRIGHT + $GUI_DOCKSIZE + $GUI_DOCKBOTTOM)
 
    GUISetState(@SW_SHOW)
 
    __ListViewFill($hListView, Random(1, 5, 1), Random(25, 100, 1)) ; Fill the ListView with Random data.
 
    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                Exit
 
            Case $iButton
                $sPrintOut = _GUICtrlListView_SaveXML($hListView, @ScriptDir & "\Export.xml")
                ShellExecute($sPrintOut)
 
        EndSwitch
    WEnd
EndFunc   ;==>_Main
 
; #AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
; #FUNCTION# =========================================================================================================
; Name...........: _GUICtrlListView_SaveXML()
; Description ...: Exports the details of a ListView to a .xml file.
; Syntax.........: _GUICtrlListView_SaveXML($hListView, $sFile, [$iDetails = 1])
; Parameters ....: $hListView - Handle of the ListView.
;                  $sFile - FilePath, this should ideally use the filetype .xml e.g. @ScriptDir & "\Example.xml"
;                  $iDetails - [Optional] - Print the number of columns & rows. [Default = 1 - Print the number of columns & rows.]
; Requirement(s).: v3.2.12.1 or higher
; Return values .: Success - Returns filepath.
;                  Failure - Returns filepath & sets @error = 1
; Author ........: guinness
; Example........; Yes
;=====================================================================================================================
Func _GUICtrlListView_SaveXML($hListView, $sFile, $iDetails = 1)
    Local $aColumnsText, $hFileOpen, $iError = 0, $sDetails = "", $sItem, $sXMLBody, $sXMLColumns, $sXMLHeader
    Local $iColumnCount = _GUICtrlListView_GetColumnCount($hListView)
    Local $iItemCount = _GUICtrlListView_GetItemCount($hListView)
    Local $aColumns[$iColumnCount]
 
    If $iDetails Then
        $sDetails = ' rows="' & $iItemCount & '" cols="' & $iColumnCount & '"'
    EndIf
    $sXMLHeader = '<?xml version="1.0" encoding="UTF-8" ?>' & @CRLF & '<listview' & $sDetails & '>' & @CRLF
 
    For $A = 0 To $iColumnCount - 1 ; ListView Columns
        $aColumnsText = _GUICtrlListView_GetColumn($hListView, $A)
        $aColumns[$A] = StringStripWS(StringLower($aColumnsText[5]), 8)
    Next
 
    For $A = 0 To $iItemCount - 1 ; ListView Items.
        $sXMLBody &= @TAB & '<item>' & @CRLF
        For $B = 0 To $iColumnCount - 1
            $sItem = _GUICtrlListView_GetItemText($hListView, $A, $B)
            $sXMLBody &= @TAB & @TAB & '<' & $aColumns[$B] & '>' & $sItem & '</' & $aColumns[$B] & '>' & @CRLF
        Next
        $sXMLBody &= @TAB & '</item>' & @CRLF
    Next
    $sXMLBody &= '</listview>' & @CRLF
 
    $hFileOpen = FileOpen($sFile, 2)
    FileWrite($hFileOpen, $sXMLHeader & $sXMLColumns & $sXMLBody)
    FileClose($hFileOpen)
    If @error Then
        $iError = 1
    EndIf
    Return SetError($iError, 0, $sFile)
EndFunc   ;==>_GUICtrlListView_SaveXML
 
Func __ListViewFill($hListView, $iColumns, $iRows) ; Required only for _Main(), but not the UDF!
    For $A = 0 To $iColumns - 1
        _GUICtrlListView_InsertColumn($hListView, $A, "Column " & $A + 1, 50)
        _GUICtrlListView_SetColumnWidth($hListView, $A - 1, -2)
    Next
    For $A = 0 To $iRows - 1
        _GUICtrlListView_AddItem($hListView, Chr(Random(65, 90, 1)) & " - Row " & $A + 1 & ": Col 1", $A)
        For $B = 1 To $iColumns
            _GUICtrlListView_AddSubItem($hListView, $A, "Row " & $A + 1 & ": Col " & $B + 1, $B)
        Next
    Next
EndFunc   ;==>__ListViewFill

Download the ZIP file to obtain all exporting Examples.

ListView Export.zip 19.96K 747 downloads

Other Examples for exporting ListView data are: _GUICtrlListView_SaveCSV(), _GUICtrlListView_SaveHTML() & _GUICtrlListView_SaveTxt()

Edited by guinness, 30 August 2011 - 05:46 AM.

Mongoose likes this

Example List: _AdapterConnections() • _AlwaysRun() • _AppMon() • _AppMonEx() • _BinaryBin() • _CheckMsgBox() • _CmdLineRaw() • _ContextMenu() • _DesktopDimensions() • _DisplayPassword() • _Fibonacci() • _FileCompare() • _FileCompareContents() • _FileNameByHandle() • _FilePrefix/SRE() • _FindInFile() • _GetBackgroundColor()/_SetBackgroundColor() • _GetConrolID() • _GetCtrlClass() • _GetDirectoryFormat() • _GetDriveMediaType() • _GetFilename()/_GetFilenameExt() • _GetHardwareID() • _GetIP() • _GetIP_Country() • _GetOSLanguage() • _GetSavedSource • _GetStringSize() • _GetSystemPaths() • _GetURLImage() • _GIFImage() • _GoogleWeather() • _GUICtrlCreateGroup() • _GUICtrlListBox_CreateArray() • _GUICtrlListView_CreateArray() • _GUICtrlListView_SaveCSV() • _GUICtrlListView_SaveHTML() • _GUICtrlListView_SaveTxt() • _GUICtrlListView_SaveXML() • _GUICtrlMenu_Recent() • _GUICtrlMenu_SetItemImage() • _GUICtrlTreeView_CreateArray() • _GUIDisable() • _GUIImageList_SetIconFromHandle() • _GUISetIcon() • _Icon_Clear()/_Icon_Set() • _InetGet() • _InetGetGUI() • _InetGetProgress() • _IPDetails() • _IsFileOlder() • _IsGUID() • _IsHex() • _IsPalindrome() • _IsRegKey() • _IsStringRegExp() • _IsUPX() • _IsValidType() • _IsWebColor() • _Language() • _Log() • _MicrosoftInternetConnectivity() • _MSDNDataType() • _PathFull/GetRelative/Split() • _PathSplitEx() • _PrintFromArray() • _ProgressSetMarquee() • _ReDim() • _RockPaperScissors()/_RockPaperScissorsLizardSpock() • _ScrollingCredits • _SelfDelete() • _SelfRename() • _SelfUpdate() • _SendTo() • _ShellAll() • _ShellFile() • _ShellFolder() • _SingletonHWID() • _SingletonPID() • _Startup() • _StringIsValid() • _StringReplaceWholeWord() • _StringStripChar() • _Temperature() • _TrialPeriod() • _UKToUSDate()/_USToUKDate() • _WinAPI_CreateGUID() • _WMIDateStringToDate()/_DateToWMIDateString() • AutoIt Search • AutoIt3 Portable • AutoItWinGetTitle()/AutoItWinSetTitle() • Coding • FileInstallr • GeoIP database • GUI - Only Close Button • GUI Examples • GUICtrlDeleteImage() • GUICtrlGetBkColor() • GUICtrlGetStyle() • GUIGetBkColor() • LockFile() • PasteBin • SciTE Jump • Signature Creator • WM_COPYDATA • More Examples...Updated: 11/04/2013

Back to top

#2 Mat

43 38 48 31 30 4E 34 4F 32

MVPs
4,042 posts

Posted 06 June 2011 - 04:13 PM

Thats ugly and stupid, and that xml is never going to be pretty. Why not convert (slug is the term used in some places) the column headers to tags with a system for avoiding duplicates? Why not use properties rather than a new complex item called 'details'?

^{I don't know where I'm going, but I'm on my way.}

Back to top

#3 guinness

guinness

MVPs
10,439 posts

Posted 06 June 2011 - 04:20 PM

Thats ugly and stupid

OK, XML is totally new to me, so do you have a better output Example that I could at least use please.

Example List: _AdapterConnections() • _AlwaysRun() • _AppMon() • _AppMonEx() • _BinaryBin() • _CheckMsgBox() • _CmdLineRaw() • _ContextMenu() • _DesktopDimensions() • _DisplayPassword() • _Fibonacci() • _FileCompare() • _FileCompareContents() • _FileNameByHandle() • _FilePrefix/SRE() • _FindInFile() • _GetBackgroundColor()/_SetBackgroundColor() • _GetConrolID() • _GetCtrlClass() • _GetDirectoryFormat() • _GetDriveMediaType() • _GetFilename()/_GetFilenameExt() • _GetHardwareID() • _GetIP() • _GetIP_Country() • _GetOSLanguage() • _GetSavedSource • _GetStringSize() • _GetSystemPaths() • _GetURLImage() • _GIFImage() • _GoogleWeather() • _GUICtrlCreateGroup() • _GUICtrlListBox_CreateArray() • _GUICtrlListView_CreateArray() • _GUICtrlListView_SaveCSV() • _GUICtrlListView_SaveHTML() • _GUICtrlListView_SaveTxt() • _GUICtrlListView_SaveXML() • _GUICtrlMenu_Recent() • _GUICtrlMenu_SetItemImage() • _GUICtrlTreeView_CreateArray() • _GUIDisable() • _GUIImageList_SetIconFromHandle() • _GUISetIcon() • _Icon_Clear()/_Icon_Set() • _InetGet() • _InetGetGUI() • _InetGetProgress() • _IPDetails() • _IsFileOlder() • _IsGUID() • _IsHex() • _IsPalindrome() • _IsRegKey() • _IsStringRegExp() • _IsUPX() • _IsValidType() • _IsWebColor() • _Language() • _Log() • _MicrosoftInternetConnectivity() • _MSDNDataType() • _PathFull/GetRelative/Split() • _PathSplitEx() • _PrintFromArray() • _ProgressSetMarquee() • _ReDim() • _RockPaperScissors()/_RockPaperScissorsLizardSpock() • _ScrollingCredits • _SelfDelete() • _SelfRename() • _SelfUpdate() • _SendTo() • _ShellAll() • _ShellFile() • _ShellFolder() • _SingletonHWID() • _SingletonPID() • _Startup() • _StringIsValid() • _StringReplaceWholeWord() • _StringStripChar() • _Temperature() • _TrialPeriod() • _UKToUSDate()/_USToUKDate() • _WinAPI_CreateGUID() • _WMIDateStringToDate()/_DateToWMIDateString() • AutoIt Search • AutoIt3 Portable • AutoItWinGetTitle()/AutoItWinSetTitle() • Coding • FileInstallr • GeoIP database • GUI - Only Close Button • GUI Examples • GUICtrlDeleteImage() • GUICtrlGetBkColor() • GUICtrlGetStyle() • GUIGetBkColor() • LockFile() • PasteBin • SciTE Jump • Signature Creator • WM_COPYDATA • More Examples...Updated: 11/04/2013

Back to top

#4 Mat

43 38 48 31 30 4E 34 4F 32

MVPs
4,042 posts

Posted 06 June 2011 - 05:23 PM

Listview:

Id | Name
0 | Foo
1 | Bar

I'd go with:

<listview rows="2" cols="2">
    <item>
        <id>0</id>
        <name>Foo</name>
    </item>
    <item>
        <id>1</id>
        <name>Bar</name>
    </item>
</listview>

rows and cols should be optional. They aren't really needed.

^{I don't know where I'm going, but I'm on my way.}