#include <Excel.au3>
#include <Constants.au3>

Global Const $START = 2  ; E1<========= starting row to begin reading from your excel sheet

Global $oWorkBook = _Excel_BookAttach("Book1.xls", "filename") ; OTR.XLSX
If @error Then Exit MsgBox($MB_OK, "Error", "Excel sheet not loaded")
Global $iLastRow = $oWorkbook.ActiveSheet.Usedrange.Rows.Count
Global $aList = _Excel_RangeRead($oWorkBook, Default, "E" & $START & ":E" & $iLastRow) ; Read column E from START to end
If @error or Not IsArray($aList) Then Exit MsgBox($MB_OK, "Error", "unable to read column from excel sheet")
_ArrayDisplay($aList) ; Display content of column E

HotKeySet("{PGDN}", CopyNextCell)  ; PageDown to copy next cell into your other app
HotKeySet("^+{END}", Terminate)    ; ctrl-shift-end to exit your script

While Sleep(100)
WEnd

Func Terminate()
  Exit
EndFunc

Func CopyNextCell()
  Local Static $iPos = 0
  Local $hWnd = WinActivate("[CLASS:Notepad]") ; https://www.booking2.sellingplatformconnect.amadeus.com/
  If Not $hWnd Then Exit MsgBox($MB_OK, "Error", "Application not loaded")
  WinWaitActive($hWnd)

  Send("^a{DEL}" & $aList[$iPos])
  ;ControlSetText($hWnd, "", "Your control name here", $aList[$iPos]) ; LOT better but you need to find the control with au3info.exe
  $iPos += 1
  If $iPos > $iLastRow - $START Then Exit MsgBox($MB_OK, "Warning", "Last row reached, exiting script")
EndFunc