# Function Reference

# _GUICtrlHeader_SetBitmapMargin

Sets the width of the margin, specified in pixels, of a bitmap

#include <GuiHeader.au3>
_GUICtrlHeader_SetBitmapMargin ( $hWnd, $iWidth )

## Parameters

$hWnd | Handle to the control
$iWidth | Width, specified in pixels, of the bitmap margin

## Return Value

Success: | the previous bitmap margin width.
Failure: | 0.

## Related

_GUICtrlHeader_GetBitmapMargin

## Example

    #include "Extras\HelpFileInternals.au3"

    #include <GUIConstantsEx.au3>
    #include <GuiHeader.au3>

    Example()

    Func Example()
        ; Create GUI
        Local $hGUI = GUICreate("Header Get BitmapMargin (v" & @AutoItVersion & ")", 450, 300, 100, 100)
        Local $hHeader = _GUICtrlHeader_Create($hGUI)
        _MemoCreate(2, 52, 444, 220)

    ;~  _GUICtrlHeader_SetUnicodeFormat($hHeader, True)

        GUISetState(@SW_SHOW)

        ; Add columns
        _GUICtrlHeader_AddItem($hHeader, "Column 0", 100)
        _GUICtrlHeader_AddItem($hHeader, "Column 1", 100)
        _GUICtrlHeader_AddItem($hHeader, "Column 2", 100)
        _GUICtrlHeader_AddItem($hHeader, "Column 3", 100)

        ; Show current bitmap margin
        _MemoWrite("Current margin .: " & _GUICtrlHeader_GetBitmapMargin($hHeader))

        ; Set new bitmap margin
        _GUICtrlHeader_SetBitmapMargin($hHeader, 8)

        ; Show new bitmap margin
        _MemoWrite("New margin .....: " & _GUICtrlHeader_GetBitmapMargin($hHeader))

        _MemoMsgBoxStatus("", -1, $hGUI) ; no more action, wait GUI for closing

    EndFunc   ;==>Example