#include <GDIPlus.au3>
#include <WinAPITheme.au3>
#include "RoundGUI.au3"

; #DESCRIPTION# ========================================
; Title .........: Round GUI UDF - Example 1
; AutoIt Version : 3.3.16.1
; Description ...: Example of the Round Corner GUI UDF
; Goal ..........: Show creation of different controls
; Author ........: Nine, rcmaehl
; Date ..........: 2025-09-10
; ======================================================

Opt("MustDeclareVars", True)

Example()

Func Example()
  Local $hGUI = GUICreate("Example", 600, 500, -1, -1, $WS_POPUP, $WS_EX_LAYERED + $WS_EX_CONTROLPARENT)
  
  Local $hDC = _WinAPI_GetDC($hGUI)
  _WinAPI_SetBkColor($hDC, 0xEEFFC0) ; BGR
  _WinAPI_SetTextColor($hDC, 0xB0B0B0)
  _WinAPI_ReleaseDC($hGUI, $hDC)

  GUISetFont(11, 0, 0, "Comic Sans MS")
  _WinAPI_SetLayeredWindowAttributes($hGUI, 0xC0FFEE)

  _RGUI_RoundRect(0, 0, 600, 500, 0x202020, 0x202020, 20)
  _RGUI_RoundLabel("Example", 10, 10, 580, 30, $hGUI, 0xFFFFFF, 15, True)
  GUICtrlSetFont(-1, 13)
  _RGUI_DrawLine(110, 40, 110, 480, 0x808080)

  Local $idClear = _RGUI_RoundButton("Clear", 10, 50, 80, 30, $hGUI, 0xFF00, 15)
  Local $idCopy = _RGUI_RoundButton("Copy", 10, 90, 80, 30, $hGUI, 0xFF00, 15)
  Local $idExit = _RGUI_RoundButton("Exit", 10, 450, 80, 30, $hGUI, 0xFF00, 15)

  Local $idInput = _RGUI_RoundInput("Enter something", 130, 60, 400, 30, $hGUI,  0xFF00, 15, 6)
  Local $idEdit = _RGUI_RoundEdit("Enter something here also", 130, 110, 400, 180, $hGUI, 0X404040, 15, 8, $ES_WANTRETURN + $WS_VSCROLL + $ES_AUTOVSCROLL)

  Local $idGroup = _RGUI_RoundGroup("Group", 130, 320, 180, 150, $hGUI, 0x202020, 15, 3)
  GUICtrlSetFont(-1, 10)
  Local $idOpt1 = GUICtrlCreateRadio("Option 1", 150, 350, 80, 20)
  _WinAPI_SetWindowTheme(GUICtrlGetHandle($idOpt1), "0", "0")
  GUICtrlSetBkColor(-1, 0x202020)
  GUICtrlSetColor(-1, 0xB0B0B0)
  Local $idOpt2 = GUICtrlCreateRadio("Option 2", 150, 390, 80, 20)
  _WinAPI_SetWindowTheme(GUICtrlGetHandle($idOpt2), "0", "0")
  GUICtrlSetBkColor(-1, 0x202020)
  GUICtrlSetColor(-1, 0xB0B0B0)
  GUICtrlCreateGroup("", -99, -99)

  _RGUI_RoundLabel("Auto-Size", 350, 320, -1, -1, $hGUI, 0X404040, 15)

  GUISetState()

  Local $idCtrl
  While True
    Switch GUIGetMsg()
      Case $GUI_EVENT_CLOSE, $idExit
        ExitLoop
      Case $GUI_EVENT_PRIMARYDOWN
        $idCtrl = _RGUI_ButtonPress($idClear, $idCopy, 0xFF00)
      Case $GUI_EVENT_PRIMARYUP
        _RGUI_ButtonReset($idCtrl, 0xB0B0B0)
      Case $idInput
        ConsoleWrite("Input" & @CRLF)
      Case $idEdit
        ConsoleWrite("Edit" & @CRLF)
      Case $idClear
        GUICtrlSetData($idInput, "")
      Case $idCopy
        ClipPut(GUICtrlRead($idEdit))
    EndSwitch
  WEnd
EndFunc   ;==>Example