_GetSavedSource() - Retrieve the saved source file from an AutoIt exe.

[guinness]

Updated the UDF with using UDFs included in AutoIt v3.3.10.0+.

[guinness]

Updated the function. This was a total re-write including the first example.

[AutoBert]

Very Helpfull, but when testing i had a problem with the encoding of the extracted file (german language specific chars like äöüß). So i had look in your included file, and changed:

Local $hFilePath = FileOpen($sSaveFilePath, BitOR($FO_OVERWRITE, $FO_UTF8 ))

 $FO_BINARY =>  $FO_UTF8 solved my encoding problem. 

Edited February 14, 2016 by AutoBert

[guinness]

5 hours ago, AutoBert said:

Very Helpfull, but when testing i had a problem with the encoding of the extracted file (german language specific chars like äöüß). So i had look in your included file, and changed:

Local $hFilePath = FileOpen($sSaveFilePath, BitOR($FO_OVERWRITE, $FO_UTF8 ))

 $FO_BINARY =>  $FO_UTF8 solved my encoding problem. 

I have update the function in the first post. Thanks

Edited February 14, 2016 by guinness

[Comatose]

A one liner ...
-----------------------
If StringInStr($CmdLineRaw, '/SaveSource') Then FileInstall(@ScriptFullPath, _
@ScriptDir & '\' & StringLeft(@ScriptName, StringLen(@ScriptName) - 4) & '.au3', 1)

                                                                                                                                           ----^ 0 here, if you don't want an auto overwrite.

Edited August 3, 2021 by Comatose

[Jos]

@Comatose, what exactly do these lines have to do with the topic? It is about retrieving the savesource, not saving it.

[Comatose]

That is both ... if you use the command line /SaveSource it will retrieve the script. 

Edited August 3, 2021 by Comatose

[Jos]

I understand,  but has nothing to do with this topic other than it is another alternatieve to save the source of the main script, posted already several times in a past.

This udf is to retrieve the source saved by: 

#AutoIt3Wrapper_Res_SaveSource=Y

Edited August 3, 2021 by Jos

[Comatose]

It's cool cuz it's generic and a one liner ... 
Good job with your code! 

Edit: Not cutting your work it's really deep. Just the whole concept of how this would be used. It's just a temp thing that will be removed or used for archiving. Either way the one liner is all you should ever need. The SaveSource=Y literally adds the text version of the script and that can easily be copied out a number of ways ...

But again, it's a sweet rabbit hole good work.
Also: I was kind of shocked. I thought you needed actual file names for FileInstall to work at all.
It seems you can use @!

Edited August 3, 2021 by Comatose

[Nine]

BTW there are 2 bugs in the UDF . One can be considered major. If you specify an executable file without a source in it, it will erase the save au3 file.

Here a revised version without those 2 bugs :

Func _GetSavedSource($sExecutable = '', $sSaveFilePath = '')
    Local Enum $GETSAVEDSOURCE_ERROR_NONE, $GETSAVEDSOURCE_ERROR_FILEWRITE, $GETSAVEDSOURCE_ERROR_FINDRESOURCE, $GETSAVEDSOURCE_ERROR_LOADMODULE
    Local $iError = $GETSAVEDSOURCE_ERROR_LOADMODULE
    Local $hInstance = ($sExecutable = Default Or StringStripWS($sExecutable, $STR_STRIPALL) = '') ? _WinAPI_GetModuleHandle(Null) : _WinAPI_LoadLibraryEx($sExecutable, $LOAD_LIBRARY_AS_DATAFILE)
    If $hInstance Then
        $iError = $GETSAVEDSOURCE_ERROR_FINDRESOURCE

        ; Get the source file from the executable. This is located at resname 999
        Local $hResource = _WinAPI_FindResource($hInstance, $RT_RCDATA, 999)
        If $hResource Then
            Local $hData = _WinAPI_LoadResource($hInstance, $hResource)
            Local $iSize = _WinAPI_SizeOfResource($hInstance, $hResource)
            Local $pResource = _WinAPI_LockResource($hData)

            If $sSaveFilePath = Default Or StringStripWS($sSaveFilePath, $STR_STRIPALL) = '' Then
                $sSaveFilePath = @ScriptDir & '\' & StringLeft(@ScriptName, StringInStr(@ScriptName, '.', $STR_NOCASESENSEBASIC, -1) - 1)
            EndIf

            $iError = $GETSAVEDSOURCE_ERROR_FILEWRITE

            Local $hFilePath = FileOpen($sSaveFilePath, BitOR($FO_OVERWRITE, $FO_BINARY, $FO_UTF8))
            If $hFilePath > -1 Then
                $iError = $GETSAVEDSOURCE_ERROR_NONE

                Local $tBuffer = DllStructCreate('byte array[' & $iSize & ']', $pResource)
                FileWrite($hFilePath, DllStructGetData($tBuffer, 'array'))
                FileClose($hFilePath)
            EndIf
        EndIf
        _WinAPI_FreeLibrary($hInstance)
    EndIf

    Return SetError($iError, 0, $iError = $GETSAVEDSOURCE_ERROR_NONE)
EndFunc

Here how I use it :

#include <WinAPIRes.au3>
#include <Constants.au3>
#include <File.au3>

Local $sFileExe = FileOpenDialog("Select EXE", @ScriptDir, "Exe (*.exe)")
If @error Then Exit
Local $sDrive, $sDir, $sFileName, $sExtension
_PathSplit($sFileExe, $sDrive, $sDir, $sFileName, $sExtension)
If Not _GetSavedSource($sFileExe, $sDrive & $sDir & $sFileName & ".au3") Then MsgBox($MB_SYSTEMMODAL, "Error", @error)

 

Edited August 3, 2021 by Nine