17 replies to this topic

[Syed23]

Hi All,
To improve my knowledge i have written another basic example script. please help me and give me some suggestion on this to improve more..... The below script will check the connection status of the net..


Here is the UDF.

AutoIt        expandcollapse  popup

 
#include-once
Local $strcomputer,$objWMIService,$colItems ,$objItem
 
Func Connection($strcomputer)
$objWMIService = ObjGet("winmgmts:\\" & $strComputer & "\root\cimv2")
 
 $colItems = $objWMIService.ExecQuery _
    ("Select * from Win32_NetworkAdapter")
 
For $objItem in $colItems
    Select
Case $objItem.NetConnectionStatus
        Case 0
$strStatus = "Disconnected"
        Case 1
$strStatus = "Connecting"
        Case 2
$strStatus = "Connected"
        Case 3
$strStatus = "Disconnecting"
        Case 4
$strStatus = "Hardware not present"
        Case 5
$strStatus = "Hardware disabled"
        Case 6
$strStatus = "Hardware malfunction"
        Case 7
$strStatus = "Media disconnected"
        Case 8
$strStatus = "Authenticating"
        Case 9
$strStatus = "Authentication succeeded"
        Case 10
$strStatus = "Authentication failed"
        Case 11
$strStatus = "Invalid address"
        Case 12
$strStatus = "Credentials required"
    EndSelect
 Next
Return $strStatus
EndFunc

Here is the example:

#include <Net.au3>
MsgBox(0,"",Connection(@ComputerName))

[BrewManNH]

This line:

Local $strcomputer,$objWMIService,$colItems ,$objItem
 

should be inside the function. Otherwise it will declare those variables as global and may cause interaction with other parts of a script if you reuse the variable names. Declaring a variable as Local in a Global scope declares them as global automatically, the Local designation is ignored in this case.

[wraithdu]

Also your Select block is horribly broken. It's using Switch syntax, but incorrectly. Help file awaits!

Edited by wraithdu, 26 October 2011 - 03:06 AM.

[BrewManNH]

I also noticed that the value in $strstatus is only going to hold the last value of $colitems because you don't preserve any other readings. My computer shows several network connections, most disconnected, that were added because of VPN connections and other wireless locations I've connected it to.

Something like this might be more in line with what you're looking to show.

AutoIt        expandcollapse  popup

Func Connection($strcomputer)
    Local $strStatus=""
    $objWMIService = ObjGet("winmgmts:\\" & $strcomputer & "\root\cimv2")

    $colItems = $objWMIService.ExecQuery _
            ("Select * from Win32_NetworkAdapter")

    For $objItem In $colItems
        Switch $objItem.NetConnectionStatus
            Case 0
                $strStatus &= "Disconnected" & @LF
            Case 1
                $strStatus &= "Connecting" & @LF
            Case 2
                $strStatus &= "Connected" & @LF
            Case 3
                $strStatus &= "Disconnecting" & @LF
            Case 4
                $strStatus &= "Hardware not present" & @LF
            Case 5
                $strStatus &= "Hardware disabled" & @LF
            Case 6
                $strStatus &= "Hardware malfunction" & @LF
            Case 7
                $strStatus &= "Media disconnected" & @LF
            Case 8
                $strStatus &= "Authenticating" & @LF
            Case 9
                $strStatus &= "Authentication succeeded" & @LF
            Case 10
                $strStatus &= "Authentication failed" & @LF
            Case 11
                $strStatus &= "Invalid address" & @LF
            Case 12
                $strStatus &= "Credentials required" & @LF
        EndSwitch
    Next
    Return $strStatus
EndFunc   ;==>Connection

Edited by BrewManNH, 26 October 2011 - 03:19 AM.

[Syed23]

Thanks for all your response! I am glad to get suggestion and i have modified my scripts!


BrewManNH,

why i am getting result like attached screen shot? i am expecting the result should be either "Connected"or "disconnected" or "Hardware not found".But the result shows 7 times as disconnected and 1 time connected.

Edited:

i got it why it happened i moddifed the script again. But still i have a question. My machine is connected with network, but still shows as disconnected? i am wondering why

Edited by Syed23, 26 October 2011 - 05:38 AM.

[Syed23]

is this correct am i doing?

AutoIt        expandcollapse  popup

 
Global $strcomputer, $objWMIService, $colItems, $objItem
 
Connection(@ComputerName)
 
 
Func Connection($strcomputer)
Local $strStatus = ""
$objWMIService = ObjGet("winmgmts:\\" & $strcomputer & "\root\cimv2")
 
$colItems = $objWMIService.ExecQuery _
("Select * from Win32_NetworkAdapter where NetConnectionStatus='2'")
$strStatus = "Disconnected"
For $objItem In $colItems
Switch $objItem.NetConnectionStatus
Case 0
$strStatus = "Disconnected"
Case 1
$strStatus = "Connecting"
Case 2
$strStatus = "Connected"
Case 3
$strStatus = "Disconnecting"
Case 4
$strStatus = "Hardware not present"
Case 5
$strStatus = "Hardware disabled"
Case 6
$strStatus = "Hardware malfunction"
Case 7
$strStatus = "Media disconnected"
Case 8
$strStatus = "Authenticating"
Case 9
$strStatus = "Authentication succeeded"
Case 10
$strStatus = "Authentication failed"
Case 11
$strStatus = "Invalid address"
Case 12
$strStatus = "Credentials required"
EndSwitch
 
Next
MsgBox(0,"", $strStatus)
EndFunc   ;==>Connection

[frp64]

Hi, maybe in this page you can meet anything. The link is:

http://blogs.technet.com/b/heyscriptingguy/archive/2007/08/20/how-can-i-tell-if-a-wireless-network-adapter-is-connected-to-the-network.aspx

Greetings, Frank Rodriguez.

[BrewManNH]

Thanks for all your response! I am glad to get suggestion and i have modified my scripts!


BrewManNH,

why i am getting result like attached screen shot? i am expecting the result should be either "Connected"or "disconnected" or "Hardware not found".But the result shows 7 times as disconnected and 1 time connected.

Edited:

i got it why it happened i moddifed the script again. But still i have a question. My machine is connected with network, but still shows as disconnected? i am wondering why

You're showing as disconnected because you broke the functionality of the script again by "fixing" the script back to the way you had it before. You should reread what I wrote about the $strstatus value in my post and try and figure out what you're doing wrong, and where you really need to look to see if a specific NIC is connected or not, not whether all the network connections on your system are connected or not.

[Syed23]

Yeah! now i fixed it completely! Thanks

[JohnOne]

Yeah! now i fixed it completely! Thanks

So.....

This is an Example Script Forum, try to work out the protocol when you have improved a script.

Or was this a thinly veiled support question?

[guinness]

This is an Example Script Forum, try to work out the protocol when you have improved a script.

Actually this brings up a valid question, if you've specified somewhere along the course of the conversation that you've fixed a problem with the initial code example (that you've freely posted without a license,) is it mandatory to update the original post? Or could this be construed as breaking the 'ask for source code' rules?

[guinness]

Here is a better approach >> the huge difference is this gets rid of the connections the average user isn't really concerned about, for example I'm only interested in the physical connections i.e. WLAN, Bluetooth & LAN. It also returns an Array and not a String as well as telling you what the adapters are!

Function:

AutoIt        expandcollapse  popup

#include <Array.au3>

Local $aArray = _AdapterConnections() ; Data is returned as a 2D Array. Adapter|Status.
_ArrayDisplay($aArray)

For $i = 1 To $aArray[0][0]
    ConsoleWrite('Adapter: ' & $aArray[$i][0] & ' is currently ' & $aArray[$i][1] & '.' & @LF)
Next

Func _AdapterConnections($sComputer = @ComputerName)
    Local $aReturn[1][2] = [[0, 2]], $iDimension = 0, $sDelimeter = Chr(01), $sReturn = ''
    Local $aStatus[13] = ['Disconnected', 'Connecting', 'Connected', 'Disconnecting', 'Hardware not present', _
            'Hardware disabled', 'Hardware malfunction', 'Media disconnected', 'Authenticating', 'Authentication succeeded', _
            'Authentication failed', 'Invalid address', 'Credentials required']

    Local $oWMIService = ObjGet('winmgmts:' & $sComputer & '')
    Local $oColItems = $oWMIService.ExecQuery('Select * From Win32_NetworkAdapter', 'WQL', 0x30)

    If IsObj($oColItems) Then
        For $oObjItem In $oColItems
            If $oObjItem.AdapterType = '' Or $oObjItem.NetConnectionID = '' Then ; Ensures that the connections are physical adapters.
                ContinueLoop
            EndIf
            If StringInStr($sDelimeter & $sReturn, $sDelimeter & $oObjItem.Description & $sDelimeter, 1) Then ; Ensures there are no duplicates.
                ContinueLoop
            EndIf
            $sReturn &= $oObjItem.Description & $sDelimeter

            If ($aReturn[0][0] + 1) >= $iDimension Then ; <a href='http://www.autoitscript.com/forum/topic/129689-redim-the-most-efficient-way-so-far-when-you-have-to-resize-an-existing-array/' class='bbc_url' title=''>http://www.autoitscript.com/forum/topic/129689-redim-the-most-efficient-way-so-far-when-you-have-to-resize-an-existing-array/</a>
                $iDimension = ($aReturn[0][0] + 1) * 2
                ReDim $aReturn[$iDimension][$aReturn[0][1]]
            EndIf

            $aReturn[0][0] += 1
            $aReturn[$aReturn[0][0]][0] = $oObjItem.Description
            For $i = 0 To 12
                If $oObjItem.NetConnectionStatus = $i Then ; <a href='http://msdn.microsoft.com/en-us/library/windows/desktop/aa394216(v=vs.85' class='bbc_url' title='External link' rel='nofollow external'>http://msdn.microsoft.com/en-us/library/windows/desktop/aa394216(v=vs.85</a>).aspx
                    $aReturn[$aReturn[0][0]][1] = $aStatus[$i]
                    ExitLoop
                EndIf
            Next
        Next
    EndIf

    ReDim $aReturn[$aReturn[0][0] + 1][$aReturn[0][1]]
    $aReturn[0][1] = ''
    Return $aReturn
EndFunc   ;==>_AdapterConnections

Edited by guinness, 08 October 2012 - 04:00 PM.

[JohnOne]

What I meant was, the OP posted here in the Example Forum.

Then grins with glee after "fixing it completely" and disappears into the night, suggesting it was really just support they wanted in the first place, not to provide an example.

[Syed23]

i did not disappear John. Here is a public holiday and so i did not come to office and i did not get a chance to reply. Here is my fixed code. Thanks for the open comment

AutoIt        expandcollapse  popup

 
#include-once
Global $strcomputer, $objWMIService, $colItems, $objItem
 
Func Connection($strcomputer)
Local $strStatus = ""
$objWMIService = ObjGet("winmgmts:\\" & $strcomputer & "\root\cimv2")
 
$colItems = $objWMIService.ExecQuery _
("Select * from Win32_NetworkAdapter where NetConnectionStatus='2'")
$strStatus = "Disconnected";    if connection is not there it won't go inside the loop and it will use this value
For $objItem In $colItems
Switch $objItem.NetConnectionStatus
Case 0
$strStatus = "Disconnected"
Case 1
$strStatus = "Connecting"
Case 2
$strStatus = "Connected"
Case 3
$strStatus = "Disconnecting"
Case 4
$strStatus = "Hardware not present"
Case 5
$strStatus = "Hardware disabled"
Case 6
$strStatus = "Hardware malfunction"
Case 7
$strStatus = "Media disconnected"
Case 8
$strStatus = "Authenticating"
Case 9
$strStatus = "Authentication succeeded"
Case 10
$strStatus = "Authentication failed"
Case 11
$strStatus = "Invalid address"
Case 12
$strStatus = "Credentials required"
EndSwitch
 
Next
Return $strStatus
EndFunc   ;==>Connection

[guinness]

Syed23,

Your code works, but doesn't meet what I would call a basic standard of coding, here's why >>

1. You're requesting the return of active connections only, thus rendering the Switch...EndSwitch useless.
2. If only returns the last active connection it finds, strange considering I have Bluetooth and WLAN enabled. (See BrewManNH's post as to why.)
3. Using Global declaration in this example isn't required.

How I would do your previous Example:

AutoIt        expandcollapse  popup

#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6 -w 7
#include <Array.au3>
 
Global $aArray
 
$aArray = _AdaptersConnected() ; Data is returned as a 1D Array. Adapter.
_ArrayDisplay($aArray)
 
For $A = 1 To $aArray[0]
    ConsoleWrite("Adapter: " & $aArray[$A] & " is currently Connected." & @LF)
Next
 
Func _AdaptersConnected($sComputer = @ComputerName)
    Local $aReturn[1] = [0], $iDimension = 0, $oColItems, $oWMIService, $sDelimeter = Chr(01), $sReturn = ""
 
    $oWMIService = ObjGet("winmgmts:\\" & $sComputer & "\")
    $oColItems = $oWMIService.ExecQuery("Select * From Win32_NetworkAdapter Where NetConnectionStatus='2'", "WQL", 0x30)
 
    If IsObj($oColItems) Then
        For $oObjItem In $oColItems
            If $oObjItem.AdapterType = "" Or $oObjItem.NetConnectionID = "" Then ; Ensures that the connections are physical adapters.
                ContinueLoop
            EndIf
            If StringInStr($sDelimeter & $sReturn, $sDelimeter & $oObjItem.Description & $sDelimeter, 1) Then ; Ensures there are no duplicates.
                ContinueLoop
            EndIf
            $sReturn &= $oObjItem.Description & $sDelimeter
 
            If ($aReturn[0] + 1) >= $iDimension Then ; <a href='http://www.autoitscript.com/forum/topic/...en-you-have-to-resize-an-exist' class='bbc_url' title=''>http://www.autoitscript.com/forum/topic/...en-you-have-to-resize-an-exist</a>
                $iDimension = ($aReturn[0] + 1) * 2
                ReDim $aReturn[$iDimension]
            EndIf
 
            $aReturn[0] += 1
            $aReturn[$aReturn[0]] = $oObjItem.Description
        Next
    EndIf
 
    ReDim $aReturn[$aReturn[0] + 1]
    Return $aReturn
EndFunc   ;==>_AdaptersConnected

Edited by guinness, 27 October 2011 - 01:40 PM.

[Syed23]

hmmm... ok i will use your example and i will compare myself what is the difference. Thanks for your suggestion guinness!

[guinness]

Look at the ConsoleWrite() with your version I get 1 connected when I should get 2 and secondly what is connected? Mine shows the adapter names.

[BrewManNH]

I left my example as a way to "teach him to fish", obviously fishing isn't his forte.