Starting & Stopping within GUI

[kiffab]

Hi Guys

Building an app in work and need some expert assistance.

I have a GUI with a start/stop button. When I click it, it executes a function. This function reads a log and returns a status. I am using:

case $my_button
MyFunction()
AdlibRegister("My Function here", $interval)

$interval is just a refresh time like 10 secs, 20 secs etc.

If clicked a second time, I want it to STOP doing what it's doing. I'm not sure how to do this. The alternative is to just exit but I'd rather stop and remain in app.

Any help appreciated.

Thanks.

[Melba23]

kiffab,

Perhaps like this:

#include <GUIConstantsEx.au3>

$hGUI = GUICreate("Test", 500, 500)

$cButton = GUICtrlCreateButton("Run", 10, 10, 80, 30)

GUISetState()

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $cButton
            Switch GUICtrlRead($cButton)
                Case "Run"
                    MsgBox(0, "Hi", "Function Running")
                    AdlibRegister("_Run", 1000)
                    GUICtrlSetData($cButton, "Stop")
                Case "Stop"
                    MsgBox(0, "Hi", "Function Ended")
                    AdlibUnRegister("_Run")
                    GUICtrlSetData($cButton, "Run")
            EndSwitch
    EndSwitch

WEnd

Func _Run()
    ConsoleWrite("Running at " & @SEC & @CRLF)
EndFunc

Any help?

M23

[kiffab]

adlibunregister !!! DOH!!!

Thanks buddy

[kiffab]

One complication... I am using an image as my button.

Can the same thing be achieved?

The button has an initial stop type image (red light). When clicked, it changes to green (on).

Also, I should add it's not technically a "button" - I'm using GUICtrlCreatePic. Sorry.

Edited July 14, 2012 by kiffab

[Melba23]

kiffab,

I am using an image as my button. Can the same thing be achieved?

Very easily:

expandcollapse popup

#include <GUIConstantsEx.au3>

Global $iColour = "Red"

$sPath = StringRegExpReplace(@AutoItExe, "(^.*)(.*)", "1")
$sRed = $sPath & "ExamplesGUIAdvancedImagesRed.bmp"
$sGrn = $sPath & "ExamplesGUIAdvancedImagesGreen.bmp"

$hGUI = GUICreate("Test", 500, 500)

$cPic = GUICtrlCreatePic($sRed, 10, 10, 30, 30)

GUISetState()

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $cPic
            Switch $iColour
                Case "Red"
                    MsgBox(0, "Hi", "Function Running")
                    AdlibRegister("_Run", 1000)
                    GUICtrlSetImage($cPic, $sGrn)
                    $iColour = "Green"
                Case "Green"
                    MsgBox(0, "Hi", "Function Ended")
                    AdlibUnRegister("_Run")
                    GUICtrlSetImage($cPic, $sRed)
                    $iColour = "Red"
            EndSwitch
    EndSwitch

WEnd

Func _Run()
    ConsoleWrite("Running at " & @SEC & @CRLF)
EndFunc

M23

[kiffab]

Perfect! Works a treat and I understand exactly what you've done there. This will be useful for other parts of my app. Thank you