# Function Reference

# _GUICtrlEdit_GetLine

Retrieves a line of text from an edit control

#include <GuiEdit.au3>
_GUICtrlEdit_GetLine ( $hWnd, $iLine )

## Parameters

$hWnd | Control ID/Handle to the control
$iLine | 0-based line index to get

## Return Value

Success: | the line of text.
Failure: | an empty string.

## Example

    #include <GUIConstantsEx.au3>
    #include <GuiEdit.au3>
    #include <MsgBoxConstants.au3>

    Example()

    Func Example()
        Local $idEdit
        Local $sWow64 = ""
        If @AutoItX64 Then $sWow64 = "\Wow6432Node"
        Local $sFile = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE" & $sWow64 & "\AutoIt v3\AutoIt", "InstallDir") & "\include\_ReadMe_.txt"

        ; Create GUI
        GUICreate("Edit Get Line", 400, 300)
        $idEdit = GUICtrlCreateEdit("", 2, 2, 394, 268)
        GUISetState(@SW_SHOW)

        _GUICtrlEdit_SetText($idEdit, FileRead($sFile))

        MsgBox($MB_SYSTEMMODAL, "Information", _GUICtrlEdit_GetLine($idEdit, 2))

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
        GUIDelete()
    EndFunc   ;==>Example