# Function Reference

# _GUICtrlListBox_Destroy

Delete the control

#include <GuiListBox.au3>
_GUICtrlListBox_Destroy ( ByRef $hWnd )

## Parameters

$hWnd | Control ID/Handle to the control

## Return Value

Success: | True, $hWnd is set to 0.
Failure: | False.

## Remarks

Restricted to only be used on Listbox controls created with _GUICtrlListBox_Create().

## Related

_GUICtrlListBox_Create

## Example

    #include <DirConstants.au3>
    #include <GUIConstantsEx.au3>
    #include <GuiListBox.au3>
    #include <MsgBoxConstants.au3>

    Example()

    Func Example()
        Local $hGUI, $hListBox

        ; Create GUI
        $hGUI = GUICreate("(UDF Created) List Box Destroy", 400, 296)
        $hListBox = _GUICtrlListBox_Create($hGUI, "", 2, 2, 396, 296)
        GUISetState(@SW_SHOW)

        ; Add files
        _GUICtrlListBox_BeginUpdate($hListBox)
        _GUICtrlListBox_ResetContent($hListBox)
        _GUICtrlListBox_InitStorage($hListBox, 100, 4096)
        _GUICtrlListBox_Dir($hListBox, @WindowsDir & "\win*.exe")
        _GUICtrlListBox_AddFile($hListBox, @WindowsDir & "\notepad.exe")
        _GUICtrlListBox_Dir($hListBox, "", $DDL_DRIVES)
        _GUICtrlListBox_Dir($hListBox, "", $DDL_DRIVES, False)
        _GUICtrlListBox_EndUpdate($hListBox)

        MsgBox($MB_SYSTEMMODAL, "Information", "Destroying ListBox")
        _GUICtrlListBox_Destroy($hListBox)

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
    EndFunc   ;==>Example