# Function Reference

# _GUICtrlComboBoxEx_GetItemText

Retrieve a string from the list of a ComboBox

#include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_GetItemText ( $hWnd, $iIndex, ByRef $sText )

## Parameters

$hWnd | Handle to the control
$iIndex | 0-based index to Retrieve from
$sText | Variable that will receive the string

## Return Value

Success: | the length of the string.
Failure: | -1.

## Example

    #include <GuiComboBoxEx.au3>
    #include <GUIConstantsEx.au3>
    #include <GuiImageList.au3>
    #include <MsgBoxConstants.au3>

    Example()

    Func Example()
        Local $hGUI, $hImage, $iImage, $sText, $hCombo

        ; Create GUI
        $hGUI = GUICreate("ComboBoxEx Get Item Text", 400, 300)
        $hCombo = _GUICtrlComboBoxEx_Create($hGUI, "", 2, 2, 394, 100)
        GUISetState(@SW_SHOW)

        $hImage = _GUIImageList_Create(16, 16, 5, 3)
        _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 110)
        _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 131)
        _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 165)
        _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 168)
        _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 137)
        _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 146)
        _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0xFF0000, 16, 16))
        _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x00FF00, 16, 16))
        _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x0000FF, 16, 16))
        _GUICtrlComboBoxEx_SetImageList($hCombo, $hImage)

        _GUICtrlComboBoxEx_BeginUpdate($hCombo)
        For $x = 0 To 149
            $iImage = Random(0, 8, 1)
            _GUICtrlComboBoxEx_AddString($hCombo, StringFormat("%03d : Random string", Random(1, 100, 1)), $iImage, $iImage)
        Next
        _GUICtrlComboBoxEx_EndUpdate($hCombo)
        _GUICtrlComboBoxEx_SetItemImage($hCombo, 0, 1)
        _GUICtrlComboBoxEx_SetItemIndent($hCombo, 1, 1)
        _GUICtrlComboBoxEx_SetItemIndent($hCombo, 2, 1)
        _GUICtrlComboBoxEx_SetItemSelectedImage($hCombo, 0, 3)

        ; Get Item Text
        _GUICtrlComboBoxEx_GetItemText($hCombo, 0, $sText)
        MsgBox($MB_SYSTEMMODAL, "Information", "Item Text: " & $sText)

        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
    EndFunc   ;==>Example