139 replies to this topic

[Yashied]

LAST VERSION - 1.7 / 2.0b
17-Oct-11

The library allows to set hotkeys by using the low-level keyboard hook. Below are the main differences between HotKey UDF from the native HotKeySet() function.

• To assign a hotkeys are used integer values ​​instead of strings as in the HotKeySet() function. This is useful, for example, to save the hotkey's values in the registry.
• Ability to set any hotkeys including CTRL+ALT+DEL, F12, WIN+*, etc. The only exceptions are special keys such as "Fn" which do not have their own scan code.
• Ability to utilize or pass on the specified hotkeys for other applications.
• Ability to set hotkeys that already used by other applications.
• Ability to set hotkeys only for the specified window(s).
• Ability to prevent re-activation of the hotkeys when it is held down.
• Ability to disable previously installed hotkeys without removing the hook from the hook chain, ie without losing priority.
• Ability to block call user-defined function associated with the hotkey if the previous call has not been completed.

Here is what you can not do by using this library.

• Set hotkey only for the CTRL, ALT, SHIFT, WIN, and any combination of this keys. Any hotkey should always include one function key. For example, ALT+A, CTRL+SHIFT+F10, etc.
• Set hotkey for a mouse buttons.
• Prevent using the hotkey like CTRL+ALT+DEL, CTRL+SHIFT+ESC (Windows Vista+), and similar.
• Use more than one function key in the hotkey. For example, ALT+A+B, F1+F2, etc.
• Use "Fn" key or any other keys that do not have their own scan code.

HotKey UDF Library v1.7
(Previous downloads: 2618)

 HotKey.au3   24.32K   1735 downloads


HotKey UDF Library v2.0b (Read here for more information)
(Previous downloads: 289)

 HotKey_20b.au3   25.29K   1082 downloads


Virtual-Key (VK) Code Constants (Optional)
(Previous downloads: 1576)

 vkConstants.au3   5.62K   1125 downloads


Example1

Spoiler

AutoIt        expandcollapse  popup

#Include <HotKey.au3>

Global Const $VK_ESCAPE = 0x1B
Global Const $VK_F12 = 0x7B

; Assign "F12" with Message() and set extended function call
_HotKey_Assign($VK_F12, 'Message', BitOR($HK_FLAG_DEFAULT, $HK_FLAG_EXTENDEDCALL))

; Assign "CTRL-ESC" with Quit()
_HotKey_Assign(BitOR($CK_CONTROL, $VK_ESCAPE), 'Quit')

While 1
    Sleep(10)
WEnd

Func Message($iKey)
    MsgBox(0, 'Hot key Test Message', 'F12 (0x' & Hex($iKey, 4) & ') has been pressed!')
EndFunc   ;==>Message

Func Quit()
    Exit
EndFunc   ;==>Quit

Example2

Spoiler

AutoIt        expandcollapse  popup

#Include <HotKey.au3>

Global Const $VK_OEM_PLUS = 0xBB
Global Const $VK_OEM_MINUS = 0xBD

Global $Form, $Label
Global $i = 0

$Form = GUICreate('MyGUI', 200, 200)
$Label = GUICtrlCreateLabel($i, 20, 72, 160, 52, 0x01)
GUICtrlSetFont(-1, 32, 400, 0, 'Tahoma')
GUISetState()

; Assign "CTRL-(+)" with MyFunc1() and "CTRL-(-)" with MyFunc2() for created window only
_HotKey_Assign(BitOR($CK_CONTROL, $VK_OEM_PLUS), 'MyFunc1', 0, $Form)
_HotKey_Assign(BitOR($CK_CONTROL, $VK_OEM_MINUS), 'MyFunc2', 0, $Form)

Do
Until GUIGetMsg() = -3

Func MyFunc1()
    $i += 1
    GUICtrlSetData($Label, $i)
EndFunc   ;==>MyFunc1

Func MyFunc2()
    $i -= 1
    GUICtrlSetData($Label, $i)
EndFunc   ;==>MyFunc2

Example3

Spoiler

AutoIt        expandcollapse  popup

#Include <GUIConstants.au3>
#Include <HotKey.au3>

Global Const $VK_ESCAPE = 0x1B
Global Const $VK_F12 = 0x7B

; Assign "F12" with Form()
_HotKey_Assign($VK_F12, 'Form')

; Assign "CTRL-ESC" with Quit()
_HotKey_Assign(BitOR($CK_CONTROL, $VK_ESCAPE), 'Quit')

While 1
    Sleep(10)
WEnd

Func Form()

    Local $Form, $Button, $Msg

    $Form = GUICreate('MyGUI', 350, 350, -1, -1, BitOR($WS_CAPTION, $WS_POPUP, $WS_SYSMENU), $WS_EX_TOPMOST)
    $Button = GUICtrlCreateButton('Exit', 140, 315, 70, 23)
    GUICtrlSetState(-1, BitOR($GUI_DEFBUTTON, $GUI_FOCUS))
    GUISetState(@SW_SHOW, $Form)

    While 1
        Switch GUIGetMsg()
            Case $Button, $GUI_EVENT_CLOSE
                ExitLoop
        EndSwitch
    WEnd

    GUIDelete($Form)
EndFunc   ;==>Form

Func Quit()
    Exit
EndFunc   ;==>Quit

Edited by Yashied, 17 October 2011 - 11:51 PM.

[ProgAndy]

What's wrong with HotKeySet() ? This is much easier

[Yashied]

What's wrong with HotKeySet() ? This is much easier

Differences HotKeySet() from HotKeyAssign():

Removed. (See first post)

Edited by Yashied, 17 August 2009 - 08:10 PM.

[WeMartiansAreFriendly]

Very nice idea. :thumsup:

Unfortunately the script crashes after it exits. I'm using Vista SP1, AutoIt 3.2.12.1

[ProgAndy]

OK, with the description, i see the advantages Great work.

[Yashied]

Thanks for your reply. I specifically used as a hotkey code number, not the string value in HotKeySet (). When writing a complete application where necessary to keep the hotkeys code (such as the registry), it is better to use the number.

Edited by Yashied, 01 March 2009 - 04:30 PM.

[Yashied]

Very nice idea. :thumsup:

Unfortunately the script crashes after it exits. I'm using Vista SP1, AutoIt 3.2.12.1

Try AutoIt v3.3.0.0.

[Yashied]

Who are interested, I updated the HotKey.au3.

[BrammerTheHammer]

OMG, thank you, I have been looking for this for a long time, I was about to write a program from scratch.

I am try to make a my own hotkeys, such as Win+Alt+F calling a function which sends a Shift+Right. Using HotKeySet the alt key would randomly get passed to the active window 50% of the time. So far, using your program the alt key only gets passed if I have an Office2007 app or OpenOffice as the active window and press the windows key first.
Do you know of any way to fix this small problem, other than training myself to press the alt key first?

Also, is there a way to use your program to capture the windows key so that it does not open the StartMenu, but still works for the hot keys? I tried capturing using VK_LWIN but it blocked the hot keys that used CK_WIN.

I will be trying to set approximately 90 hot keys, including the blocked ones (Win+K, Win+U). I will reply to this thread with my findings.

Again, thank you, this is a vast improvement.
BTH

[Yashied]

This library has been updated.

[Yashied]

OMG, thank you, I have been looking for this for a long time, I was about to write a program from scratch.

I am try to make a my own hotkeys, such as Win+Alt+F calling a function which sends a Shift+Right. Using HotKeySet the alt key would randomly get passed to the active window 50% of the time. So far, using your program the alt key only gets passed if I have an Office2007 app or OpenOffice as the active window and press the windows key first.
Do you know of any way to fix this small problem, other than training myself to press the alt key first?

Also, is there a way to use your program to capture the windows key so that it does not open the StartMenu, but still works for the hot keys? I tried capturing using VK_LWIN but it blocked the hot keys that used CK_WIN.

I will be trying to set approximately 90 hot keys, including the blocked ones (Win+K, Win+U). I will reply to this thread with my findings.

Again, thank you, this is a vast improvement.
BTH

Hi, BrammerTheHammer. I completely rewrote this library. Now she is working as I thought from the beginning. I suggest first to read the comments in the file. I have made many changes and additions.

[Zedna]

Looks like very strong UDF. 

But internal code is quite complicated.

Thanks for sharing anyway Yashied.

[Yashied]

Looks like very strong UDF. 

But internal code is quite complicated.

Thanks for sharing anyway Yashied.

Thank you, Zedna. I tried to ease this UDF, but most have no choice (if only at the expense of his work). I wrote a long time it, and then repairs, and then completely rewrote this library, and now it works exactly as I designed from the outset.

[Zedna]

I have no use for it now but I like such educative scripts

where you can learn something new and see what all is possible to do in Win32API/AutoIt :-)

[KenNichols]

Thanks, Works Great!

[hegearon]

Looks great.

[nguyenbason]

Can i set on textbox or editbox? (Like when input something, press enter go to function)

[Yashied]

AutoIt        expandcollapse  popup

#Include <HotKey.au3>

Global Const $VK_RETURN = 0x0D

Global $Edit, $hEdit

GUICreate('Test', 400, 400)
$Edit = GUICtrlCreateEdit('', 10, 10, 380, 380)
$hEdit = GUICtrlGetHandle($Edit)
GUISetState()

_HotKeyAssign($VK_RETURN, 'MyFunc', $HK_FLAG_NOBLOCKHOTKEY)

Do
Until GUIGetMsg() = -3

Func MyFunc()
    If _WinAPI_GetFocus() <> $hEdit Then
        Return
    EndIf
    ConsoleWrite('OK' & @CR)
EndFunc   ;==>MyFunc

[nguyenbason]

AutoIt        expandcollapse  popup

#Include <HotKey.au3>

Global Const $VK_RETURN = 0x0D

Global $Edit, $hEdit

GUICreate('Test', 400, 400)
$Edit = GUICtrlCreateEdit('', 10, 10, 380, 380)
$hEdit = GUICtrlGetHandle($Edit)
GUISetState()

_HotKeyAssign($VK_RETURN, 'MyFunc', $HK_FLAG_NOBLOCKHOTKEY)

Do
Until GUIGetMsg() = -3

Func MyFunc()
    If _WinAPI_GetFocus() <> $hEdit Then
        Return
    EndIf
    ConsoleWrite('OK' & @CR)
EndFunc   ;==>MyFunc

Thanks, but i tried your example but nothing happened, console has no output.

[crashburn]

nice... i've been working allday just to find a solution for setting hotkey to a specified window, and heres the answer. ty