# Function Reference

# _GUICtrlComboBoxEx_BeginUpdate

Prevents updating of the control until the EndUpdate function is called

#include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_BeginUpdate ( $hWnd )

## Parameters

$hWnd | Handle to the control

## Return Value

Success: | True.
Failure: | False.

## Related

_GUICtrlComboBoxEx_EndUpdate

## Example

    #include <GuiComboBoxEx.au3>
    #include <GUIConstantsEx.au3>
    #include <GuiImageList.au3>

    Example()

    Func Example()
        Local $hGUI, $hImage, $hCombo

        ; Create GUI
        $hGUI = GUICreate("ComboBoxEx Begin Update", 400, 300)
        $hCombo = _GUICtrlComboBoxEx_Create($hGUI, "", 2, 2, 394, 100)
        GUISetState(@SW_SHOW)

        $hImage = _GUIImageList_Create(16, 16, 5, 3)
        For $x = 0 To 146
            _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", $x)
        Next
        _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0xFF0000, 16, 16))
        _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x00FF00, 16, 16))
        _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x0000FF, 16, 16))
        _GUICtrlComboBoxEx_SetImageList($hCombo, $hImage)

        _GUICtrlComboBoxEx_InitStorage($hCombo, 150, 300)

        _GUICtrlComboBoxEx_BeginUpdate($hCombo)
        For $x = 0 To 149
            _GUICtrlComboBoxEx_AddString($hCombo, StringFormat("%03d : Random string", Random(1, 200, 1)), $x, $x)
        Next
        _GUICtrlComboBoxEx_EndUpdate($hCombo)

        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
    EndFunc   ;==>Example