# Function Reference

# _GUICtrlTreeView_GetImageIndex

Retrieves the normal state image index

#include <GuiTreeView.au3>
_GUICtrlTreeView_GetImageIndex ( $hWnd, $hItem )

## Parameters

$hWnd | Control ID/Handle to the control
$hItem | Handle to the item

## Return Value

Success: | the image list index.
Failure: | 0.

## Related

_GUICtrlTreeView_SetImageIndex

## Example

    #include <GUIConstantsEx.au3>
    #include <GuiImageList.au3>
    #include <GuiTreeView.au3>
    #include <MsgBoxConstants.au3>
    #include <WindowsStylesConstants.au3>

    Example()

    Func Example()
        GUICreate("TreeView Get/Set Image Index (v" & @AutoItVersion & ")", 400, 300)

        Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)
        Local $idTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
        GUISetState(@SW_SHOW)

        Local $hImage = _GUIImageList_Create(16, 16, 5, 3)
        _GUIImageList_AddIcon($hImage, "shell32.dll", 110)
        _GUIImageList_AddIcon($hImage, "shell32.dll", 131)
        _GUIImageList_AddIcon($hImage, "shell32.dll", 165)
        _GUIImageList_AddIcon($hImage, "shell32.dll", 168)
        _GUIImageList_AddIcon($hImage, "shell32.dll", 137)
        _GUIImageList_AddIcon($hImage, "shell32.dll", 146)
        _GUICtrlTreeView_SetNormalImageList($idTreeView, $hImage)

        _GUICtrlTreeView_BeginUpdate($idTreeView)
        Local $ahItem[6], $hRandomImage
        For $x = 0 To _GUIImageList_GetImageCount($hImage) - 1
            $hRandomImage = $x ;Random(0, 5, 1)
            $ahItem[$x] = _GUICtrlTreeView_Add($idTreeView, 0, StringFormat("[%02d] New Item", $x), $hRandomImage, $hRandomImage)
        Next
        _GUICtrlTreeView_EndUpdate($idTreeView)

        Local $hRandomItem = 2 ; Random(0, UBound($ahItem) - 1, 1)
        MsgBox($MB_SYSTEMMODAL, "Information", StringFormat("Item %d Image Index? %s", $hRandomItem, _GUICtrlTreeView_GetImageIndex($idTreeView, $ahItem[$hRandomItem])))
        _GUICtrlTreeView_SelectItem($idTreeView, $ahItem[$hRandomItem])

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
        GUIDelete()
    EndFunc   ;==>Example