# Function Reference

# _WinAPI_GetWindowRect

Retrieves the dimensions of the bounding rectangle of the specified window

#include <WinAPISysWin.au3>
_WinAPI_GetWindowRect ( $hWnd )

## Parameters

$hWnd | Handle of the window

## Return Value

Success: | $tagRECT structure that receives the screen coordinates
Failure: | Sets the @error flag to non-zero, call _WinAPI_GetLastError() to get extended error information

## Related

$tagRECT

## See Also

Search GetWindowRect in MSDN Library.

## Example

    #include <WinAPIGdi.au3>
    #include <WinAPISysWin.au3>

    _Example()

    Func _Example()
        Local $hWindow = WinGetHandle("[REGEXPTITLE:(?i)(.*" & @ScriptName & ".*SciTE.*?)]")
        Local $tagRECT = _WinAPI_GetWindowRect($hWindow)
        Local $hMonitor = _WinAPI_MonitorFromRect($tagRECT, $MONITOR_DEFAULTTONEAREST)

        Local $aData = _WinAPI_GetMonitorInfo($hMonitor)
        If Not @error Then
            ConsoleWrite('Handle:      ' & $hMonitor & @CRLF)
            ConsoleWrite('Rectangle:   ' & DllStructGetData($aData[0], 1) & ', ' & DllStructGetData($aData[0], 2) & ', ' & DllStructGetData($aData[0], 3) & ', ' & DllStructGetData($aData[0], 4) & @CRLF)
            ConsoleWrite('Work area:   ' & DllStructGetData($aData[1], 1) & ', ' & DllStructGetData($aData[1], 2) & ', ' & DllStructGetData($aData[1], 3) & ', ' & DllStructGetData($aData[1], 4) & @CRLF)
            ConsoleWrite('Primary:     ' & $aData[2] & @CRLF)
            ConsoleWrite('Device name: ' & $aData[3] & @CRLF)
        EndIf
    EndFunc   ;==>_Example