Run IExplorer in GUI ?

[BoBo]

hi

i have a little question...

is it possible to run the IExplorer inside the GUI???

Just a little window.

greetings BoBo

[GaryFrost]

In the beta version are the functions objcreate and GUICtrlCreateObj, that makes this possible here's the example from the help file in the beta

CODE

#include <GUIConstants.au3>

; Simple example: Embedding an Internet Explorer Object inside an AutoIt GUI

;

; The full example is available in the test\ActiveX directory (TestXInternet.au3)

;

; See also: http://msdn.microsoft.com/workshop/browser...netexplorer.asp

$oIE = ObjCreate("Shell.Explorer.2")

; Create a simple GUI for our output

GUICreate ( "Embedded Web control Test", 640, 580,(@DesktopWidth-640)/2, (@DesktopHeight-580)/2 , $WS_OVERLAPPEDWINDOW + $WS_VISIBLE + $WS_CLIPSIBLINGS)

$GUIActiveX = GUICtrlCreateObj ( $oIE, 10, 40 , 600 , 360 )

$GUI_Button_Back = GuiCtrlCreateButton ("Back", 10, 420, 100, 30)

$GUI_Button_Forward = GuiCtrlCreateButton ("Forward", 120, 420, 100, 30)

$GUI_Button_Home = GuiCtrlCreateButton ("Home", 230, 420, 100, 30)

$GUI_Button_Stop = GuiCtrlCreateButton ("Stop", 330, 420, 100, 30)

GUISetState () ;Show GUI

$oIE.navigate("http://www.autoitscript.com")

; Waiting for user to close the window

While 1

$msg = GUIGetMsg()

Select

Case $msg = $GUI_EVENT_CLOSE

ExitLoop

Case $msg = $GUI_Button_Home

$oIE.navigate("http://www.autoitscript.com")

Case $msg = $GUI_Button_Back

$oIE.GoBack

Case $msg = $GUI_Button_Forward

$oIE.GoForward

Case $msg = $GUI_Button_Stop

$oIE.Stop

EndSelect

Wend

GUIDelete ()

Exit