17 replies to this topic

[Chimaera]

I'm working on something to enable the built in admin account on windows 7
ie the one that is hidden on install of windows.

I know how to enable it but i want to be able to detect it so if its already active i don't try and make it active again.

so some sort of function etc that i can run a check with maybe?
im using net user to change it to active

Is there a way to detect it?

any pointers helpfull.

[rover]

WMI rootCIMV2 "SELECT Disabled FROM Win32_UserAccount WHERE Name = 'Administrator'"
or parse Account Active from STDOUT of Run("Net user Administrator")

Edited by rover, 23 April 2012 - 09:18 PM.

[guinness]

WMI rootCIMV2 "SELECT Disabled FROM Win32_UserAccount WHERE Name = 'Administrator'"

I started Scriptomatic but got a little distracted, that's one to add to my function folder. Thanks.

[guinness]

ConsoleWrite(_IsAdminEnabled() & @CRLF)

Func _IsAdminEnabled()
    Local $oWMIService = ObjGet('winmgmts:localhostrootCIMV2')
    Local $oColItems = $oWMIService.ExecQuery('SELECT * FROM Win32_UserAccount WHERE Name = "Administrator"', "WQL", 0x30)
    If IsObj($oColItems) Then
        For $oItem In $oColItems
            Return $oItem.Disabled = False
        Next
    EndIf
    Return True
EndFunc   ;==>_IsAdminEnabled

Edited by guinness, 24 April 2012 - 09:08 AM.

[JohnOne]

"Return $oItem.Disabled = False"

Would that not return false when it is Enabled?

[guinness]

If the Admin account is Disabled it returns True, not False.

Edited by guinness, 24 April 2012 - 09:42 AM.

[JohnOne]

Seems a little unintuitive bud, unless you named it "IsAdminDisabled.

[guinness]

I wouldn't worry about that line, if the Admin account is enabled then _IsAdminEnabled returns True.

[JohnOne]

Must be this brain block I've had of late.

Cheers.

[guinness]

It's OK. It feels more natural to write the True statement first and then the False statement e.g.

; This is how the majority of users write code.
If _IsAdminEnabled() Then
    ; It's True
Else
    ; It's False
EndIf

; So using _IsAdminDisabled would result in this.
If _IsAdminDisabled() = False Then
    ; It's True
Else
    ; It's False
EndIf

[JFX]

How about that?

Func _IsAccountDisabled($sUser = @UserName, $sCompName = ".")
Local $aCall = DllCall("netapi32.dll", "int", "NetUserGetInfo", "wstr", $sCompName, "wstr", $sUser, "dword", 1, "ptr*", 0)
If @error Or $aCall[0] Then Return SetError(1, 0, False)
Local $Return = (BitAND(DllStructGetData(DllStructCreate("ptr;ptr;dword;dword;ptr;ptr;dword;ptr", $aCall[4]), 7), 2) <> 0)
DllCall("netapi32.dll", "int", "NetApiBufferFree", "ptr", $aCall[4])
Return $Return
EndFunc

ConsoleWrite(_IsAccountDisabled('Administrator') & @CRLF)

Edited by JFX, 24 April 2012 - 10:04 AM.

[JohnOne]

One returns false (guinness) and the other returns true (JFX)

[guinness]

Yeh, because JFX is checking if the Admin account is disabled.

[JohnOne]

lol

I need a few more days off.

[guinness]

I suppose I'm just an optimistic person and prefer enabled.

[Chimaera]

Geez i step out the house and the thread has gone mad..

Many thanks to all who contributed

I was still working on this

$colItems = ""
$Output=""
$objWMIService = ObjGet("winmgmts:\\localhost\root\CIMV2")
$colItems = $objWMIService.ExecQuery("SELECT * FROM Win32_UserAccount", "WQL")
If IsObj($colItems) then
   For $objItem In $colItems
      $Output &= "Caption: " & $objItem.Caption & @CRLF
      $Output &= "Disabled: " & $objItem.Disabled & @CRLF
      if Msgbox(1,"WMI Output",$Output) = 2 then ExitLoop
      $Output=""
   Next
Else
   Msgbox(0,"WMI Output","No WMI Objects Found for class: " & "Win32_UserAccount" )
Endif

[guinness]

See post #4 for a working function.

[guinness]

Using the method of 'net user' and reading the Standard Output Stream >> http://www.autoitscript.com/forum/topic/139260-autoit-snippets/page__pid__981844__st__20#entry981844