# Function Reference

# _GUICtrlListBox_ResetContent

Remove all items from the list box

#include <GuiListBox.au3>
_GUICtrlListBox_ResetContent ( $hWnd )

## Parameters

$hWnd | Control ID/Handle to the control

## Return Value

None.

## Related

_GUICtrlListBox_DeleteString

## Example

    #include <GUIConstantsEx.au3>
    #include <GuiListBox.au3>
    #include <MsgBoxConstants.au3>
    #include <WindowsStylesConstants.au3>

    Example()

    Func Example()
        Local $idListBox

        ; Create GUI
        GUICreate("List Box Reset Content", 400, 296)
        $idListBox = GUICtrlCreateList("", 2, 2, 396, 296, BitOR($WS_BORDER, $WS_VSCROLL, $LBS_NOTIFY, $LBS_DISABLENOSCROLL, $WS_HSCROLL))
        GUISetState(@SW_SHOW)

        ; Add strings
        _GUICtrlListBox_BeginUpdate($idListBox)
        For $iI = 1 To 9
            _GUICtrlListBox_AddString($idListBox, StringFormat("%03d : Random string", Random(1, 100, 1)))
        Next
        _GUICtrlListBox_EndUpdate($idListBox)

        MsgBox($MB_SYSTEMMODAL, "Information", "Resetting Content")
        _GUICtrlListBox_ResetContent($idListBox)

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
        GUIDelete()
    EndFunc   ;==>Example