# Function Reference

# _GUICtrlTab_SetImageList

Sets the image list associated with a tab control

#include <GuiTab.au3>
_GUICtrlTab_SetImageList ( $hWnd, $hImage )

## Parameters

$hWnd | Control ID/Handle to the control
$hImage | Handle to the image list to assign to the tab control

## Return Value

Returns the handle to the previous image list.

## Related

_GUICtrlTab_GetImageList

## Example

    #include "Extras\HelpFileInternals.au3"

    #include <GUIConstantsEx.au3>
    #include <GuiImageList.au3>
    #include <GuiTab.au3>
    #include <MsgBoxConstants.au3>
    #include <WinAPIGdi.au3>

    Example()

    Func Example()
        ; Create GUI
        Local $hGUI = GUICreate("Tab Get/Set Image List (v" & @AutoItVersion & ")", 450, 300, 100, 100)
        Local $hTab = _GUICtrlTab_Create($hGUI, 2, 2, 446, 266)
        _MemoMsgBoxStatus() ; Status creation

        GUISetState(@SW_SHOW)

        ; Create images
        Local $hImage = _GUIImageList_Create()
        _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0xFF0000, 16, 16))
        _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0x00FF00, 16, 16))
        _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0x0000FF, 16, 16))
        $hImage = _GUICtrlTab_SetImageList($hTab, $hImage)

        ; Add tabs
        _GUICtrlTab_InsertItem($hTab, 0, "Tab 0", 0)
        _GUICtrlTab_InsertItem($hTab, 1, "Tab 1", 1)
        _GUICtrlTab_InsertItem($hTab, 2, "Tab 2", 2)

        ; Show image list handle
        _MemoMsgBox($MB_SYSTEMMODAL, "Information", "Previous Image list handle: 0x" & Hex($hImage) & @CRLF & _
                "IsPtr = " & IsPtr($hImage) & " IsHWnd = " & IsHWnd($hImage))

        ; Loop until the user exits.

        _MemoMsgBoxStatus("", -1, $hGUI) ; no more action, wait GUI for closing

    EndFunc   ;==>Example