Smtp Mailer That Supports Html And Attachments.

[saywell]

Is there any way to add a reply-to address?

My users send photos via a shared gmail account, but I'd like to set up an auto-response in my email account to automagically send a 'received' message to the sender's own email account.

Thanks,

William

[Jos]

Just update the UDF with:

$objEmail.ReplyTo = "replyto@domain.com"

Jos

[saywell]

Thanks Jos - That works as intended from the scripting point of view.  Reply-to address added correctly.

Sadly gmail's servers ignore the reply-to address when sending automatic responses [anti-spam].  But at least a manual reply works to that address, so still some benefit.

William

[Noviceatthis]

Thanks Jos, Works very well

Im just having a slight issue and, forgive me if this is a stupid question, but:

$Body = "Hello" & @CRLF & "        This is a new line"

The spaces before the second part of the string do not appear to sending, the second line just starts with the text. I was wondering whether there was a solution to this, Its just to get a nice Indent at the start of the second  line of of the email.

Thanks in advance.

Edited January 22, 2014 by Noviceatthis

[mLipok]

I have a question:

Does _INetSmtpMailCom () uses by any means and is dependent on the RPC server ?

[Jos]

Thanks Jos, Works very well

Im just having a slight issue and, forgive me if this is a stupid question, but:

$Body = "Hello" & @CRLF & "        This is a new line"

The spaces before the second part of the string do not appear to sending, the second line just starts with the text. I was wondering whether there was a solution to this, Its just to get a nice Indent at the start of the second  line of of the email.

Thanks in advance.

Have you tried using HTML coding for the spaces?

[Jos]

 

I have a question:

Does _INetSmtpMailCom () uses by any means and is dependent on the RPC server ?

 

It uses the standard CDO.Message COM object

[Noviceatthis]

No I havn't, i'll give that a go, thanks

[Morronic]

expandcollapse popup

;##################################
; Include
;##################################
#Include <file.au3>
#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
;##################################
; Main Window For Input Email and Body
;##################################

Func sendMail()
Global $fileVer = "1.0"
$Form1 = GUICreate("Mailer V" & $fileVer, 921, 701, -1, -1)
GUISetFont(10, 400, 0, "Times New Roman")
Global $inputEmail = GUICtrlCreateInput("", 408, 56, 217, 23)
Global $inputSubject = GUICtrlCreateInput("", 408, 96, 217, 23)
Global $inputMessage = GUICtrlCreateEdit("", 144, 152, 649, 409, $ES_WANTRETURN)
$buttonSend = GUICtrlCreateButton("Send", 536, 600, 105, 33)
$Label1 = GUICtrlCreateLabel("Enter Client's Email:", 272, 56, 124, 23)
GUICtrlSetFont(-1, 12, 400, 0, "Times New Roman")
$Label2 = GUICtrlCreateLabel("Message:", 48, 304, 73, 25)
GUICtrlSetFont(-1, 14, 400, 0, "Times New Roman")
$buttonCancel = GUICtrlCreateButton("Cancel", 224, 600, 105, 33)
$Label3 = GUICtrlCreateLabel("Enter Subject:", 288, 96, 89, 23)
GUICtrlSetFont(-1, 12, 400, 0, "Times New Roman")
GUISetState(@SW_SHOW)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $buttonSend
            ExitLoop
        Case $buttonCancel
            Exit
    EndSwitch
WEnd
EndFunc

;##################################
; Variables
;##################################
$SmtpServer = "smtp.Example.com"              ; address for the smtp-server to use - REQUIRED
$FromName = "Example"                      ; name from who the email was sent
$FromAddress = "Example@Example.com" ; address from where the mail should come
$AttachFiles = ""                       ; the file(s) you want to attach seperated with a ; (Semicolon) - leave blank if not needed
$CcAddress = ""       ; address for cc - leave blank if not needed
$BccAddress = ""     ; address for bcc - leave blank if not needed
$Importance = "Normal"                  ; Send message priority: "High", "Normal", "Low"
$Username = "Example@Example.com"           ; username for the account used from where the mail gets sent - REQUIRED
$Password = "********"                  ; password for the account used from where the mail gets sent - REQUIRED
$IPPort = 465                            ; port used for sending the mail
$ssl = 1                                ; enables/disables secure socket layer sending - put to 1 if using httpS
;~ $IPPort=465                          ; GMAIL port used for sending the mail
;~ $ssl=1                               ; GMAILenables/disables secure socket layer sending - put to 1 if using httpS
;##################################
; Script
;##################################

sendMail()
$Subject = GUICtrlRead($inputSubject)   ; subject from the email - can be anything you want it to be
$Body = GUICtrlRead($inputMessage)      ; the messagebody from the mail - can be left blank but then you get a blank mail
$ToAddress = GUICtrlRead($inputEmail)   ; destination address of the email - REQUIRED
Global $oMyRet[2]
Global $oMyError = ObjEvent("AutoIt.Error", "MyErrFunc")
$rc = _INetSmtpMailCom($SmtpServer, $FromName, $FromAddress, $ToAddress, $Subject, $Body, $AttachFiles, $CcAddress, $BccAddress, $Importance, $Username, $Password, $IPPort, $ssl)
If @error Then
    MsgBox(0, "Error sending message", "Error code:" & @error & "  Description:" & $rc)
EndIf
;
; The UDF
Func _INetSmtpMailCom($s_SmtpServer, $s_FromName, $s_FromAddress, $s_ToAddress, $s_Subject = "", $as_Body = "", $s_AttachFiles = "", $s_CcAddress = "", $s_BccAddress = "", $s_Importance="Normal", $s_Username = "", $s_Password = "", $IPPort = 25, $ssl = 0)
    Local $objEmail = ObjCreate("CDO.Message")
    $objEmail.From = '"' & $s_FromName & '" <' & $s_FromAddress & '>'
    $objEmail.To = $s_ToAddress
    Local $i_Error = 0
    Local $i_Error_desciption = ""
    If $s_CcAddress <> "" Then $objEmail.Cc = $s_CcAddress
    If $s_BccAddress <> "" Then $objEmail.Bcc = $s_BccAddress
    $objEmail.Subject = $s_Subject
    If StringInStr($as_Body, "<") And StringInStr($as_Body, ">") Then
        $objEmail.HTMLBody = $as_Body
    Else
        $objEmail.Textbody = $as_Body & @CRLF
    EndIf
    If $s_AttachFiles <> "" Then
        Local $S_Files2Attach = StringSplit($s_AttachFiles, ";")
        For $x = 1 To $S_Files2Attach[0]
            $S_Files2Attach[$x] = _PathFull($S_Files2Attach[$x])
;~          ConsoleWrite('@@ Debug : $S_Files2Attach[$x] = ' & $S_Files2Attach[$x] & @LF & '>Error code: ' & @error & @LF) ;### Debug Console
            If FileExists($S_Files2Attach[$x]) Then
                ConsoleWrite('+> File attachment added: ' & $S_Files2Attach[$x] & @LF)
                $objEmail.AddAttachment($S_Files2Attach[$x])
            Else
                ConsoleWrite('!> File not found to attach: ' & $S_Files2Attach[$x] & @LF)
                SetError(1)
                Return 0
            EndIf
        Next
    EndIf
    $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
    $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpserver") = $s_SmtpServer
    If Number($IPPort) = 0 then $IPPort = 25
    $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = $IPPort
    ;Authenticated SMTP
    If $s_Username <> "" Then
        $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = 1
        $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendusername") = $s_Username
        $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/sendpassword") = $s_Password
    EndIf
    If $ssl Then
        $objEmail.Configuration.Fields.Item ("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = True
    EndIf
    ;Update settings
    $objEmail.Configuration.Fields.Update
    ; Set Email Importance
    Switch $s_Importance
        Case "High"
            $objEmail.Fields.Item ("urn:schemas:mailheader:Importance") = "High"
        Case "Normal"
            $objEmail.Fields.Item ("urn:schemas:mailheader:Importance") = "Normal"
        Case "Low"
            $objEmail.Fields.Item ("urn:schemas:mailheader:Importance") = "Low"
    EndSwitch
    $objEmail.Fields.Update
    ; Sent the Message
    $objEmail.Send
    If @error Then
        SetError(2)
        Return $oMyRet[1]
    EndIf
    $objEmail=""
EndFunc   ;==>_INetSmtpMailCom
;
;
; Com Error Handler
Func MyErrFunc()
    $HexNumber = Hex($oMyError.number, 8)
    $oMyRet[0] = $HexNumber
    $oMyRet[1] = StringStripWS($oMyError.description, 3)
    ConsoleWrite("### COM Error !  Number: " & $HexNumber & "   ScriptLine: " & $oMyError.scriptline & "   Description:" & $oMyRet[1] & @LF)
    SetError(1); something to check for when this function returns
    Return
EndFunc   ;==>MyErrFunc

In case anyone wants it I made a basic GUI to the program. Obviously before you compile or run change the settings such as port #, server, Email address, etc. Of course any issues let me know or yell at me for my horrible code 

Anyway hope it helps someone 

[Allow2010]

i have an issue here that i do not understand, maybe someone can explain ist to me:

Sending mail with this function works fine, as long as i send less than 10241 characters.

When sending more than 10240 characters i get an error code 2 saying that the connection to the server was interrupted.

Is this a limitation of the smtp connection and how can i prevent it? When sending a file attachment i  do not have this problem, and also not when sending the text by any other mail program.

Any ideas? Thanks !

[Allow2010]

found the solution: you can not send a line with more than 10240 characters.

To prevent that just make sure you have some @crlf characters in you text to break it into smaller lines...thats all.

As i constructed my html email from textlines that i combindes with "<br>" i never had any @crlf chracters in the text. Now i just combine the textlines with "<br>" & @crlf and everthing works just fine...

[DLXS]

Hi,

Can't make it work with gmail dunno why:(

With SSL = 0 I get this:

 

If I put SSL = 1 then:

All settings seems ok to me:

$SmtpServer = "smtp.gmail.com"              ; address for the smtp-server to use - REQUIRED
$FromName = "Name"                      ; name from who the email was sent
$FromAddress = "MYEMAILHERE@gmail.com" ; address from where the mail should come
$ToAddress = "MYEMAILHERE@gmail.com"   ; destination address of the email - REQUIRED
$Subject = "Userinfo"                   ; subject from the email - can be anything you want it to be
$Body = ""                              ; the messagebody from the mail - can be left blank but then you get a blank mail
$AttachFiles = ""                       ; the file(s) you want to attach seperated with a ; (Semicolon) - leave blank if not needed
$CcAddress = ""       ; address for cc - leave blank if not needed
$BccAddress = ""     ; address for bcc - leave blank if not needed
$Importance = "Normal"                  ; Send message priority: "High", "Normal", "Low"
$Username = "MYEMAILHERE@gmail.com"                    ; username for the account used from where the mail gets sent - REQUIRED
$Password = "MYPASSWASHERETOO"                  ; password for the account used from where the mail gets sent - REQUIRED
$IPPort = 465                            ; port used for sending the mail
$ssl = 1

What shall I do?

edit: ## COM Error !  Number: 80020009   ScriptLine: 92   Description:The message could not be sent to the SMTP server. The transport error code was 0x80040217. The server response was not available

Also, just read I need CDO.dll. Didn't have a clue. will check because I can't install it omfg Ideas?

Edited April 27, 2014 by DLXS

[Jos]

Try using the Username without the @gmail.com part.

Show me your total script to ensure there are no other issues.

Jos

Edited April 27, 2014 by Jos

[lifesux]

Hi,

Can't make it work with gmail dunno why:(

With SSL = 0 I get this:

 

If I put SSL = 1 then:

All settings seems ok to me:

$SmtpServer = "smtp.gmail.com"              ; address for the smtp-server to use - REQUIRED
$FromName = "Name"                      ; name from who the email was sent
$FromAddress = "MYEMAILHERE@gmail.com" ; address from where the mail should come
$ToAddress = "MYEMAILHERE@gmail.com"   ; destination address of the email - REQUIRED
$Subject = "Userinfo"                   ; subject from the email - can be anything you want it to be
$Body = ""                              ; the messagebody from the mail - can be left blank but then you get a blank mail
$AttachFiles = ""                       ; the file(s) you want to attach seperated with a ; (Semicolon) - leave blank if not needed
$CcAddress = ""       ; address for cc - leave blank if not needed
$BccAddress = ""     ; address for bcc - leave blank if not needed
$Importance = "Normal"                  ; Send message priority: "High", "Normal", "Low"
$Username = "MYEMAILHERE@gmail.com"                    ; username for the account used from where the mail gets sent - REQUIRED
$Password = "MYPASSWASHERETOO"                  ; password for the account used from where the mail gets sent - REQUIRED
$IPPort = 465                            ; port used for sending the mail
$ssl = 1

What shall I do?

edit: ## COM Error !  Number: 80020009   ScriptLine: 92   Description:The message could not be sent to the SMTP server. The transport error code was 0x80040217. The server response was not available

Also, just read I need CDO.dll. Didn't have a clue. will check because I can't install it omfg Ideas?

same

[Jos]

same

Great info ... so SAME reply for you:

Did you do what I suggested?

..else show me your script.

Jos

Edited May 3, 2014 by Jos

[Wombat]

So I just recently updated my version of autoit to the latest public release, and as I began going over the code of my older apps to make sure they still worked I noticed that your smtp mail client is error~ing in a rather odd manner.

If I take the code in your first post in this thread (which I assume to be the latest version) and run it through the syntax check it produces this:

>"C:\Program Files (x86)\AutoIt3\SciTE\AutoIt3Wrapper\AutoIt3Wrapper.exe" /prod /AU3Check /in "P:\Workshop\SMTPmail.au3"
+>18:35:14 Starting AutoIt3Wrapper v.2.2.0.0 SciTE v.3.4.1.0   Keyboard:00000409  OS:WIN_7/Service Pack 1  CPU:X64 OS:X64    Environment(Language:0409)
+>         SciTEDir => C:\Program Files (x86)\AutoIt3\SciTE   UserDir => C:\Users\someone\AppData\Local\AutoIt v3\SciTE\AutoIt3Wrapper   SCITE_USERHOME => C:\Users\someone\AppData\Local\AutoIt v3\SciTE 
>Running AU3Check (3.3.12.0)  from:C:\Program Files (x86)\AutoIt3  input:P:\Workshop\SMTPmail.au3
"P:\Workshop\SMTPmail.au3"(40,15) : error: missing separator character before keyword.
    $objEmail.To
~~~~~~~~~~~~~~^
P:\Workshop\SMTPmail.au3 - 1 error(s), 0 warning(s)
!>18:35:14 AU3Check ended. Press F4 to jump to next error.rc:2
+>18:35:14 AutoIt3Wrapper Finished.
>Exit code: 0    Time: 0.8978

But if I change $objEmail.To to $objEmail.ReplyTo it does not error out and indeed works. Why is this?

As I said, I did not alter anything about your code in the first post and it produced an error.

Edited June 12, 2014 by Wombat

[BrewManNH]

Its a bug in Au3Check, not in the script. This bug I believe may have been fixed already, but even if it hasn't, you can safely ignore it, or make it so that Au3Check doesn't run every time.

[Wombat]

But I use Au3Check to check my code for anything I may have missed. Is there a way to flag that line of code to be ignored by Au3Check? Possibly in the same way you would comment out something...

[BrewManNH]

http://www.autoitscript.com/autoit3/scite/download/beta_SciTE4AutoIt3/Au3Check.exe

Updated beta version of Au3Check that should contain a fix for that.

BTW, when someone says there's probably been a fix for something, you should probably go look for the fix. Look in the BugTracker, usually under Fixed Bugs. After all, that's what the BugTracker link is there for, to report bugs and see if there's been a fix to a bug you think is happening.

[Wombat]

I apologize, I indeed should have paid better attention to your response.