# Function Reference

# _GUICtrlRichEdit_SetParaNumbering

Sets numbering of paragraph(s) in the current selection or, if no selection, of paragraph(s) inserted at the insertion point

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetParaNumbering ( $hWnd, $sStyle [, $iTextToNbrSpace = Default [, $bForceRoman = False]] )

## Parameters

$hWnd | Handle to the control
$sStyle | a string specifying style and starting "number": e.g. "." (bullet), "1)","(b)", "C.", "iv", "V)" This is the "numbering" that will display for the first paragraph. Trailing spaces indicate the minimum spaces between the number and the paragraph unless $iTextToNbrSpace is entered Special cases: "=" - This paragraph is an unnumbered paragraph within the preceding list element "" - removed the numbering from the selected paragraph(s)
$iTextToNbrSpace | [optional] space between number/bullet and paragraph (in space units) Default: number of trailing spaces times point size
$bForceRoman | [optional] False - i, v, x ... in $sStyle is letter i, v, x ... {Default)

## Return Value

Success: | True.
Failure: | False and sets the @error flag to non-zero.
@error: | 101 - $hWnd is not a handle 103 - $iTextToNbrSpace is not a postive number 104 - $bForceRoman must be True or False

## Remarks

To set "space units", call _GUICtrlRichEdit_SetSpaceUnit(). Initially inches.

## Related

_GUICtrlRichEdit_GetParaNumbering, _GUICtrlRichEdit_SetSpaceUnit

## See Also

Search EM_SETPARAFORMAT in MSDN Library.

## Example

    #include <GUIConstantsEx.au3>
    #include <GuiRichEdit.au3>
    #include <WindowsStylesConstants.au3>

    Global $g_idLbl_Msg, $g_hRichEdit

    Example()

    Func Example()
        Local $hGui, $iMsg, $idBtn_Next, $iStep = 0
        $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, StringLen(".exe")) & ")", 320, 350, -1, -1)
        $g_hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
                BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
        $g_idLbl_Msg = GUICtrlCreateLabel("", 10, 235, 300, 60)
        $idBtn_Next = GUICtrlCreateButton("Next", 270, 310, 40, 30)
        GUISetState(@SW_SHOW)

        _GUICtrlRichEdit_SetText($g_hRichEdit, "First paragraph")
        _GUICtrlRichEdit_SetSel($g_hRichEdit, 0, 1)
        Report("Para with default indent settings")

        While True
            $iMsg = GUIGetMsg()
            Select
                Case $iMsg = $GUI_EVENT_CLOSE
                    _GUICtrlRichEdit_Destroy($g_hRichEdit) ; needed unless script crashes
                    ; GUIDelete()   ; is OK too
                    Exit
                Case $iMsg = $idBtn_Next
                    $iStep += 1
                    Switch $iStep
                        Case 1
                            _GUICtrlRichEdit_AppendText($g_hRichEdit, @CRLF & "Second paragraph")
                            _GUICtrlRichEdit_SetParaNumbering($g_hRichEdit, ".")
                            Report("Added second paragraph")
                        Case 2
                            _GUICtrlRichEdit_SetSel($g_hRichEdit, 0, 2)
                            Report("Style of first paragraph in the selection")
                        Case 3
                            _GUICtrlRichEdit_SetSel($g_hRichEdit, 10, 26)
                            _GUICtrlRichEdit_SetParaNumbering($g_hRichEdit, "v)  ", Default, True)
                            Report("Change settings of both paragraphs")
                        Case 4
                            _GUICtrlRichEdit_SetSel($g_hRichEdit, 10, 26)
                            _GUICtrlRichEdit_SetParaNumbering($g_hRichEdit, "2.  ", Default, True)
                            Report("Changed settings for both paragraphs")
                        Case 5
                            ; Stream all text to the Desktop so you can look at settings in Word
                            _GUICtrlRichEdit_Deselect($g_hRichEdit)
                            _GUICtrlRichEdit_StreamToFile($g_hRichEdit, @DesktopDir & "\gcre.rtf")
                            GUICtrlSetState($idBtn_Next, $GUI_DISABLE)
                    EndSwitch
            EndSelect
        WEnd
    EndFunc   ;==>Example

    Func Report($sMsg)
        $sMsg = $sMsg & @CRLF & @CRLF & "Get function returns " & @CRLF & _GUICtrlRichEdit_GetParaNumbering($g_hRichEdit)
        GUICtrlSetData($g_idLbl_Msg, $sMsg)
    EndFunc   ;==>Report