14 replies to this topic

[guinness]

I currently have a Language UDF which I need to tidy up and one day will release on the AutoIt Forums (I just need to add the function headers.) But in the interim I thought I would upload _GetOSLanguage() which retrieves the language of the OS. Now for most on here this code is really really simple, but I've noticed some still find Arrays a little hard to grasp and despite a brilliant wiki page, a 'real world' example can help with understanding this data type a little bit more.

It's also a different take on the Help file example which uses Select...EndSelect.

Function:

AutoIt        expandcollapse  popup

; #FUNCTION# ====================================================================================================================
; Name ..........: _GetOSLanguage
; Description ...: Retrieves the language of the OS, this supports 19 of the most popular languages.
; Syntax ........: _GetOSLanguage()
; Parameters ....: None
; Return values .: OS language
; Author ........: guinness
; Link ..........: http://www.autoitscript.com/forum/topic/131832-getoslanguage-retrieve-the-language-of-the-os/
; Example .......: Yes
; ===============================================================================================================================
Func _GetOSLanguage()
    Local Const $aString[20] = [19, $LANG_ENGLISH, $LANG_CHINESE, $LANG_DANISH, $LANG_DUTCH, $LANG_ESTONIAN, $LANG_FINNISH, $LANG_FRENCH, $LANG_GERMAN, _
            $LANG_HUNGARIAN, $LANG_ITALIAN, $LANG_JAPANESE, $LANG_NORWEGIAN, $LANG_POLISH, $LANG_PORTUGUESE, $LANG_ROMANIAN, $LANG_RUSSIAN, _
            $LANG_SERBIAN, $LANG_SPANISH, $LANG_SWEDISH], _
            $aLanguage[20] = [19, 'English', 'Chinese', 'Danish', 'Dutch', 'Estonian', 'Finnish', 'French', 'German', _
            'Hungarian', 'Italian', 'Japanese', 'Norwegian', 'Polish', 'Portuguese', 'Romanian', 'Russian', _
            'Serbian', 'Spanish', 'Swedish'], _
            $iOSLang = Dec(StringRight(@OSLang, 2)) ; @OSLang is four characters in length, the first two is the dialect and the remaining is the language. Thanks GEOSoft.
    For $i = 1 To $aString[0]
        If $iOSLang = $aString[$i] Then
            $aLanguage[1] = $aLanguage[$i]
            ExitLoop
        EndIf
    Next
    Return $aLanguage[1]
EndFunc   ;==>_GetOSLanguage

Example use of Function:

#include <Constants.au3>

MsgBox($MB_SYSTEMMODAL, '', 'The default language translation will be ' & _GetOSLanguage() & '.' & @CRLF)

Edited by guinness, 31 January 2013 - 12:23 PM.

[Emiel Wieldraaijer]

@Guinness

Thanks for posting.

I've created a similar function, never posted and don't know why.

I use @MUILang instead of @OSLang (Only for Vista and Above)

There is a simple reason for this, @OSLang shows the Language of the OS but not the displayed language. So when you buy for example a HP computer with a dutch OS, you will get an English OS (@OSLang) with a dutch Language Pack (@MUILang) preinstalled.

When i was working on something similar as your UDF i came across this problem, that why is made a request for something as @MUILang http://www.autoitscript.com/trac/autoit/ticket/869

Best regards,

Emiel

Edited by Emiel Wieldraaijer, 13 August 2011 - 03:13 PM.

[JohnOne]

On win 7, @MUILang returns 0409 (English (united States)) when in fact everything on my pc is English (United Kingdom)

[Emiel Wieldraaijer]

On win 7, @MUILang returns 0409 (English (united States)) when in fact everything on my pc is English (United Kingdom)

Very strang, maybe you should report it as a bug.
I don't know for sure but @MUILang retrieves the information from your registry.

Edited by Emiel Wieldraaijer, 13 August 2011 - 03:55 PM.

[JohnOne]

When installing windows, I am always very carefull to make sure of those points, and control panel region and language show UK for everything in it.

[Emiel Wieldraaijer]

I have no english (UK) OS so i cannot check

[Yashied]

It may be easier.

#Include <WinAPIEx.au3>

ConsoleWrite(_WinAPI_GetLocaleInfo(Dec(@OSLang), $LOCALE_SLANGUAGE) & @CR)
ConsoleWrite(_WinAPI_GetLocaleInfo(Dec(@OSLang), $LOCALE_SENGLANGUAGE) & @CR)
ConsoleWrite(_WinAPI_GetLocaleInfo(Dec(@OSLang), $LOCALE_SABBREVLANGNAME) & @CR)
ConsoleWrite(_WinAPI_GetLocaleInfo(Dec(@OSLang), $LOCALE_SNATIVELANGNAME) & @CR)

Edited by Yashied, 13 August 2011 - 09:21 PM.

[JohnOne]

I still get this with Your code Yashied.

English (United States)
English
ENU
English

I cannot figure out why.

[Emiel Wieldraaijer]

I still get this with Your code Yashied.

I cannot figure out why.

Your language isn't completly English (UK) but 0409 English (US)

English - United States 0409 1033
English - United Kingdom 0809 2057

http://msdn.microsoft.com/en-us/goglobal/bb964664

[JohnOne]

Thanks, but that list is also in the autoit3 help file, I know what it should be, it just is not right.

I cannot find anywhere on my PC that says my language,location, region or indeed keyboard, is English US

Its rather puzzling.

Edited by JohnOne, 13 August 2011 - 11:00 PM.

[guinness]

_WinAPI_GetLocaleInfo()

Another function I've missed from WinAPIEx!

[guinness]

Updated the original post with an idea by GEOSoft. Thanks.

[guinness]

I've updated the function by using the available (though as of yet undocumented) constant variables.

Edit: Now I exit the loop instead of using a return command, Single Entry-Single Exit point.

Edited by guinness, 31 January 2013 - 12:24 PM.

[Exit]

Keep it simple

; for language ids see <a href='http://msdn.microsoft.com/goglobal/bb964664' class='bbc_url' title='External link' rel='nofollow external'>http://msdn.microsoft.com/goglobal/bb964664</a>
MsgBox(Default, Default, 'The default language translation of this PC is ' & __GetOSLanguage())
MsgBox(Default, Default, 'The default English translation is ' & __GetOSLanguage(9))
MsgBox(Default, Default, 'The translation for London is ' & __GetOSLanguage(809))
MsgBox(Default, Default, 'The translation for Montego Bay is ' & __GetOSLanguage(2009))
Func __GetOSLanguage($Lang = "")
Local Const $GetLanguage = 114
Local $a = DllCall('kernel32.dll', 'int', 'GetLocaleInfoW', 'ulong', Dec($Lang), 'dword', $GetLanguage, 'wstr', '', 'int', 2048)
Return $a[3]
EndFunc ;==>__GetOSLanguage

Edited by Exit, 31 January 2013 - 03:34 PM.

[guinness]

Thanks.