# Function Reference

# _GUICtrlToolbar_GetButtonRectEx

Retrieves the bounding rectangle for a specified toolbar button

#include <GuiToolbar.au3>
_GUICtrlToolbar_GetButtonRectEx ( $hWnd, $iCommandID )

## Parameters

$hWnd | Handle to the control
$iCommandID | Button command ID

## Return Value

Returns a $tagRECT structure.

## Related

$tagRECT, _GUICtrlToolbar_GetButtonRect

## Example

    #include "Extras\HelpFileInternals.au3"

    #include <GUIConstantsEx.au3>
    #include <GuiToolbar.au3>
    #include <WinAPIConstants.au3>
    #include <WindowsStylesConstants.au3>

    Example()

    Func Example()

        ; Create GUI
        Local $hGUI = GUICreate("Toolbar Get Button RectEx (v" & @AutoItVersion & ")", 400, 300)
        Local $hToolbar = _GUICtrlToolbar_Create($hGUI)
        _MemoCreate(2, 36, 396, 262, $WS_VSCROLL)
        GUISetState(@SW_SHOW)

        ; Add standard system bitmaps
        Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
            Case 0
                _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
            Case 2
                _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
        EndSwitch

        ; Add buttons
        Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $e_idHelp
        _GUICtrlToolbar_AddButton($hToolbar, $e_idNew, $STD_FILENEW)
        _GUICtrlToolbar_AddButton($hToolbar, $e_idOpen, $STD_FILEOPEN)
        _GUICtrlToolbar_AddButton($hToolbar, $e_idSave, $STD_FILESAVE)
        _GUICtrlToolbar_AddButtonSep($hToolbar)
        _GUICtrlToolbar_AddButton($hToolbar, $e_idHelp, $STD_HELP)

        ; Show Save button rectangle
        Local $tRECT = _GUICtrlToolbar_GetButtonRectEx($hToolbar, $e_idSave)
        _MemoWrite("Save Button Rect")
        _MemoWrite("----------------")
        _MemoWrite("Left ...: " & DllStructGetData($tRECT, "Left"))
        _MemoWrite("Top ....: " & DllStructGetData($tRECT, "Top"))
        _MemoWrite("Right ..: " & DllStructGetData($tRECT, "Right"))
        _MemoWrite("Bottom .: " & DllStructGetData($tRECT, "Bottom"))

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
    EndFunc   ;==>Example