# Function Reference

# _GUICtrlComboBox_SetItemHeight

Set the height of list items or the selection field in a ComboBox

#include <GuiComboBox.au3>
_GUICtrlComboBox_SetItemHeight ( $hWnd, $iHeight [, $iComponent = -1] )

## Parameters

$hWnd | Control ID/Handle to the control
$iHeight | The height, in pixels, of the combo box component identified by $iComponent
$iComponent | [optional] Use the following values: –1 - Set the height of the selection field 0 - Set the height of list items

## Return Value

Success: | 0.
Failure: | -1 if height is invalid.

## Related

_GUICtrlComboBox_GetItemHeight

## Example

    #include "Extras\HelpFileInternals.au3"

    #include <GuiComboBox.au3>
    #include <GUIConstantsEx.au3>

    Example()

    Func Example()
        ; Create GUI
        GUICreate("ComboBox Get/Set Item Height (v" & @AutoItVersion & ")", 400, 296)
        Local $idCombo = GUICtrlCreateCombo("", 2, 2, 396, 296)
        _MemoCreate(2, 32, 396, 266, 0)
        GUISetState(@SW_SHOW)

        ; Add files
        _GUICtrlComboBox_BeginUpdate($idCombo)
        _GUICtrlComboBox_AddDir($idCombo, @WindowsDir & "\*.exe")
        _GUICtrlComboBox_EndUpdate($idCombo)

        ; Get Item Height (selection field)
        _MemoWrite("Item Height (selection field): " & _GUICtrlComboBox_GetItemHeight($idCombo))

        ; Get Item Height (list items)
        _MemoWrite("Item Height (list items): " & _GUICtrlComboBox_GetItemHeight($idCombo, 0))

        ; Set Item Height (selection field)
        _GUICtrlComboBox_SetItemHeight($idCombo, 18)

        ; Set Item Height (selection field)
        _GUICtrlComboBox_SetItemHeight($idCombo, 20, 0)

        ; Get Item Height (selection field)
        _MemoWrite("Item Height (selection field): " & _GUICtrlComboBox_GetItemHeight($idCombo))

        ; Get Item Height (list items)
        _MemoWrite("Item Height (list items): " & _GUICtrlComboBox_GetItemHeight($idCombo, 0))

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
        GUIDelete()
    EndFunc   ;==>Example