#include <WinAPICOM.au3>

Func _GetCurrentSoundDevice()
	Local Const $sCLSID_MMDeviceEnumerator = "{BCDE0395-E52F-467C-8E3D-C4579291692E}"
	Local Const $sIID_IMMDeviceEnumerator = "{A95664D2-9614-4F35-A746-DE8DB63617E6}"
	Local Const $tagIMMDeviceEnumerator = "EnumAudioEndpoints hresult(int;int;ptr*);" & _
			"GetDefaultAudioEndpoint hresult(int;int;ptr*);" & _
			"GetDevice hresult(wstr;ptr*);" & _
			"RegisterEndpointNotificationCallback hresult(ptr);" & _
			"UnregisterEndpointNotificationCallback hresult(ptr);"

	Local Const $IID_IMMDevice = "{D666063F-1587-4E43-81F1-B948E807363F}"
	Local Const $tagIMMDevice = "Activate hresult(ptr;dword;variant*;ptr*);" & _
			"OpenPropertyStore hresult(dword;ptr*);" & _
			"GetId hresult(ptr*);" & _
			"GetState hresult(dword*);"

	Local Const $IID_IPropertyStore = "{886d8eeb-8cf2-4446-8d02-cdba1dbdcf99}"
	Local Const $tagIPropertyStore = "GetCount hresult(dword*);" & _
			"GetAt hresult(dword;ptr*);" & _
			"GetValue hresult(struct*;variant*);" & _
			"SetValue hresult(struct*;variant);" & _
			"Commit hresult();"

	Local Const $sPKEY_Device_FriendlyName = "{a45c254e-df1c-4efd-8020-67d146a850e0} 14"

	Local Const $STGM_READ = 0
	Local Const $DEVICE_STATE_ACTIVE = 0x00000001

	Local Const $eRender = 0
	Local Const $eCapture = 1
	Local Const $eAll = 2
	Local Const $EDataFlow_enum_count = 3

	Local Const $eConsole = 0
	Local Const $eMultimedia = 1
	Local Const $eCommunications = 2
	Local Const $ERole_enum_count = 3

	Local $oEnumerator = ObjCreateInterface($sCLSID_MMDeviceEnumerator, $sIID_IMMDeviceEnumerator, $tagIMMDeviceEnumerator)

	Local $pDefaultEndpoint
	$oEnumerator.GetDefaultAudioEndpoint($eRender, $DEVICE_STATE_ACTIVE, $pDefaultEndpoint)

	Local $oEndpoint = ObjCreateInterface($pDefaultEndpoint, $IID_IMMDevice, $tagIMMDevice)

	Local $pProps
	$oEndpoint.OpenPropertyStore($STGM_READ, $pProps)
	$oProps = ObjCreateInterface($pProps, $IID_IPropertyStore, $tagIPropertyStore)

	Local $tPKEY_Device_FriendlyName = _WinAPI_PKEYFromString($sPKEY_Device_FriendlyName)
	Local $sName
	$oProps.GetValue($tPKEY_Device_FriendlyName, $sName)

	Return $sName
EndFunc

Func _WinAPI_PKEYFromString($sPKEY, $pID = Default)
	Local $tPKEY = DllStructCreate("byte GUID[16]; dword PID;")
	DllCall("propsys.dll", "long", "PSPropertyKeyFromString", "wstr", $sPKEY, "struct*", $tPKEY)
	If $pID <> Default Then DllStructSetData($tPKEY, "PID", $pID)
	Return $tPKEY
EndFunc