# Function Reference

# _GUICtrlToolbar_GetButtonParam

Retrieves the button param value

#include <GuiToolbar.au3>
_GUICtrlToolbar_GetButtonParam ( $hWnd, $iCommandID )

## Parameters

$hWnd | Handle to the control
$iCommandID | Button command ID

## Return Value

Returns the application-defined value.

## Related

_GUICtrlToolbar_SetButtonParam

## Example

    #include "Extras\HelpFileInternals.au3"

    #include <GUIConstantsEx.au3>
    #include <GuiToolbar.au3>
    #include <WinAPIConstants.au3>
    #include <WindowsStylesConstants.au3>

    Example()

    Func Example()
        Local $hGUI, $hToolbar
        Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $e_idHelp

        ; Create GUI
        $hGUI = GUICreate("Toolbar", 400, 300)
        $hToolbar = _GUICtrlToolbar_Create($hGUI)
        _MemoCreate(2, 36, 396, 262, $WS_VSCROLL)
        GUISetState(@SW_SHOW)

        ; Add standard system bitmaps
        Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
            Case 0
                _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
            Case 2
                _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
        EndSwitch

        ; Add buttons
        _GUICtrlToolbar_AddButton($hToolbar, $e_idNew, $STD_FILENEW)
        _GUICtrlToolbar_AddButton($hToolbar, $e_idOpen, $STD_FILEOPEN)
        _GUICtrlToolbar_AddButton($hToolbar, $e_idSave, $STD_FILESAVE)
        _GUICtrlToolbar_AddButtonSep($hToolbar)
        _GUICtrlToolbar_AddButton($hToolbar, $e_idHelp, $STD_HELP)

        ; Set Save button parameter
        _GUICtrlToolbar_SetButtonParam($hToolbar, $e_idSave, 1234)

        ; Show Save button parameter
        _MemoWrite("Save button parameter: " & _GUICtrlToolbar_GetButtonParam($hToolbar, $e_idSave))

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
    EndFunc   ;==>Example