15 replies to this topic

[MvGulik]

Think it would be more intuitive (and usefull) if AdlibUnRegister() would completely reset things.
Ergo: This code would than actually be counting from the new AdlibRegister() timepoint. Instead of (kinda) behaving like there was no AdlibUnRegister() call at all.

AutoIt        expandcollapse  popup

#AutoIt3Wrapper_AU3Check_Stop_OnWarning=y
#AutoIt3Wrapper_AU3Check_Parameters=-q -d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6 -w 7

Global Const $iRatio = 100 ;; 1000
Global Const $sAdlib = 'AdlibFunc'
Global $iTimer = 0

$iTimer = TimerInit()

AdlibRegister($sAdlib, 4 * $iRatio)
Sleep((4 * 5 * $iRatio) + $iRatio)
AdlibUnRegister($sAdlib)
Exit

#cs    result:
AdlibFunc(), 409.264650422213 (+4)
AdlibFunc(), 799.788431372549 (+4)
AdlibFunc(), 1207.94519428939 (+4)
AdlibFunc(), 1616.18206347503 (+4)
AdlibFunc(), 2013.64021504222 (+4)
#ce

Func AdlibFunc()
    DebugOut('AdlibFunc(), ' & TimerDiff($iTimer))
    AdlibUnRegister($sAdlib)
    sleep(3*$iRatio) ;; some simulated processing time.
    AdlibRegister($sAdlib, 4 * $iRatio)
EndFunc

Func DebugOut($sMsg)
    ConsoleWrite($sMsg & @CRLF)
EndFunc

[3.3.8.1/3.3.9.4]

---

GOTO message http://www.autoitscript.com/forum/topic/141749-adlib-timing-behavior-adlibunregister/#entry997403 to skip confusing parts. (That would be message #10) (using stupid full http link, as forum post-editor is bugged to no end.)

Edited by MvGulik, 25 June 2012 - 07:15 AM.

[PhoenixXL]

Inside the Adlib Function therez no need to Unregister or ReRegister.

The script waits till the Function completes

Hope that helps
Phoenix XL

Edited by PhoenixXL, 23 June 2012 - 02:37 PM.

[MvGulik]

Inside the Adlib Function therez no need to Unregister or ReRegister.

The script waits till the Function completes

Hope that helps
Phoenix XL

Nope, Not really helping (yet).

Why do you say "... there is no need ..." ?.. I main I know there is no need, or better in my case "no use" for it, as there is no change in the default behavior.
But that's also my point, it would be nice if there would be a use for it.

I though about the fact that I'm doing the additional adlib-registering inside the adlib call, but did not follow trough on that thought. (mainly because I think there will be no difference, or effect, by doing so. ... will test later)

[Richard Robertson]

What do you mean by reset? I can't see what you're trying to accomplish without a concrete example.

[MvGulik]

If I read the OP code "as is" I think the more logical output/behavior would be something like:

AdlibFunc(), 400.~ (+4)...[*$ratio]
AdlibFunc(), 1100.~ (+3+4)
AdlibFunc(), 1800.~ (+3+4)
AdlibFunc(), 2500.~ (+3+4)
AdlibFunc(), 3200.~ (+3+4)

instead of

AdlibFunc(), 400.~ (+4)
AdlibFunc(), 800.~ (+4)
AdlibFunc(), 1200.~ (+4)
AdlibFunc(), 1600.~ (+4)
AdlibFunc(), 2000.~ (+4)

Which makes more sense to me if the code would use the names AdlibPauseCallback() and AdlibUnPauseCallback() for the adlib-register calls inside the AdlibFunc() function.

[corrections...][+codetags]

Edited by MvGulik, 23 June 2012 - 05:30 PM.

[czardas]

Think it would be more intuitive (and usefull) if AdlibUnRegister() would completely reset things.
Ergo: This code would than actually be counting from the new AdlibRegister() timepoint. Instead of (kinda) behaving like there was no AdlibUnRegister() call at all.

I didn't know this was the case. In the help file it says:

Re-registering an already existing Adlib function will update it with a new time.

Have you tested that?

Edited by czardas, 23 June 2012 - 05:10 PM.

[MvGulik]

Yep. works as expected.
But had wrong expectation. (stupid typo-bug fixed)(re-digesting result ...)

AutoIt        expandcollapse  popup

#AutoIt3Wrapper_AU3Check_Stop_OnWarning=y
#AutoIt3Wrapper_AU3Check_Parameters=-q -d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6 -w 7

#cs    result:
AdlibFunc(), 400 ... (+4)
AdlibFunc(), 900 ... (+5)
AdlibFunc(), 1500 ... (+6)
#ce

Global Const $iRatio = 100 ;; 1000
Global Const $sAdlib = 'AdlibFunc'
Global $iTimer = 0, $iCounter = 4

$iTimer = TimerInit()

AdlibRegister($sAdlib, 4 * $iRatio)
do
until $iCounter > 6
AdlibUnRegister($sAdlib)
Exit

Func AdlibFunc()
    DebugOut('AdlibFunc(), ' & _TimerDiffRound($iTimer))
    $iCounter += 1
    AdlibRegister($sAdlib, $iCounter * $iRatio)
EndFunc
Func _TimerDiffRound($time)
    Return Round(TimerDiff($time)/$iRatio)*$iRatio
EndFunc

Func DebugOut($sMsg)
    ConsoleWrite($sMsg & @CRLF)
EndFunc

[bug fixed]

Edited by MvGulik, 23 June 2012 - 08:20 PM.

[MvGulik]

Darn(2) ... back to the drawing board.

AutoIt        expandcollapse  popup

#AutoIt3Wrapper_AU3Check_Stop_OnWarning=y
#AutoIt3Wrapper_AU3Check_Parameters=-q -d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6 -w 7

#cs    result:
AdlibFunc(), 400
AdlibFunc(), 1100
AdlibFunc(), 1800
AdlibFunc(), 2500
AdlibFunc(), 3200
#ce

Global Const $iRatio = 100 ;; 1000
Global Const $sAdlib = 'AdlibFunc'
Global $fExit = False, $fAdlibReReg = False, $iTimer = 0
AdlibRegister('setExit', 36 * $iRatio)

$iTimer = TimerInit()

AdlibRegister($sAdlib, 4 * $iRatio)
Do
    If $fAdlibReReg Then
        AdlibUnRegister($sAdlib)
        AdlibRegister($sAdlib, 4 * $iRatio)
        $fAdlibReReg = False
    EndIf
Until $fExit
AdlibUnRegister($sAdlib)
Exit

Func AdlibFunc()
    DebugOut('AdlibFunc(), ' & Round(TimerDiff($iTimer)/$iRatio)*$iRatio )
    sleep(3*$iRatio) ;; some simulated processing time.
    $fAdlibReReg = True
EndFunc
Func SetExit()
    $fExit = True
EndFunc

Func DebugOut($sMsg)
    ConsoleWrite($sMsg & @CRLF)
EndFunc

---

For completion. #7 test tested outside adlib call. (no difference to result at #7) (+stupid typo-bug fix.)

Spoiler

AutoIt        expandcollapse  popup

#AutoIt3Wrapper_AU3Check_Stop_OnWarning=y
#AutoIt3Wrapper_AU3Check_Parameters=-q -d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6 -w 7

#cs    result:
AdlibFunc(), 400 .. (+4)
AdlibFunc(), 900 .. (+5)
AdlibFunc(), 1500 .. (+6)
#ce

Global Const $iRatio = 100 ;; 1000
Global Const $sAdlib = 'AdlibFunc'
Global $fAdlibReReg = False, $iTimer = 0, $iCounter = 4

$iTimer = TimerInit()

AdlibRegister($sAdlib, 4 * $iRatio)
Do
    If $fAdlibReReg Then
        $iCounter += 1
        AdlibRegister($sAdlib, $iCounter * $iRatio)
        $fAdlibReReg = False
    EndIf
until $iCounter > 6
AdlibUnRegister($sAdlib)
Exit

Func AdlibFunc()
    DebugOut('AdlibFunc(), ' & _TimerDiffRound($iTimer))
    $fAdlibReReg = True
EndFunc
Func _TimerDiffRound($time)
    Return Round(TimerDiff($time)/$iRatio)*$iRatio
EndFunc

Func DebugOut($sMsg)
    ConsoleWrite($sMsg & @CRLF)
EndFunc

---

On Hold: (something I don't get(yet) is bugging me ...)

Edited by MvGulik, 23 June 2012 - 09:05 PM.

[czardas]

I just ran a test on this. AdLibRegister appears to reset the time as expected, so I'm not sure what this is about.

AutoIt        expandcollapse  popup

AdlibRegister("MyAdlib", 2000)

Dim $iTimer = TimerInit()

Sleep(8100)
; 2 seconds
; 4 seconds
; 6 seconds
; 8 seconds

AdlibUnRegister("MyAdlib")
Sleep(1000) ; Following results should now return odd numbers
AdlibRegister("MyAdlib", 2000)

Sleep(8100)
; 11 seconds
; 13 seconds
; 15 seconds
; 17 seconds

Func MyAdlib()
    ConsoleWrite(Round(TimerDiff($iTimer)/1000) & " seconds" & @LF)
EndFunc

There's a few miliseconds processing time, but the rounded results turn from even to odd (on my machine) after re-registering the adlib.

The only thing I don't get is why this function is called adlib. To me this sounds like ad libitum (ad lib) meaning free rhythm, at your leisure - ie not accurate timing - quite the opposite of the function's description.

to play the passage in free time rather than in strict or "metronomic" tempo (a practice known as rubato when not expressly indicated by the composer);

Edited by czardas, 24 June 2012 - 09:50 AM.

[MvGulik]

Taking my time ... But your right that Adlib works as expected, when your using the adlib-reg's outside its own adlib-call scoop.
But when you use the additional AdlibRegister() commands inside its own adlib-call. It works a little differently.
The new adlib starting time-point will not be based on the moment the additional AdlibRegister() was issued. But it will be based on the start-time of the adlib-call (your currently are in).

Considering changing stuff on something, while using it, is generally not a good thing. (adlib or otherwise.) I think a general note about this in doc might not be bad thing.

Code used to check. (bug free I hope )

Spoiler

AutoIt        expandcollapse  popup

#AutoIt3Wrapper_AU3Check_Stop_OnWarning=y
#AutoIt3Wrapper_AU3Check_Parameters=-q -d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6 -w 7
;; Adlib re-reg call made outside own adlib call.

#cs    result: no additional 3sec simulated adlib-call work time.
AdlibFunc(), 400 .. (+4)
AdlibFunc(), 900 .. (+5)
AdlibFunc(), 1500 .. (+6)
#ce
#cs    result: with additional 3sec simulated adlib-call work time.
AdlibFunc(), 400 .. (+4)
AdlibFunc(), 1200 .. (+3+5)
AdlibFunc(), 2100 .. (+3+6)
#ce

Global Const $iRatio = 100 ;; 1000
Global Const $sAdlib = 'AdlibFunc'
Global $fAdlibReReg = False, $iTimer = 0, $iCounter = 0

$iCounter = 4
$iTimer = TimerInit()
AdlibRegister($sAdlib, $iCounter * $iRatio)
Do
    If $fAdlibReReg Then
        $iCounter += 1
        sleep(3*$iRatio) ;; some simulated processing time. (here or in AdlibFunc() Adlib-call.)
        AdlibRegister($sAdlib, $iCounter * $iRatio)
        $fAdlibReReg = False
    EndIf
until $iCounter > 6
AdlibUnRegister($sAdlib)
Exit

Func AdlibFunc()
    DebugOut('AdlibFunc(), ' & _TimerDiffRound($iTimer))
    $fAdlibReReg = True
EndFunc
Func _TimerDiffRound($time)
    Return Round(TimerDiff($time)/$iRatio)*$iRatio
EndFunc

Func DebugOut($sMsg)
    ConsoleWrite($sMsg & @CRLF)
EndFunc

AutoIt        expandcollapse  popup

#AutoIt3Wrapper_AU3Check_Stop_OnWarning=y
#AutoIt3Wrapper_AU3Check_Parameters=-q -d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6 -w 7
;; Adlib re-reg call made inside own adlib call.

#cs    result: no additional 3sec simulated adlib-call work time.
AdlibFunc(), 400 ... (+4)
AdlibFunc(), 900 ... (+5)
AdlibFunc(), 1500 ... (+6)
#ce
#cs    result: with additional 3sec simulated adlib-call work time.
AdlibFunc(), 400 ... (+4)
AdlibFunc(), 900 ... (+5)
AdlibFunc(), 1500 ... (+6)
#ce

Global Const $iRatio = 100 ;; 1000
Global Const $sAdlib = 'AdlibFunc'
Global $iTimer = 0, $iCounter = 0

$iCounter = 4
$iTimer = TimerInit()
AdlibRegister($sAdlib, $iCounter * $iRatio)
do
until $iCounter > 6
AdlibUnRegister($sAdlib)
Exit

Func AdlibFunc()
    DebugOut('AdlibFunc(), ' & _TimerDiffRound($iTimer))
    $iCounter += 1
    sleep(3*$iRatio) ;; some simulated processing time.
    AdlibRegister($sAdlib, $iCounter * $iRatio) ;; this one is not taking in account the fact that its delayed by the 3sec sleep.
EndFunc
Func _TimerDiffRound($time)
    Return Round(TimerDiff($time)/$iRatio)*$iRatio
EndFunc

Func DebugOut($sMsg)
    ConsoleWrite($sMsg & @CRLF)
EndFunc

NTS: Recheck AdlibUnRegister(). (seems all AdlibRegister() related at this point.)

[+code comment]

Edited by MvGulik, 25 June 2012 - 07:07 AM.

[czardas]

I get what you're saying, but I'm not sure of the cause. I wonder if this could be related to variable scope - I think it's a reasonable assumption, but without access to the source code it will always be guesswork.

Edited by czardas, 25 June 2012 - 07:57 AM.

[czardas]

I can confirm MvGulik's findings.

AutoIt        expandcollapse  popup

Global $bCorrupted = False, $iTimer = TimerInit()

_TestFunc()

Func _TestFunc()
    AdlibRegister("MyAdlib", 2000)
    For $i = 1 To 5
        Sleep(2000)
        ; The following line in this funtion updates start time as expected
        If Not $bCorrupted Then _CorruptTiming() ; Move this line to the function MyAdlib()
    Next
EndFunc

Func MyAdlib()
    ConsoleWrite(Round(TimerDiff($iTimer)/1000) & " seconds" & @LF)
    ; if you place the line here instead, AdlibRegister will not update the start time
    ;If Not $bCorrupted Then _CorruptTiming() ; Allow this line to run
EndFunc

Func _CorruptTiming()
    AdlibUnRegister("MyAdlib")
    Sleep(1000)
    AdlibRegister("MyAdlib", 2000)
    $bCorrupted = True
EndFunc

Edited by czardas, 25 June 2012 - 09:32 AM.

[Manadar]

The amount of time you sleep affects the adlib calls.

[czardas]

I think the tests are pretty conclusive. There's a 1000 ms disparity in my test. If the sleep and delay times are increased, the disparity appears to remain proportional to these increases, though I believe what you say - I don't get enough sleep.

Edited by czardas, 25 June 2012 - 09:19 AM.

[MvGulik]

The amount of time you sleep affects the adlib calls.

Feel free to elaborate on that a bit more. Its kinda very general to me.

[Manadar]

Never mind. It's simply a bug. Here is another fun one:

AdlibRegister("MyAdlib", 9999999999999999999)