Issue with GuiCtrlsetColor

[GordonFreeman]

'>

The second time i try to set GuiCtrlsetColor to Green (0xFF00FF) and get this

Code

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$hGUI = GUICreate("",720,520,-1,-1)

GUICtrlCreateCheckbox("Test1",10,10,200,30)
GUICtrlSetFont(-1,12,"","","Latha",5)
GUICtrlSetColor(-1,0xFF00FF)

GUICtrlCreateCheckbox("TEST2",10,40,500,30)
GUICtrlSetFont(-1,12,"","","Latha",5)
GUICtrlSetColor(-1,0xA3A3A3)

;GUISetBkColor(0xFFFFFF,$hGUI)

GUISetState(@SW_SHOW)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

    EndSwitch
WEnd

Win7 x32 SP1 - 

Autoit 3.3.12.0

I already tried reboot, change some lines and the interface only look "normal" when i comment all SetColor functions.

Thanks in advance

Edited August 28, 2014 by GordonFreeman

[Melba23]

GordonFreeman,

 

Green (0xFF00FF)

As GUICtrlSetColor takes RGB colours, why would you expect 0xFF00FF to have any green in it at all?

Moving on, as the Help file clearly states: "Checkbox, Radio, Group Progress, Combo controls cannot be painted if the "Windows XP/Vista style" is used". So you need to remove the theme before colouring:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$hGUI = GUICreate("", 720, 520, -1, -1)

$cCheck_1 = GUICtrlCreateCheckbox("Test1", 10, 10, 200, 30)
GUICtrlSetFont($cCheck_1, 12, "", "", "Latha", 5)
DllCall("UxTheme.dll", "int", "SetWindowTheme", "hwnd", GUICtrlGetHandle($cCheck_1), "wstr", 0, "wstr", 0)
GUICtrlSetColor(-1, 0x00FF00) ; Green <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<

$cCheck_2 = GUICtrlCreateCheckbox("TEST2", 10, 40, 500, 30)
GUICtrlSetFont($cCheck_2, 12, "", "", "Latha", 5)
DllCall("UxTheme.dll", "int", "SetWindowTheme", "hwnd", GUICtrlGetHandle($cCheck_2), "wstr", 0, "wstr", 0) ; <<<<<<<<<<<<<<<<<<<<<<<<<
GUICtrlSetColor(-1, 0xA3A3A3)

GUISetState(@SW_SHOW)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

That gives me green text for the first checkbox.

M23

[GordonFreeman]

Thanks Melba! I am daltonian 0xFF00FF looks green for me 

[Melba23]

GordonFreeman,

Glad I could help.

M23