# Function Reference

# _GDIPlus_GraphicsDrawString

Draw a string

#include <GDIPlus.au3>
_GDIPlus_GraphicsDrawString ( $hGraphics, $sString, $nX, $nY [, $sFont = Default [, $fSize = Default [, $iFormat = Default [, $iARGB = Default]]]] )

## Parameters

$hGraphics | Handle to a Graphics object
$sString | String to be drawn
$nX | X coordinate where the string will be drawn
$nY | Y coordinate where the string will be drawn
$sFont | [optional] Name of the font to use for drawing. Default = "Arial".
$fSize | [optional] Font size to use for drawing. Default = 10.
$iFormat | [optional] Format flags. Can be one or more of the following. Default = 0 : 0x0001 - Specifies that reading order is right to left 0x0002 - Specifies that individual lines of text are drawn vertically on the display device 0x0004 - Specifies that parts of characters are allowed to overhang the string's layout rectangle 0x0020 - Specifies that Unicode layout control characters are displayed with a representative character 0x0400 - Specifies that an alternate font is used for characters that are not supported in the requested font 0x0800 - Specifies that the space at the end of each line is included in a string measurement 0x1000 - Specifies that the wrapping of text to the next line is disabled 0x2000 - Specifies that only entire lines are laid out in the layout rectangle 0x4000 - Specifies that characters overhanging the layout rectangle and text extending outside the layout rectangle are allowed to show
$iARGB | [optional] Font Color with Aplpha channel. Default = 0xFF000000 (Black). If Alpha channel is 0 then it is forced to 0xFF to avoid empty display.

## Return Value

Success: | True.
Failure: | False and sets the @error flag to non-zero, @extended may contain GPSTATUS error code ($GDIP_ERR* see GPIPlusConstants.au3).

## Related

_GDIPlus_GraphicsDrawStringEx

## Example

    #include <GDIPlus.au3>
    #include <GUIConstantsEx.au3>

    Example()

    Func Example()
        Local $hGUI, $hGraphic

        ; Create GUI
        $hGUI = GUICreate("GDI+", 400, 300)
        GUISetState(@SW_SHOW)

        ; Draw a string
        _GDIPlus_Startup()
        $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGUI)
        _GDIPlus_GraphicsDrawString($hGraphic, "Hello world", 140, 110)
        _GDIPlus_GraphicsDrawString($hGraphic, "Hello colored world", 140, 210, Default, Default, Default, 0xFF007F)

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE

        ; Clean up resources
        _GDIPlus_GraphicsDispose($hGraphic)
        _GDIPlus_Shutdown()
    EndFunc   ;==>Example