# Function Reference

# TrayItemGetText

Gets the itemtext of a tray menu/item control.

TrayItemGetText ( controlID )

## Parameters

controlID | The control identifier (controlID) as returned by a TrayCreateItem or TrayCreateMenu function.

## Return Value

Success: | The itemtext of the tray menu/item control.
Failure: | 0.

## Related

TrayItemGetHandle, TrayItemSetText

## Example

    #NoTrayIcon

    #include <MsgBoxConstants.au3>
    #include <StringConstants.au3>
    #include <TrayConstants.au3> ; Required for the $TRAY_ICONSTATE_SHOW constant.

    Opt("TrayMenuMode", 3) ; The default tray menu items will not be shown and items are not checked when selected. These are options 1 and 2 for TrayMenuMode.

    Example()

    Func Example()
        Local $idGetText = TrayCreateItem("Get 'About' Text")
        TrayCreateItem("") ; Create a separator line.

        Local $idAbout = TrayCreateItem("About")
        TrayCreateItem("") ; Create a separator line.

        Local $idExit = TrayCreateItem("Exit")

        TraySetState($TRAY_ICONSTATE_SHOW) ; Show the tray menu.

        While 1
            Switch TrayGetMsg()
                Case $idAbout ; Display a message box about the AutoIt version and installation path of the AutoIt executable.
                    MsgBox($MB_SYSTEMMODAL, "", "AutoIt tray menu example." & @CRLF & @CRLF & _
                            "Version: " & @AutoItVersion & @CRLF & _
                            "Install Path: " & StringLeft(@AutoItExe, StringInStr(@AutoItExe, "\", $STR_NOCASESENSEBASIC, -1) - 1)) ; Find the folder of a full path.

                Case $idGetText
                    ; Display a message box about the text of the 'About' item.
                    MsgBox($MB_SYSTEMMODAL, "", "The text of the 'About' item is: " & TrayItemGetText($idAbout))

                Case $idExit ; Exit the loop.
                    ExitLoop
            EndSwitch
        WEnd
    EndFunc   ;==>Example