# Function Reference

# _GUICtrlListView_SubItemHitTest

Determines which listview item or subitem is at a given position

#include <GuiListView.au3>
_GUICtrlListView_SubItemHitTest ( $hWnd [, $iX = -1 [, $iY = -1]] )

## Parameters

$hWnd | Control ID/Handle to the control
$iX | [optional] X position to test or -1 to use the current mouse position
$iY | [optional] Y position to test or -1 to use the current mouse position

## Return Value

Returns an array with the following format:
[ 0] - 0-based index of the item at the specified position, or -1
[ 1] - 0-based index of the subitem at the specified position, or -1
[ 2] - If True, position is in control's client window but not on an item
[ 3] - If True, position is over item icon
[ 4] - If True, position is over item text
[ 5] - If True, position is over item state image
[ 6] - If True, position is somewhere on the item
[ 7] - If True, the position is above the control's client area
[ 8] - If True, the position is below the control's client area
[ 9] - If True, the position is to the left of the client area
[10] - If True, the position is to the right of the client area

## Related

_GUICtrlListView_HitTest

## Example

    #include "Extras\WM_NOTIFY.au3"

    #include <GUIConstantsEx.au3>
    #include <GuiImageList.au3>
    #include <GuiListView.au3>
    #include <GuiStatusBar.au3>
    #include <StructureConstants.au3>
    #include <WindowsNotifsConstants.au3>

    Global $g_idListView, $g_hStatusBar, $g_iIndex = -1, $g_iSubIndex = -1

    Example()

    Func Example()
        ; Create GUI
        Local $hGUI = GUICreate("ListView SubItem Hit Test (v" & @AutoItVersion & ")", 400, 300)
        $g_idListView = GUICtrlCreateListView("", 2, 2, 394, 268)
        $g_idListView = GUICtrlGetHandle($g_idListView) ; get the handle for use in the notify events
        $g_hStatusBar = _GUICtrlStatusBar_Create($hGUI, -1, "")

        ; Enable extended control styles
        _GUICtrlListView_SetExtendedListViewStyle($g_idListView, $LVS_EX_SUBITEMIMAGES)
        GUISetState(@SW_SHOW)

        ; Set ANSI format
    ;~     _GUICtrlListView_SetUnicodeFormat($g_idListView, False)

        _WM_NOTIFY_Register()

        ; Load images
        Local $hImage = _GUIImageList_Create()
        _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($g_idListView, 0xFF0000, 16, 16))
        _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($g_idListView, 0x00FF00, 16, 16))
        _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($g_idListView, 0x0000FF, 16, 16))
        _GUICtrlListView_SetImageList($g_idListView, $hImage, 1)

        ; Add columns
        _GUICtrlListView_AddColumn($g_idListView, "Column 1", 100)
        _GUICtrlListView_AddColumn($g_idListView, "Column 2", 100)
        _GUICtrlListView_AddColumn($g_idListView, "Column 3", 100)

        ; Add items
        _GUICtrlListView_AddItem($g_idListView, "Row 1: Col 1", 0)
        _GUICtrlListView_AddSubItem($g_idListView, 0, "Row 1: Col 2", 1, 1)
        _GUICtrlListView_AddSubItem($g_idListView, 0, "Row 1: Col 3", 2, 2)
        _GUICtrlListView_AddItem($g_idListView, "Row 2: Col 1", 1)
        _GUICtrlListView_AddSubItem($g_idListView, 1, "Row 2: Col 2", 1, 2)
        _GUICtrlListView_AddItem($g_idListView, "Row 3: Col 1", 2)

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
        GUIDelete()
    EndFunc   ;==>Example

    Func ListView_Click()
        Local $aHit = _GUICtrlListView_SubItemHitTest($g_idListView)
        If ($aHit[0] <> -1) And (($aHit[0] <> $g_iIndex) Or ($aHit[1] <> $g_iSubIndex)) Then
            _GUICtrlStatusBar_SetText($g_hStatusBar, @TAB & StringFormat("HitTest Item: %d, SubItem: %d", $aHit[0], $aHit[1]))
            $g_iIndex = $aHit[0]
            $g_iSubIndex = $aHit[1]
        EndIf
    EndFunc   ;==>ListView_Click

    Func WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)
        #forceref $hWnd, $iMsg, $wParam
        Local $hWndListView = $g_idListView
        If Not IsHWnd($g_idListView) Then $hWndListView = GUICtrlGetHandle($g_idListView)

        Local $tNMHDR = DllStructCreate($tagNMHDR, $lParam)
        Local $hWndFrom = HWnd(DllStructGetData($tNMHDR, "hWndFrom"))
        Local $iCode = DllStructGetData($tNMHDR, "Code")
        Switch $hWndFrom
            Case $hWndListView
                Switch $iCode
                    Case $LVN_COLUMNCLICK ; A column was clicked
                        _WM_NOTIFY_DebugEvent("$LVN_COLUMNCLICK", $tagNMLISTVIEW, $lParam, "IDFrom,,Item,SubItem,NewState,OldState,Changed,ActionX,ActionY,Param")
                        ; No return value
                    Case $LVN_KEYDOWN ; A key has been pressed
                        _WM_NOTIFY_DebugEvent("$LVN_KEYDOWN", $tagNMLVKEYDOWN, $lParam, "IDFrom,,VKey,Flags")
                        ; No return value
                    Case $NM_CLICK ; Sent by a list-view control when the user clicks an item with the left mouse button
                        _WM_NOTIFY_DebugEvent("$NM_CLICK", $tagNMITEMACTIVATE, $lParam, "IDFrom,,Index,SubItem,NewState,OldState,Changed,X,Y,lParam,KeyFlags")
                        ListView_Click()
                        ; No return value
                    Case $NM_DBLCLK ; Sent by a list-view control when the user double-clicks an item with the left mouse button
                        _WM_NOTIFY_DebugEvent("$NM_DBLCLK", $tagNMITEMACTIVATE, $lParam, "IDFrom,,Index,SubItem,NewState,OldState,Changed,X,Y,lParam,KeyFlags")
                        ; No return value
                    Case $NM_KILLFOCUS ; The control has lost the input focus
                        _WM_NOTIFY_DebugEvent("$NM_KILLFOCUS", $tagNMHDR, $lParam, "hWndFrom,IDFrom")
                        ; No return value
                    Case $NM_RCLICK ; Sent by a list-view control when the user clicks an item with the right mouse button
                        _WM_NOTIFY_DebugEvent("$NM_RCLICK", $tagNMITEMACTIVATE, $lParam, "IDFrom,,Index,SubItem,NewState,OldState,Changed,X,Y,lParam,KeyFlags")
                        ;Return 1 ; not to allow the default processing
                        Return 0 ; allow the default processing
                    Case $NM_RDBLCLK ; Sent by a list-view control when the user double-clicks an item with the right mouse button
                        _WM_NOTIFY_DebugEvent("$NM_RDBLCLK", $tagNMITEMACTIVATE, $lParam, "IDFrom,,Index,SubItem,NewState,OldState,Changed,X,Y,lParam,KeyFlags")
                        ; No return value
                    Case $NM_RETURN ; The control has the input focus and that the user has pressed the ENTER key
                        _WM_NOTIFY_DebugEvent("$NM_RETURN", $tagNMHDR, $lParam, "hWndFrom,IDFrom")
                        ; No return value
                    Case $NM_SETFOCUS ; The control has received the input focus
                        _WM_NOTIFY_DebugEvent("$NM_SETFOCUS", $tagNMHDR, $lParam, "hWndFrom,IDFrom")
                        ; No return value
                EndSwitch
        EndSwitch
        Return $GUI_RUNDEFMSG
    EndFunc   ;==>WM_NOTIFY