# Function Reference

# _GUICtrlTreeView_SetChecked

Sets whether a item has it's checkbox checked or not

#include <GuiTreeView.au3>
_GUICtrlTreeView_SetChecked ( $hWnd, $hItem [, $bCheck = True] )

## Parameters

$hWnd | Control ID/Handle to the control
$hItem | Handle to the item
$bCheck | [optional] Value to set checked state to: True - Checked False - Not checked

## Return Value

Success: | True.
Failure: | False.

## Related

_GUICtrlTreeView_GetChecked

## Example

    #include <GUIConstantsEx.au3>
    #include <GuiTreeView.au3>
    #include <MsgBoxConstants.au3>
    #include <WindowsStylesConstants.au3>

    Example()

    Func Example()
        GUICreate("TreeView Get/Set Checked (v" & @AutoItVersion & ")", 400, 300)

        Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)
        Local $idTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
        GUISetState(@SW_SHOW)

        ; Set ANSI format
    ;~     _GUICtrlListView_SetUnicodeFormat($idListview, False)

        _GUICtrlTreeView_BeginUpdate($idTreeView)
        Local $aidTVi_Item[6]
        For $x = 0 To UBound($aidTVi_Item) - 1
            $aidTVi_Item[$x] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Item", $x), $idTreeView)
        Next
        _GUICtrlTreeView_EndUpdate($idTreeView)

        Local $hRandomItem = Random(0, UBound($aidTVi_Item) - 1, 1)
        MsgBox($MB_SYSTEMMODAL, "Information", StringFormat("Item %d Checked? %s", $hRandomItem, _GUICtrlTreeView_GetChecked($idTreeView, $aidTVi_Item[$hRandomItem])))
        _GUICtrlTreeView_SetChecked($idTreeView, $aidTVi_Item[$hRandomItem])
        MsgBox($MB_SYSTEMMODAL, "Information", StringFormat("Item %d Checked? %s", $hRandomItem, _GUICtrlTreeView_GetChecked($idTreeView, $aidTVi_Item[$hRandomItem])))

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
        GUIDelete()
    EndFunc   ;==>Example