# Function Reference

# _GUICtrlEdit_EndUpdate

Enables screen repainting that was turned off with the _GUICtrlEdit_BeginUpdate function

#include <GuiEdit.au3>
_GUICtrlEdit_EndUpdate ( $hWnd )

## Parameters

$hWnd | Control ID/Handle to the control

## Return Value

Success: | True.
Failure: | False.

## Related

_GUICtrlEdit_BeginUpdate

## Example

    #include <GUIConstantsEx.au3>
    #include <GuiEdit.au3>
    #include <GuiStatusBar.au3>

    Example()

    Func Example()
        Local $hStatusBar, $idEdit, $hGUI
        Local $sWow64 = ""
        If @AutoItX64 Then $sWow64 = "\Wow6432Node"
        Local $sFile = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE" & $sWow64 & "\AutoIt v3\AutoIt", "InstallDir") & "\include\_ReadMe_.txt"

        ; Create GUI
        $hGUI = GUICreate("Edit End Update", 400, 300)
        $idEdit = GUICtrlCreateEdit("", 2, 2, 394, 268)
        $hStatusBar = _GUICtrlStatusBar_Create($hGUI, -1)
        GUISetState(@SW_SHOW)

        _GUICtrlEdit_BeginUpdate($idEdit)
        _GUICtrlEdit_SetText($idEdit, FileRead($sFile))
        _GUICtrlEdit_EndUpdate($idEdit)

        _GUICtrlStatusBar_SetIcon($hStatusBar, 0, 97, "shell32.dll")
        _GUICtrlStatusBar_SetText($hStatusBar, @TAB & "Lines: " & _GUICtrlEdit_GetLineCount($idEdit))

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
        GUIDelete()
    EndFunc   ;==>Example