# Function Reference

# _GUICtrlRichEdit_SetParaAttributes

Sets attributes of paragraph(s) in the current selection or, if no selection, of paragraphs inserted at the insertion point

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetParaAttributes ( $hWnd, $sStatesAndAtts )

## Parameters

$hWnd | Handle to the control
$sStatesAndAtts | a string consisting of groups separated by semicolons ";". Each group consists of: First character - state: + - turn attribute on - - turn attribute off "fpg" - force this/these paragraphs on to new page(s) (Initially off) "hyp" - automatic hypthenation (Initially on) "kpt" - keep this/these paragraph(s) together on a page (Initially off} "kpn" - keep this/these paragraph(s) and the next together on a page (Initially off) "pwo" - prevent widows and orphans, i.e. avoid a single line of this/these paragraphs on a page (Initially off) "r2l" - display text using right-to-left reading order (Initially off) "row" - paragraph(s) is/are table row(s) (Initially off) "sbs" - display paragraphs side by side (Initially off) "sln" - suppress line numbers in documents or sections with line numbers (Initially off)

## Return Value

Success: | True.
Failure: | False and sets the @error flag to non-zero.
@error: | 101 - $hWnd is not a handle 1021 - a state character in $sStatesAndAtts is invalid. It is in @extended 1022 - an attribute abbreviation in $sStatesAndAtts is invalid. It is in @extended 1023 - length of $sStatesAndAtts is invalid

## Remarks

Displays results in Word but not in Rich Edit.

## Related

_GUICtrlRichEdit_GetParaAttributes

## See Also

Search EM_SETPARAFORMAT in MSDN Library.

## Example

    #include <GUIConstantsEx.au3>
    #include <GuiRichEdit.au3>
    #include <WindowsStylesConstants.au3>

    Global $g_idLbl_Msg, $g_hRichEdit

    Example()

    Func Example()
        Local $hGui, $iMsg, $idBtn_Next, $iStep = 0
        $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, StringLen(".exe")) & ")", 320, 350, -1, -1)
        $g_hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
                BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
        $g_idLbl_Msg = GUICtrlCreateLabel("", 10, 235, 300, 60)
        $idBtn_Next = GUICtrlCreateButton("Next", 270, 310, 40, 30)
        GUISetState(@SW_SHOW)

        _GUICtrlRichEdit_AppendText($g_hRichEdit, "First paragraph")
        Report("First paragraph: default attributes")

        While True
            $iMsg = GUIGetMsg()
            Select
                Case $iMsg = $GUI_EVENT_CLOSE
                    _GUICtrlRichEdit_Destroy($g_hRichEdit) ; needed unless script crashes
                    ; GUIDelete()   ; is OK too
                    Exit
                Case $iMsg = $idBtn_Next
                    $iStep += 1
                    Switch $iStep
                        Case 1
                            _GUICtrlRichEdit_AppendText($g_hRichEdit, @CRLF & "Second paragraph")
                            _GUICtrlRichEdit_SetParaAttributes($g_hRichEdit, "-hyp")
                            Report("Second paragraph: hyphenation off")
                        Case 2
                            _GUICtrlRichEdit_SetSel($g_hRichEdit, 10, -1)
                            _GUICtrlRichEdit_SetParaAttributes($g_hRichEdit, "-hyp;+fpg;+kpn")
                            Report("Attributes of first paragraph in selection")
                        Case 3
                            ; Stream all text to the Desktop so you can look at attributes in Word
                            _GUICtrlRichEdit_Deselect($g_hRichEdit)
                            _GUICtrlRichEdit_StreamToFile($g_hRichEdit, @DesktopDir & "\gcre.rtf")
                            GUICtrlSetState($idBtn_Next, $GUI_DISABLE)
                    EndSwitch
            EndSelect
        WEnd
    EndFunc   ;==>Example

    Func Report($sMsg)
        $sMsg = $sMsg & @CRLF & @CRLF & "Get function returns " & @CRLF & _GUICtrlRichEdit_GetParaAttributes($g_hRichEdit)
        GUICtrlSetData($g_idLbl_Msg, $sMsg)
    EndFunc   ;==>Report