# Function Reference

# _GUICtrlListBox_FindInText

Searches for an item that contains the specified text anywhere in its text

#include <GuiListBox.au3>
_GUICtrlListBox_FindInText ( $hWnd, $sText [, $iStart = -1 [, $bWrapOK = True]] )

## Parameters

$hWnd | Control ID/Handle to the control
$sText | Text to match
$iStart | [optional] 0-based index of the item to begin the search with or -1 to start from the beginning. The specified item is itself excluded from the search.
$bWrapOK | [optional] If True, the search will continue with the first item if no match is found

## Return Value

Success: | the 0-based index of the item.
Failure: | -1.

## Remarks

The search is case insensitive.

## Related

_GUICtrlListBox_FindString, _GUICtrlListBox_SelectString

## Example

    #include <GUIConstantsEx.au3>
    #include <GuiListBox.au3>

    Example()

    Func Example()
        Local $iIndex, $idListBox

        ; Create GUI
        GUICreate("List Box Find In Text", 400, 296)
        $idListBox = GUICtrlCreateList("", 2, 2, 396, 296)

        GUISetState(@SW_SHOW)

        ; Add strings
        _GUICtrlListBox_BeginUpdate($idListBox)
        For $iI = 1 To 9
            _GUICtrlListBox_AddString($idListBox, StringFormat("%03d : Random string", Random(1, 100, 1)))
        Next
        _GUICtrlListBox_InsertString($idListBox, "eXaCt tExT", 3)
        _GUICtrlListBox_EndUpdate($idListBox)

        ; Find an item
        $iIndex = _GUICtrlListBox_FindInText($idListBox, "exa")
        _GUICtrlListBox_SetCurSel($idListBox, $iIndex)

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
        GUIDelete()
    EndFunc   ;==>Example