# Function Reference

# _GUICtrlTreeView_GetParentHandle

Retrieve the parent handle of item

#include <GuiTreeView.au3>
_GUICtrlTreeView_GetParentHandle ( $hWnd [, $hItem = Null] )

## Parameters

$hWnd | Control ID/Handle to the control
$hItem | [optional] item ID/handle

## Return Value

Success: | the handle to parent item.
Failure: | 0.

## Example

### Example 1

    #include <GUIConstantsEx.au3>
    #include <GuiTreeView.au3>
    #include <MsgBoxConstants.au3>
    #include <WindowsStylesConstants.au3>

    Example()

    Func Example()
        GUICreate("TreeView Get Parent Handle (v" & @AutoItVersion & ")", 400, 300)

        Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)
        Local $idTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
        GUISetState(@SW_SHOW)

        ; Set ANSI format
    ;~     _GUICtrlTreeView_SetUnicodeFormat($idTreeView, False)

        _GUICtrlTreeView_BeginUpdate($idTreeView)
        Local $idTVi_Item, $idTVi_Child
        For $x = 0 To 10
            $idTVi_Item = GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Item", $x), $idTreeView)
            _GUICtrlTreeView_GetItemHandle($idTreeView, $idTVi_Item)
            For $y = 0 To 2
                $idTVi_Child = GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Item", $y), $idTVi_Item)
            Next
        Next
        _GUICtrlTreeView_EndUpdate($idTreeView)

        _GUICtrlTreeView_SelectItem($idTreeView, $idTVi_Child)
        MsgBox($MB_SYSTEMMODAL, "Information", "Parent Handle: " & _GUICtrlTreeView_GetParentHandle($idTreeView, $idTVi_Child))
        _GUICtrlTreeView_SelectItem($idTreeView, _GUICtrlTreeView_GetParentHandle($idTreeView, $idTVi_Child))

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
        GUIDelete()
    EndFunc   ;==>Example

### Example 2

    #include <GUIConstantsEx.au3>
    #include <GuiTreeView.au3>
    #include <MsgBoxConstants.au3>
    #include <WindowsStylesConstants.au3>

    Example()

    Func Example()
        Local $hGUI = GUICreate("(UDF Created) TreeView Get Parent Handle (v" & @AutoItVersion & ")", 400, 300)

        Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)
        Local $hTreeView = _GUICtrlTreeView_Create($hGUI, 2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
        GUISetState(@SW_SHOW)

        ; Set ANSI format
    ;~     _GUICtrlTreeView_SetUnicodeFormat($hTreeView, False)

        _GUICtrlTreeView_BeginUpdate($hTreeView)
        Local $hItem, $hChild
        For $x = 0 To 20
            $hItem = _GUICtrlTreeView_Add($hTreeView, 0, StringFormat("[%02d] New Item", $x))
            For $y = 0 To 2
                $hChild = _GUICtrlTreeView_AddChild($hTreeView, $hItem, StringFormat("[%02d] New Item", $y))
            Next
        Next
        _GUICtrlTreeView_EndUpdate($hTreeView)

        _GUICtrlTreeView_SelectItem($hTreeView, $hChild)
        MsgBox($MB_SYSTEMMODAL, "Information", "Parent Handle: " & _GUICtrlTreeView_GetParentHandle($hTreeView, $hChild))
        _GUICtrlTreeView_SelectItem($hTreeView, _GUICtrlTreeView_GetParentHandle($hTreeView, $hChild))

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
        GUIDelete()
    EndFunc   ;==>Example