# Function Reference

# _WinAPI_ShellAboutDlg

Displays a Windows About dialog box

#include <WinAPIDlg.au3>
_WinAPI_ShellAboutDlg ( $sTitle, $sName, $sText [, $hIcon = 0 [, $hParent = 0]] )

## Parameters

$sTitle | The title of the Windows About dialog box.
$sName | The first line after the text "Microsoft".
$sText | The text to be displayed in the dialog box after the version and copyright information.
$hIcon | [optional] Handle to the icon that the function displays in the dialog box.
$hParent | [optional] Handle to a parent window.

## Return Value

Success: | True.
Failure: | False.

## See Also

Search ShellAbout in MSDN Library.

## Example

    #include <GUIConstantsEx.au3>
    #include <WinAPIDlg.au3>
    #include <WinAPIShellEx.au3>

    Local $hForm = GUICreate('Test ' & StringReplace(@ScriptName, '.au3', '()'), 400, 400)
    Local $idButton = GUICtrlCreateButton('About', 165, 366, 70, 23)
    GUICtrlSetState($idButton, $GUI_DEFBUTTON)
    GUISetState(@SW_SHOW)
    Send('{Enter}')

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop
            Case $idButton
                _WinAPI_ShellAboutDlg('About', 'About Dialog Box Test', 'Simple Text', _WinAPI_ShellExtractIcon(@AutoItExe, 0, 32, 32), $hForm)
        EndSwitch
    WEnd