14 replies to this topic

[skyee]

This is the current font install script:

$sFileName = '\\server.local\Software\_Install\_Default\1\CORPORATE FONT\*.*'
            If FileCopy($sFileName, @WindowsDir & '\Fonts',1) Then
            $sFileName = @WindowsDir & '\Fonts\' & StringTrimLeft($sFileName, StringInStr($sFileName, '\', 0, -1))
            DllCall('gdi32', 'long', "AddFontResourceA", 'String', $sFileName)
            EndIf

The fonts get copied, however they're not registred with system when I try to use them in i.e. MS Word. What else needs to be done?

[MrCreatoR]

Hi,

This function should work (not mine, i just modified a little)...

Func InstallFont($sSourceFile, $sFontDescription, $sFontsPath)
    Local Const $HWND_BROADCAST = 0xFFFF
    Local Const $WM_FONTCHANGE = 0x1D
    
    Local $sFontFileName = StringRegExpReplace($sSourceFile, '^.*\\', '')
    If Not FileCopy($sSourceFile, $sFontsPath & "\" & $sFontFileName, 1) Then Return SetError(1, 0, 0)
    
    Local $aRet = DllCall("gdi32.dll", "Int", "AddFontResource", "str", @WindowsDir & "\fonts\" & $sFontFileName)
    If IsArray($aRet) And $aRet[0] > 0 Then
        RegWrite("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Fonts", $sFontDescription, "REG_SZ", $sFontFileName)
        DllCall("user32.dll", "Int", "SendMessage", "hwnd", $HWND_BROADCAST, "int", $WM_FONTCHANGE, "int", 0, "int", 0)
        Return 1
    EndIf
    Return SetError(2, 0, 0)
EndFunc

[skyee]

Hi,

This function should work (not mine, i just modified a little)...

Func InstallFont($sSourceFile, $sFontDescription, $sFontsPath)
    Local Const $HWND_BROADCAST = 0xFFFF
    Local Const $WM_FONTCHANGE = 0x1D
    
    Local $sFontFileName = StringRegExpReplace($sSourceFile, '^.*\\', '')
    If Not FileCopy($sSourceFile, $sFontsPath & "\" & $sFontFileName, 1) Then Return SetError(1, 0, 0)
    
    Local $aRet = DllCall("gdi32.dll", "Int", "AddFontResource", "str", @WindowsDir & "\fonts\" & $sFontFileName)
    If IsArray($aRet) And $aRet[0] > 0 Then
        RegWrite("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Fonts", $sFontDescription, "REG_SZ", $sFontFileName)
        DllCall("user32.dll", "Int", "SendMessage", "hwnd", $HWND_BROADCAST, "int", $WM_FONTCHANGE, "int", 0, "int", 0)
        Return 1
    EndIf
    Return SetError(2, 0, 0)
EndFunc

Do you mind modifying this to enter source of my fonts? (\\server.local\Software\_Install\_Default\1\CORPORATE FONT\) since I admit have no clue where to put source from where script will get fonts?

[skyee]

Do you mind modifying this to enter source of my fonts? (\\server.local\Software\_Install\_Default\1\CORPORATE FONT\) since I admit have no clue where to put source from where script will get fonts?

I tried this:

Func InstallFont($sSourceFile, $sFontDescription, $sFontsPath)
    Local Const $HWND_BROADCAST = 0xFFFF
    Local Const $WM_FONTCHANGE = 0x1D

    Local $sFontsPath = "\\server.local\Software\_Install\_Default\1\CORPORATE FONT\"
    Local $sFontFileName = StringRegExpReplace($sSourceFile, '^.*\\', '')
    If Not FileCopy($sSourceFile, $sFontsPath & "\" & $sFontFileName, 1) Then Return SetError(1, 0, 0)
   
    Local $aRet = DllCall("gdi32.dll", "Int", "AddFontResource", "str", @WindowsDir & "\fonts\" & $sFontFileName)
    If IsArray($aRet) And $aRet[0] > 0 Then
        RegWrite("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Fonts", $sFontDescription, "REG_SZ", $sFontFileName)
        DllCall("user32.dll", "Int", "SendMessage", "hwnd", $HWND_BROADCAST, "int", $WM_FONTCHANGE, "int", 0, "int", 0)
        Return 1
    EndIf
    Return SetError(2, 0, 0)
EndFunc

But it doesn't work I would _really_ like someone to help me out here.. Fonts just dont seem to install. And I'm a script noobie

[skyee]

Anyone?

[Jos]

I guess it should be something like this (untested):

InstallFont('\\server.local\Software\_Install\_Default\1\CORPORATE FONT\fontname.ttf',"font description")

Func InstallFont($sSourceFile, $sFontDescription)
    Local Const $HWND_BROADCAST = 0xFFFF
    Local Const $WM_FONTCHANGE = 0x1D
    
    Local $sFontFileName = StringRegExpReplace($sSourceFile, '^.*\\', '')
    If Not FileCopy($sSourceFile, @WindowsDir & "\fonts\" & $sFontFileName, 1) Then Return SetError(1, 0, 0)
    
    Local $aRet = DllCall("gdi32.dll", "Int", "AddFontResource", "str", @WindowsDir & "\fonts\" & $sFontFileName)
    If IsArray($aRet) And $aRet[0] > 0 Then
        RegWrite("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Fonts", $sFontDescription, "REG_SZ", $sFontFileName)
        DllCall("user32.dll", "Int", "SendMessage", "hwnd", $HWND_BROADCAST, "int", $WM_FONTCHANGE, "int", 0, "int", 0)
        Return 1
    EndIf
    Return SetError(2, 0, 0)
EndFunc

[MrCreatoR]

I changed the function, so now it can install more then one font (if passing wildcard as file name)...

AutoIt        expandcollapse  popup

InstallFont("\\server.local\Software\_Install\_Default\1\CORPORATE FONT\*.*")

Func InstallFont($sSourceFile, $sFontDescript="", $sFontsPath="")
    Local Const $HWND_BROADCAST = 0xFFFF
    Local Const $WM_FONTCHANGE = 0x1D
    
    If $sFontsPath = "" Then $sFontsPath = @WindowsDir & "\fonts"
    
    Local $sFontName = StringRegExpReplace($sSourceFile, "^.*\\", "")
    If Not FileCopy($sSourceFile, $sFontsPath & "\" & $sFontName, 1) Then Return SetError(1, 0, 0)
    
    Local $hSearch = FileFindFirstFile($sSourceFile)
    Local $iFontIsWildcard = StringRegExp($sFontName, "\*|\?")
    Local $aRet, $hGdi32_DllOpen = DllOpen("gdi32.dll")
    
    If $hSearch = -1 Then Return SetError(2, 0, 0)
    If $hGdi32_DllOpen = -1 Then Return SetError(3, 0, 0)
    
    While 1
        $sFontName = FileFindNextFile($hSearch)
        If @error Then ExitLoop
        
        If $iFontIsWildcard Then $sFontDescript = StringRegExpReplace($sFontName, "\.[^\.]*$", "")
        
        $aRet = DllCall($hGdi32_DllOpen, "Int", "AddFontResource", "str", $sFontsPath & "\" & $sFontName)
        If IsArray($aRet) And $aRet[0] > 0 Then
            RegWrite("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Fonts", _
                $sFontDescript, "REG_SZ", $sFontsPath & "\" & $sFontName)
        EndIf
    WEnd
    
    DllClose($hGdi32_DllOpen)
    DllCall("user32.dll", "Int", "SendMessage", "hwnd", $HWND_BROADCAST, "int", $WM_FONTCHANGE, "int", 0, "int", 0)
    Return 1
EndFunc

Edit: changed to DllOpen mode.
Edit 2: Added full path writing (to registry), in case that we want to install font to other path then @WindowsDir\fonts.

Edited by MsCreatoR, 23 January 2008 - 03:41 PM.

[skyee]

I changed the function, so now it can install more then one font (if passing wildcard as file name)...

AutoIt        expandcollapse  popup

InstallFont("\\server.local\Software\_Install\_Default\1\CORPORATE FONT\*.*")

Func InstallFont($sSourceFile, $sFontDescript="", $sFontsPath="")
    Local Const $HWND_BROADCAST = 0xFFFF
    Local Const $WM_FONTCHANGE = 0x1D
    
    If $sFontsPath = "" Then $sFontsPath = @WindowsDir & "\fonts"
    
    Local $sFontName = StringRegExpReplace($sSourceFile, "^.*\\", "")
    If Not FileCopy($sSourceFile, $sFontsPath & "\" & $sFontName, 1) Then Return SetError(1, 0, 0)
    
    Local $hSearch = FileFindFirstFile($sSourceFile)
    Local $iFontIsWildcard = StringRegExp($sFontName, "\*|\?")
    Local $aRet, $hGdi32_DllOpen = DllOpen("gdi32.dll")
    
    If $hSearch = -1 Then Return SetError(2, 0, 0)
    If $hGdi32_DllOpen = -1 Then Return SetError(3, 0, 0)
    
    While 1
        $sFontName = FileFindNextFile($hSearch)
        If @error Then ExitLoop
        
        If $iFontIsWildcard Then $sFontDescript = StringRegExpReplace($sFontName, "\.[^\.]*$", "")
        
        $aRet = DllCall($hGdi32_DllOpen, "Int", "AddFontResource", "str", $sFontsPath & "\" & $sFontName)
        If IsArray($aRet) And $aRet[0] > 0 Then
            RegWrite("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Fonts", _
                $sFontDescript, "REG_SZ", $sFontsPath & "\" & $sFontName)
        EndIf
    WEnd
    
    DllClose($hGdi32_DllOpen)
    DllCall("user32.dll", "Int", "SendMessage", "hwnd", $HWND_BROADCAST, "int", $WM_FONTCHANGE, "int", 0, "int", 0)
    Return 1
EndFunc

Edit: changed to DllOpen mode.
Edit 2: Added full path writing (to registry), in case that we want to install font to other path then @WindowsDir\fonts.

Excellent work! Thank you so much

[Ármányos Kő]

I changed the function, so now it can install more then one font (if passing wildcard as file name)...

AutoIt        expandcollapse  popup

InstallFont("\\server.local\Software\_Install\_Default\1\CORPORATE FONT\*.*")

Func InstallFont($sSourceFile, $sFontDescript="", $sFontsPath="")
    Local Const $HWND_BROADCAST = 0xFFFF
    Local Const $WM_FONTCHANGE = 0x1D
    
    If $sFontsPath = "" Then $sFontsPath = @WindowsDir & "\fonts"
    
    Local $sFontName = StringRegExpReplace($sSourceFile, "^.*\\", "")
    If Not FileCopy($sSourceFile, $sFontsPath & "\" & $sFontName, 1) Then Return SetError(1, 0, 0)
    
    Local $hSearch = FileFindFirstFile($sSourceFile)
    Local $iFontIsWildcard = StringRegExp($sFontName, "\*|\?")
    Local $aRet, $hGdi32_DllOpen = DllOpen("gdi32.dll")
    
    If $hSearch = -1 Then Return SetError(2, 0, 0)
    If $hGdi32_DllOpen = -1 Then Return SetError(3, 0, 0)
    
    While 1
        $sFontName = FileFindNextFile($hSearch)
        If @error Then ExitLoop
        
        If $iFontIsWildcard Then $sFontDescript = StringRegExpReplace($sFontName, "\.[^\.]*$", "")
        
        $aRet = DllCall($hGdi32_DllOpen, "Int", "AddFontResource", "str", $sFontsPath & "\" & $sFontName)
        If IsArray($aRet) And $aRet[0] > 0 Then
            RegWrite("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Fonts", _
                $sFontDescript, "REG_SZ", $sFontsPath & "\" & $sFontName)
        EndIf
    WEnd
    
    DllClose($hGdi32_DllOpen)
    DllCall("user32.dll", "Int", "SendMessage", "hwnd", $HWND_BROADCAST, "int", $WM_FONTCHANGE, "int", 0, "int", 0)
    Return 1
EndFunc

Edit: changed to DllOpen mode.
Edit 2: Added full path writing (to registry), in case that we want to install font to other path then @WindowsDir\fonts.

This is excellent!
How would the deinstalling look like? I tried many basic things (deleting from font directory...), but surely they did not work.
I need to do something like Suitcase does on Mac.

[bluespirit]

Hi,

I'm trying to extract the font name out of a .ttf file to enter the correct info into the registry. Anyone know how to do this?

I'm installing the fonts using the AddFontResource DLL call, Registry write and SendMessage DLL call method as described below. However, this relies on you already knowing the font name. I was also going to rename the .ttf file with the full name before installing.

The best I've managed to find is a GetFontName function by Holger but this only works once the font is already installed or in memory.


Thanks for any help,
James

[DangerousDan]

nice find, I am adding this later since I have been trying to use fileinstall by itself. new to scripting as well and this autoit thing is aswesome!

I usually veiw the files from the dos prompt to get actual file names...

[ProgAndy]

Here is a full install routine for TTF fonts in VB : http://www.codeguru.com/vb/gen/vb_system/w...icle.php/c1659/
Basically, a .FOT font resource is created and installed. From this, the font name is being extracted

Edited by ProgAndy, 24 June 2008 - 06:12 PM.

[DangerousDan]

are you guys having to restart after using this function to install a font? I am...

[jennico]

very nice work ! thx. j.

[Myicq]

How would the deinstalling look like? I tried many basic things (deleting from font directory...), but surely they did not work.

I have not tried this, but guess that mostly same code can be used.
You have

BOOL RemoveFontResource(
  __in  LPCTSTR lpFileName
);

See: http://msdn.microsoft.com/en-us/library/windows/desktop/dd162922%28v=vs.85%29.aspx

My steps would be

• From registry find full path name(s)
• Call above DLL
• Remove registry entry
• Delete file
• Send broadcast message WM_FONTCHANGE

Not sure if you need to use RemoveFontResource or RemoveFontResource[A|W] for Ansi/Unicode.
Code from MrCreator should be simple to modify.

Good luck.