# Function Reference

# _GUICtrlTreeView_SetScrollTime

Sets the maximum scroll time

#include <GuiTreeView.au3>
_GUICtrlTreeView_SetScrollTime ( $hWnd, $iTime )

## Parameters

$hWnd | Control ID/Handle to the control
$iTime | New maximum scroll time, in milliseconds

## Return Value

Returns the Previous scroll time, in milliseconds.

## Remarks

The maximum scroll time is the longest amount of time that a scroll operation can take.
Scrolling will be adjusted so that the scroll will take place within the maximum scroll time.
A scroll operation may take less time than the maximum.

## Related

_GUICtrlTreeView_GetScrollTime

## Example

    #include <GUIConstantsEx.au3>
    #include <GuiTreeView.au3>
    #include <MsgBoxConstants.au3>
    #include <WindowsStylesConstants.au3>

    Example()

    Func Example()
        GUICreate("TreeView Get/Set Scroll Time (v" & @AutoItVersion & ")", 400, 300)

        Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)
        Local $idTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
        GUISetState(@SW_SHOW)

        _GUICtrlTreeView_BeginUpdate($idTreeView)
        Local $aidTVi_Item[10]
        For $x = 0 To 9
            $aidTVi_Item[$x] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Item", $x), $idTreeView)
            For $y = 1 To Random(2, 10, 1)
                GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Child", $y), $aidTVi_Item[$x])
            Next
        Next
        _GUICtrlTreeView_EndUpdate($idTreeView)

        _GUICtrlTreeView_SetScrollTime($idTreeView, 2)
        MsgBox($MB_SYSTEMMODAL, "Information", "Scroll Time: " & _GUICtrlTreeView_GetScrollTime($idTreeView) & " milliseconds")

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
        GUIDelete()
    EndFunc   ;==>Example