# Function Reference

# _GUICtrlComboBoxEx_SetItemHeight

Set the height of list items or the selection field in a ComboBox

#include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_SetItemHeight ( $hWnd, $iComponent, $iHeight )

## Parameters

$hWnd | Handle to the control
$iComponent | Use the following values: –1 - Set the height of the selection field 0 - Set the height of list items
$iHeight | The height, in pixels, of the combo box component identified by $iComponent

## Return Value

Success: | 0.
Failure: | -1 if height is invalid.

## Related

_GUICtrlComboBoxEx_GetItemHeight

## Example

    #include "Extras\HelpFileInternals.au3"

    #include <GuiComboBoxEx.au3>
    #include <GUIConstantsEx.au3>
    #include <GuiImageList.au3>

    Example()

    Func Example()

        ; Create GUI
        Local $hGUI = GUICreate("ComboBoxEx Get/Set Item Height (v" & @AutoItVersion & ")", 400, 300)
        Local $hCombo = _GUICtrlComboBoxEx_Create($hGUI, "", 2, 2, 394, 100)
        _MemoCreate(2, 32, 396, 266, 0)
        GUISetState(@SW_SHOW)

        Local $hImage = _GUIImageList_Create(16, 16, 5, 3)
        _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 110)
        _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 131)
        _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 165)
        _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 168)
        _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 137)
        _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 146)
        _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0xFF0000, 16, 16))
        _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x00FF00, 16, 16))
        _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x0000FF, 16, 16))
        _GUICtrlComboBoxEx_SetImageList($hCombo, $hImage)

        For $x = 0 To 8
            _GUICtrlComboBoxEx_AddString($hCombo, StringFormat("%03d : string", $x), $x, $x)
        Next

        _MemoWrite("Set Item Height: " & _GUICtrlComboBoxEx_SetItemHeight($hCombo, -1, 18))
        _MemoWrite("Item Height: " & _GUICtrlComboBoxEx_GetItemHeight($hCombo, -1))
        _MemoWrite("Set Item Height: " & _GUICtrlComboBoxEx_SetItemHeight($hCombo, 0, 20))
        _MemoWrite("Item Height: " & _GUICtrlComboBoxEx_GetItemHeight($hCombo, 0))

        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
    EndFunc   ;==>Example