# Function Reference

# _GUICtrlTreeView_SetNormalImageList

Sets the normal image list for the control

#include <GuiTreeView.au3>
_GUICtrlTreeView_SetNormalImageList ( $hWnd, $hImageList )

## Parameters

$hWnd | Control ID/Handle to the control
$hImageList | Handle to the image list. If 0, all images are removed

## Return Value

Returns the handle to the previous image list?

## Related

_GUICtrlTreeView_GetNormalImageList

## Example

    #include <ColorConstants.au3>
    #include <GUIConstantsEx.au3>
    #include <GuiImageList.au3>
    #include <GuiTreeView.au3>
    #include <MsgBoxConstants.au3>
    #include <WindowsStylesConstants.au3>
    #include <WindowsSysColorConstants.au3>

    Example()

    Func Example()
        GUICreate("TreeView Get/Set Normal ImageList (v" & @AutoItVersion & ")", 400, 300)

        Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)
        Local $idTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
        GUISetState(@SW_SHOW)

        _GUICtrlTreeView_SetTextColor($idTreeView, $COLOR_Crimson)
        _GUICtrlTreeView_SetLineColor($idTreeView, $COLOR_WHITE)

        Local $hImage = _GUIImageList_Create(16, 16, 5, 3)
        _GUIImageList_AddIcon($hImage, "shell32.dll", 110)
        _GUIImageList_AddIcon($hImage, "shell32.dll", 131)
        _GUIImageList_AddIcon($hImage, "shell32.dll", 165)
        _GUIImageList_AddIcon($hImage, "shell32.dll", 168)
        _GUIImageList_AddIcon($hImage, "shell32.dll", 137)
        _GUIImageList_AddIcon($hImage, "shell32.dll", 146)
        _GUICtrlTreeView_SetNormalImageList($idTreeView, $hImage)

        _GUICtrlTreeView_BeginUpdate($idTreeView)
        For $x = 0 To 5
            _GUICtrlTreeView_Add($idTreeView, 0, StringFormat("[%02d] New Item", $x + 1), $x, $x)
        Next
        _GUICtrlTreeView_EndUpdate($idTreeView)

        MsgBox($MB_SYSTEMMODAL, "Information", "Normal ImageList Handle: " & _GUICtrlTreeView_GetNormalImageList($idTreeView))

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
        GUIDelete()
    EndFunc   ;==>Example