# Function Reference

# _GUICtrlTreeView_GetFocused

Indicates whether the item has focus

#include <GuiTreeView.au3>
_GUICtrlTreeView_GetFocused ( $hWnd, $hItem )

## Parameters

$hWnd | Control ID/Handle to the control
$hItem | Handle to the item

## Return Value

True: | item has focus.
False: | item does not have focus.

## Related

_GUICtrlTreeView_SetFocused

## Example

    #include <GUIConstantsEx.au3>
    #include <GuiTreeView.au3>
    #include <MsgBoxConstants.au3>
    #include <WindowsStylesConstants.au3>

    Example()

    Func Example()
        GUICreate("TreeView Get/Set Focused (v" & @AutoItVersion & ")", 400, 300)

        Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)
        Local $idTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
        GUISetState(@SW_SHOW)

        _GUICtrlTreeView_BeginUpdate($idTreeView)
        Local $aidTVi_Item[6]
        For $x = 0 To UBound($aidTVi_Item) - 1
            $aidTVi_Item[$x] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Item", $x + 1), $idTreeView)
        Next
        _GUICtrlTreeView_EndUpdate($idTreeView)

        Local $hRandomItem = Random(0, UBound($aidTVi_Item) - 1, 1)
        MsgBox($MB_SYSTEMMODAL, "Information", StringFormat("Item %d Focused? %s", $hRandomItem, _GUICtrlTreeView_GetFocused($idTreeView, $aidTVi_Item[$hRandomItem])))
        _GUICtrlTreeView_SetFocused($idTreeView, $aidTVi_Item[$hRandomItem])
        MsgBox($MB_SYSTEMMODAL, "Information", StringFormat("Item %d Focused? %s", $hRandomItem, _GUICtrlTreeView_GetFocused($idTreeView, $aidTVi_Item[$hRandomItem])))

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
        GUIDelete()
    EndFunc   ;==>Example