# Function Reference

# _GUICtrlRichEdit_GetCharAttributes

Returns attributes of selected text

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetCharAttributes ( $hWnd )

## Parameters

$hWnd | Handle to the control

## Return Value

Success: | a string consisting of three-character groups. Each group consists of: first and second character: any of: bo - bolded di - disabled - characters displayed with a shadow [nd] em - embossed [nd] hi - hidden, i.e. not displayed im - imprinted [nd] it - italcized li - EN_LINK messages are sent when mouse is over text with this attribute ou - outlined [nd] pr - EN_PROTECT sent when user attempts to modify re - marked as revised [nd] sh - shadowed [nd] sm - small capital letters [nd] st - struck out sb - subscript [nd] sp - superscript [nd] un - underlined third character: + for on, ~ for mixed
Failure: | Empty string and sets the @error flag to non-zero.
@error: | 101 - $hWnd is not a handle -1 - no text is selected

## Remarks

Some attributes do not display in a Rich Edit control; they are marked with [nd] above.
Returns "" if no attributes are on

## Related

_GUICtrlRichEdit_SetCharAttributes

## See Also

Search EM_GETCHARFORMAT in MSDN Library.

## Example

    #include <GUIConstantsEx.au3>
    #include <GuiRichEdit.au3>
    #include <WindowsStylesConstants.au3>

    Global $g_idLbl_Msg, $g_hRichEdit

    Example()

    Func Example()
        Local $hGui = GUICreate("RichEdit Get/Set CharAttributes", 320, 350, -1, -1)
        $g_hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
                BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
        $g_idLbl_Msg = GUICtrlCreateLabel("", 10, 235, 300, 60)
        Local $idBtn_Next = GUICtrlCreateButton("Next", 270, 310, 40, 30)
        GUISetState(@SW_SHOW)

        _GUICtrlRichEdit_SetText($g_hRichEdit, "Paragraph 1 ")
        Local $iMsg, $iStep = 0
        While True
            $iMsg = GUIGetMsg()
            Select
                Case $iMsg = $GUI_EVENT_CLOSE
                    _GUICtrlRichEdit_Destroy($g_hRichEdit) ; needed unless script crashes
                    ; GUIDelete()   ; is OK too
                    Exit
                Case $iMsg = $idBtn_Next
                    $iStep += 1
                    Switch $iStep
                        Case 1
                            _GUICtrlRichEdit_SetSel($g_hRichEdit, 0, 2)
                            _GUICtrlRichEdit_SetCharAttributes($g_hRichEdit, "+un")
                            Report("1. Two characters underlined")
                        Case 2
                            _GUICtrlRichEdit_SetSel($g_hRichEdit, 1, 5)
                            _GUICtrlRichEdit_SetCharAttributes($g_hRichEdit, "+bo")
                            Report("2. Some characters bolded")
                        Case 3
                            ; Stream all text to the Desktop so you can look at settings in Word
                            _GUICtrlRichEdit_Deselect($g_hRichEdit)
                            _GUICtrlRichEdit_StreamToFile($g_hRichEdit, @DesktopDir & "\gcre.rtf")
                            GUICtrlSetState($idBtn_Next, $GUI_DISABLE)
                    EndSwitch
            EndSelect
        WEnd
    EndFunc   ;==>Example

    Func Report($sMsg)
        $sMsg = $sMsg & @CRLF & @CRLF & _GUICtrlRichEdit_GetCharAttributes($g_hRichEdit)
        GUICtrlSetData($g_idLbl_Msg, $sMsg)
    EndFunc   ;==>Report