# Function Reference

# _GUICtrlHeader_DeleteItem

Deletes a header item

#include <GuiHeader.au3>
_GUICtrlHeader_DeleteItem ( $hWnd, $iIndex )

## Parameters

$hWnd | Handle to the control
$iIndex | 0-based item index

## Return Value

Success: | True.
Failure: | False.

## Related

_GUICtrlHeader_AddItem, _GUICtrlHeader_InsertItem

## Example

    #include "Extras\HelpFileInternals.au3"

    #include <GUIConstantsEx.au3>
    #include <GuiHeader.au3>
    #include <MsgBoxConstants.au3>

    Example()

    Func Example()
        ; Create GUI
        Local $hGUI = GUICreate("Header Delete Item (v" & @AutoItVersion & ")", 450, 300, 100, 100)
        Local $hHeader = _GUICtrlHeader_Create($hGUI)
        _MemoCreate(2, 52, 444, 220)

    ;~  _GUICtrlHeader_SetUnicodeFormat($hHeader, True)

        GUISetState(@SW_SHOW)

        ; Add columns
        _GUICtrlHeader_AddItem($hHeader, "Column 0", 100)
        _GUICtrlHeader_AddItem($hHeader, "Column 1", 100)
        _GUICtrlHeader_AddItem($hHeader, "Column 2", 100)
        _GUICtrlHeader_AddItem($hHeader, "Column 3", 100)

        ; Delete column 2
        _MemoMsgBox($MB_SYSTEMMODAL, "Information", "Deleting Column 2")
        _GUICtrlHeader_DeleteItem($hHeader, 2)

        _MemoMsgBoxStatus("", Default, $hGUI) ; no more action, wait GUI for closing

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
    EndFunc   ;==>Example