# Function Reference

# _GUICtrlComboBoxEx_GetDroppedState

Determines whether the ListBox of a ComboBox is dropped down

#include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_GetDroppedState ( $hWnd )

## Parameters

$hWnd | Handle to the control

## Return Value

True: | Is dropped down.
False: | Not dropped down.

## Related

_GUICtrlComboBox_GetDroppedWidth, _GUICtrlComboBox_SetDroppedWidth, _GUICtrlComboBox_ShowDropDown, _GUICtrlComboBoxEx_ShowDropDown

## Example

    #include "Extras\HelpFileInternals.au3"

    #include <GuiComboBoxEx.au3>
    #include <GUIConstantsEx.au3>
    #include <GuiImageList.au3>

    Example()

    Func Example()
        Local $hGUI, $hImage, $hCombo

        ; Create GUI
        $hGUI = GUICreate("ComboBoxEx Get Dropped State", 400, 300)
        $hCombo = _GUICtrlComboBoxEx_Create($hGUI, "", 2, 2, 394, 100)
        _MemoCreate(2, 32, 396, 266, 0)
        GUISetState(@SW_SHOW)

        $hImage = _GUIImageList_Create(16, 16, 5, 3)
        _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 110)
        _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 131)
        _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 165)
        _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 168)
        _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 137)
        _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 146)
        _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0xFF0000, 16, 16))
        _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x00FF00, 16, 16))
        _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x0000FF, 16, 16))
        _GUICtrlComboBoxEx_SetImageList($hCombo, $hImage)

        For $x = 0 To 8
            _GUICtrlComboBoxEx_AddString($hCombo, StringFormat("%03d : Random string", Random(1, 100, 1)), $x, $x)
        Next

        ; get dropped state
        _MemoWrite("Dropped Down State......: " & _GUICtrlComboBoxEx_GetDroppedState($hCombo))

        Sleep(500)

        ; show drop down
        _GUICtrlComboBoxEx_ShowDropDown($hCombo, True)

        Sleep(500)

        ; get dropped state
        _MemoWrite("Dropped Down State......: " & _GUICtrlComboBoxEx_GetDroppedState($hCombo))

        Sleep(500)

        ; hide drop down
        _GUICtrlComboBoxEx_ShowDropDown($hCombo)

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
        GUIDelete()
    EndFunc   ;==>Example