# Function Reference

# _Excel_SheetList

Returns a list of all sheets in the specified workbook

#include <Excel.au3>
_Excel_SheetList ( $oWorkbook )

## Parameters

$oWorkbook | A workbook object

## Return Value

Success: | a two-dimensional zero based array with the following information: 0 - Name of the worksheet 1 - Object of the worksheet
Failure: | 0 and sets @error.
@error: | 1 - $oWorkbook is not an object or not a workbook object

## Example

    #include "Extras\HelpFileInternals.au3"

    #include <Array.au3>
    #include <Excel.au3>
    #include <MsgBoxConstants.au3>

    ; Create application object and open a workbook
    Local $oExcel = _Excel_Open()
    If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_SheetList Example 1", "Error creating the Excel application object." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
    Local $oWorkbook = _Excel_BookOpen($oExcel, _Extras_PathFull("_Excel2.xls"))
    If @error Then
        MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_SheetList Example 1", "Error opening workbook '" & _Extras_PathFull("_Excel2.xls'.") & @CRLF & "@error = " & @error & ", @extended = " & @extended)
        _Excel_Close($oExcel)
        Exit
    EndIf

    ; Display a list of all worksheets for a specific Workbook
    Local $aWorkSheets = _Excel_SheetList($oWorkbook)
    If @error Then Exit MsgBox($MB_SYSTEMMODAL, "Excel UDF: _Excel_SheetList Example 1", "Error listing Worksheets." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
    _ArrayDisplay($aWorkSheets, "Excel UDF: _Excel_SheetList Example 1")