Firing an event when user doubleclicked a label.

[continyu]

Hey there,

I've still same problem. I wanna run a function when my users double clicked a label. I've been told to do it with guiregistermsg but couldn't do it. Can anyone show the proper way to do it?

[Melba23]

continyu,

Not sure if it is "proper" but you can do it this way:

#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#include <StaticConstants.au3>

$fDblClick = False

$hGUI = GUICreate("Test", 500, 500)
$hLabel = GUICtrlCreateLabel("DoubleClick Me", 150, 200, 200, 50, BitOr($SS_CENTER, $SS_CENTERIMAGE))
GUICtrlSetBkColor(-1, 0xFFFF00)
GUISetState()

GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            ExitLoop
    EndSwitch

    If $fDblClick Then
        $fDblClick = False
        MsgBox(0, "Hit", "You DoubleClicked Me!")
    EndIf
WEnd

Func WM_COMMAND($hWnd, $MsgID, $wParam, $lParam)

    Local Const $STN_DBLCLK = 1
    Local $nID = BitAND($wParam, 0xFFFF)
    Local $nNotifyCode = BitShift($wParam, 16)

    If $nID = $hlabel And $nNotifyCode = $STN_DBLCLK Then $fDblClick = True
    Return $GUI_RUNDEFMSG

EndFunc

M23