# Function Reference

# _GUICtrlRichEdit_StreamFromVar

Sets text in a control from a variable

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_StreamFromVar ( $hWnd, $sVar )

## Parameters

$hWnd | Handle to the control
$sVar | a string

## Return Value

Success: | True.
Failure: | False and sets the @error flag to non-zero.
@error: | 101 - $hWnd is not a handle 700 - attempt to stream in too many characters

## Remarks

If text is selected, replaces selection, else replaces all text in the control.
Call _GUICtrlRichEdit_SetLimitOnText() to increase the number of characters the control can contain.

## Related

_GUICtrlRichEdit_SetLimitOnText, _GUICtrlRichEdit_StreamFromFile, _GUICtrlRichEdit_StreamToFile, _GUICtrlRichEdit_StreamToVar

## See Also

Search EM_STREAMIN in MSDN Library.

## Example

    #include <GUIConstantsEx.au3>
    #include <GuiRichEdit.au3>
    #include <WindowsStylesConstants.au3>

    Example()

    Func Example()
        Local $hGui, $iMsg, $idBtn_Next, $iStep = 0, $idLbl_Msg, $hRichEdit, $s
        $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, StringLen(".exe")) & ")", 320, 350, -1, -1)
        $hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
                BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
        $idLbl_Msg = GUICtrlCreateLabel("", 10, 235, 300, 60)
        $idBtn_Next = GUICtrlCreateButton("Next", 270, 310, 40, 30)
        GUISetState(@SW_SHOW)

        _GUICtrlRichEdit_SetText($hRichEdit, "First paragraph")
        While True
            $iMsg = GUIGetMsg()
            Select
                Case $iMsg = $GUI_EVENT_CLOSE
                    _GUICtrlRichEdit_Destroy($hRichEdit) ; needed unless script crashes
                    ; GUIDelete()   ; is OK too
                    Exit
                Case $iMsg = $idBtn_Next
                    $iStep += 1
                    Switch $iStep
                        Case 1
                            $s = _GUICtrlRichEdit_StreamToVar($hRichEdit)
                            GUICtrlSetData($idLbl_Msg, "Streamed to variable")
                        Case 2
                            _GUICtrlRichEdit_SetText($hRichEdit, "")
                            _GUICtrlRichEdit_StreamFromVar($hRichEdit, $s)
                            GUICtrlSetData($idLbl_Msg, "Streamed from variable")
                        Case 3
                            _GUICtrlRichEdit_SetSel($hRichEdit, 2, 6)
                            _GUICtrlRichEdit_StreamFromVar($hRichEdit, $s)
                            GUICtrlSetData($idLbl_Msg, "Replaced selection: an intentional mess!")
                            GUICtrlSetState($idBtn_Next, $GUI_DISABLE)
                    EndSwitch
            EndSelect
        WEnd
    EndFunc   ;==>Example