8 replies to this topic

[roboz]

Hi,

I've got a problem with displaying the "&" sign properly. Here's a short example:

$album = "Lock, Stock & Two Smoking Barrels"

GuiCreate("test", 600, 210)  
  
$abc = GUICtrlCreateLabel ($album, 20, 80, 400, 80)
   
GUISetState()

MsgBox(4096,'debug:' , '$album:' & $album)


While 1
   
   Sleep (100)
   
WEnd

The label created with GUICtrlCreateLabel shows:

Lock, Stock_Two Smoking Barrels

The message window shows the correct:

Lock, Stock & Two Smoking Barrels

When I replace "&" with "&&" in the string it shows one "&" in the label. Can aynone please explain why this happens? Using v3.1.1 by the way

Thanks

Edited by roboz, 13 July 2005 - 10:24 AM.

[GaryFrost]

for GUI it would be to identify a shortcut key for example an OK button

Select Alt+o and see what happens

#include <GuiConstants.au3>

$album = "Lock, Stock && Two Smoking Barrels"

GuiCreate("test", 600, 210)  
  
$abc = GUICtrlCreateLabel ($album, 20, 80, 400, 80)
$Button = GUICtrlCreateButton ("&OK",  10, 30, 50)

GUISetState()

While 1
   $msg = GUIGetMsg()
    Select
    Case $msg = $GUI_EVENT_CLOSE
        ExitLoop
    Case $msg = $Button
        MsgBox(4096,'debug:' , '$album:' & $album)
    EndSelect
WEnd

[sandyd]

Windows standard for controls is to use the & to indicate an accelerator key.

e.g. If you give a button the text of Can&cel the button will show Canc el.

This means that if you press ALT+c the button is clicked.

Labels can be attached to Edits to allow the same thing to happen. If you press the ALT key and the accelerator key, the focus is moved to the Edit relating to the Label.

The message box is just showing the string literaly.

Hope that helps.

[roboz]

Thanks for the quick replies. So is there an easy way to show the string in the label literally?

[LxP]

The best way would be to StringReplace() any '&' occurences in your data with '&&' while displaying on the GUI:

$album = "Lock, Stock & Two Smoking Barrels"

guiCreate("test", 600, 210)  
$abc = guiCtrlCreateLabel(stringReplace($album, "&", "&&"), 20, 80, 400, 80)
guiSetState()

Edited by LxP, 13 July 2005 - 11:53 AM.

[roboz]

I'll do that. Thanks

[LxP]

Probably an even better solution would be to create your label with the $SS_NOPREFIX style included:

$abc = guiCtrlCreateLabel($album, 20, 80, 400, 80, $SS_NOPREFIX)

[seandisanti]

Probably an even better solution would be to create your label with the $SS_NOPREFIX style included:

$abc = guiCtrlCreateLabel($album, 20, 80, 400, 80, $SS_NOPREFIX)

<{POST_SNAPBACK}>

another alternative would be to use chr(38) inplace of your &...
ex: "Lock, Stock, " & chr(38) & " 2 smoking barrels"... in notepad you could just press control h, and replace '&' with '" & chr(38) & "' without the surrounding single quotes... that way you can have a hotkey AND and a '&' in your string...

[roboz]

Thanks for all the help. I think I'll go with the $SS_NOPREFIX because I'm reading the information directly from iTunes through the COM interface, so that's probably the easiest way.