OnClick of Combobox

[LurchMan]

Hello Everyone - 

I have a small application that has a combo box that I would like to have it automatically update the list it contains each time the user clicks on the down arrow.  The data comes from a SQLite database.  I have attempted to use WM_NOTIFY with the below code:

Func WM_NOTIFY($hWnd, $iMsg, $iwParam, $ilParam)
    #forceref $hWnd, $iMsg, $iwParam
    Local $hWndFrom, $iIDFrom, $iCode, $tNMHDR, $hWndListView, $tInfo

    $tNMHDR = DllStructCreate($tagNMHDR, $ilParam)
    $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
    $iIDFrom = DllStructGetData($tNMHDR, "IDFrom")
    $iCode = DllStructGetData($tNMHDR, "Code")

    If $iCode = $NM_CLICK Then
        Switch $hWndFrom
            Case GUICtrlGetHandle($inPrs_EmpName)
                ConsoleWrite("you click on Processing Stats Combo" & @CRLF)
            Case GUICtrlGetHandle($inPS_EmpName)
                ConsoleWrite("you click on Phone Stats Combo" & @CRLF)
            Case GUICtrlGetHandle($inPE_EmpName)
                ConsoleWrite("you click on Phone Eval Combo" & @CRLF)
        EndSwitch
    EndIf

    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_NOTIFY

I can't seem to get any response out of the combobox.  Any Ideas?  Thanks for the help in advance. 

[Melba23]

LurchMan,

You need to register WM_COMMAND:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <WinAPI.au3>
#include <ComboConstants.au3>

$hGUI = GUICreate("Test", 500, 500)

$cCombo_1 = GUICtrlCreateCombo("", 10, 10, 200, 20)
GUICtrlSetData($cCombo_1, "1|2|3|4")
$cCombo_2 = GUICtrlCreateCombo("", 10, 50, 200, 20)
GUICtrlSetData($cCombo_2, "A|B|C|D")
$cCombo_3 = GUICtrlCreateCombo("", 10, 90, 200, 20)
GUICtrlSetData($cCombo_3, "10|20|30|40")

GUISetState()

GUIRegisterMsg($WM_COMMAND, "_WM_COMMAND")

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

Func _WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)

    If _WinAPI_HiWord($wParam) = $CBN_DROPDOWN Then
        Switch _WinAPI_LoWord($wParam)
            Case $cCombo_1
                ConsoleWrite("Combo_1 Dropped" & @CRLF)
            Case $cCombo_2
                ConsoleWrite("Combo_2 Dropped" & @CRLF)
            Case $cCombo_3
                ConsoleWrite("Combo_3 Dropped" & @CRLF)
        EndSwitch
    EndIf

EndFunc

That works for me.

M23

[LurchMan]

Melba23, once again you have made my GUI's much more functional! Thank you for the help!

[Melba23]

LurchMan,

Always a pleasure.

M23