# Function Reference

# GUICtrlCreateInput

Creates an Input control for the GUI.

GUICtrlCreateInput ( "text", left, top [, width [, height [, style = -1 [, exStyle = -1]]]] )

## Parameters

text | The text of the control.
left | The left side of the control. If -1 is used then left will be computed according to GUICoordMode.
top | The top of the control. If -1 is used then top will be computed according to GUICoordMode.
width | [optional] The width of the control (default is the previously used width).
height | [optional] The height of the control (default is the previously used height).
style | [optional] Defines the style of the control. See GUI Control Styles Appendix. default ( -1) : $ES_LEFT, $ES_AUTOHSCROLL forced styles : $WS_TABSTOP only if no $ES_READONLY. $ES_MULTILINE is always reset.
exStyle | [optional] Defines the extended style of the control. See Extended Style Table. default ( -1) : $WS_EX_CLIENTEDGE

## Return Value

Success: | the identifier (controlID) of the new control.
Failure: | 0.

## Remarks

To obtain the value of the control see GUICtrlRead().
To set or change information in the control see GUICtrlUpdate...() functions.
For defining an input control for entering passwords (input is hidden with an asterisk) use the $ES_AUTOHSCROLL + $ES_PASSWORD styles.
If you want to drag & drop a filename onto this control just add the WS_EX_ACCEPTFILES extended style on the GUICreate() and set the state to $GUI_DROPACCEPTED.
After multiple drag and drop files on this control, you can retrieve the files name which are separated by "|" with GUICtrlRead().
To use the values specified above you must #include <EditConstants.au3> in your script.
Default resizing is $GUI_DOCKHEIGHT.

## Related

GUICoordMode (Option), GUICtrlCreateUpdown, GUICtrlRead, GUICtrlSetLimit, GUICtrlUpdate..., GUIGetMsg

## Example

    #include <GUIConstantsEx.au3>
    #include <MsgBoxConstants.au3>
    #include <WindowsStylesConstants.au3>

    Example()

    Func Example()
        GUICreate(" My GUI input acceptfile", 320, 120, @DesktopWidth / 2 - 160, @DesktopHeight / 2 - 45, -1, $WS_EX_ACCEPTFILES)
        Local $idInp_File = GUICtrlCreateInput("", 10, 5, 300, 20)
        GUICtrlSetState(-1, $GUI_DROPACCEPTED)
        GUICtrlCreateInput("", 10, 35, 300, 20) ; will not accept drag&drop files
        Local $idBtn = GUICtrlCreateButton("Ok", 40, 75, 60, 20)

        GUISetState(@SW_SHOW)

        ; Loop until the user exits.
        While 1
            Switch GUIGetMsg()
                Case $GUI_EVENT_CLOSE
                    ExitLoop
                Case $idBtn
                    ExitLoop
            EndSwitch
        WEnd

        MsgBox($MB_SYSTEMMODAL, "drag drop file", GUICtrlRead($idInp_File))
    EndFunc   ;==>Example