# Function Reference

# _GUICtrlListView_SetGroupInfo

Sets group information

#include <GuiListView.au3>
_GUICtrlListView_SetGroupInfo ( $hWnd, $iGroupID, $sHeader [, $iAlign = 0 [, $iState = $LVGS_NORMAL]] )

## Parameters

$hWnd | Control ID/Handle to the control
$iGroupID | ID of the group
$sHeader | Header text
$iAlign | [optional] Alignment of the header text for the group: 0 - Left (Default) 1 - Center 2 - Right
$iState | [optional] Windows Vista or later can have one of the following values: $LVGS_NORMAL - (Default) Groups are expanded, the group name is displayed, and all items in the group are displayed. $LVGS_COLLAPSED - The group is collapsed. $LVGS_HIDDEN - The group is hidden. $LVGS_NOHEADER - The group does not display a header. $LVGS_COLLAPSIBLE - The group can be collapsed. $LVGS_FOCUSED - The group has keyboard focus. $LVGS_SELECTED - The group is selected. $LVGS_SUBSETED - The group displays only a portion of its items. $LVGS_SUBSETLINKFOCUSED - The subset link of the group has keyboard focus

## Return Value

Success: | True.
Failure: | False.

## Related

_GUICtrlListView_GetGroupInfo, _GUICtrlListView_GetGroupInfoByIndex

## Example

    #include <GUIConstantsEx.au3>
    #include <GuiImageList.au3>
    #include <GuiListView.au3>
    #include <MsgBoxConstants.au3>

    Example()

    Func Example()
        GUICreate("ListView Get/Set Group Info (v" & @AutoItVersion & ")", 400, 300)

        Local $idListview = GUICtrlCreateListView("", 2, 2, 394, 268)
        GUISetState(@SW_SHOW)

        ; Set ANSI format
    ;~     _GUICtrlListView_SetUnicodeFormat($idListview, False)

        ; Load images
        Local $hImage = _GUIImageList_Create()
        _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($idListview, 0xFF0000, 16, 16))
        _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($idListview, 0x00FF00, 16, 16))
        _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($idListview, 0x0000FF, 16, 16))
        _GUICtrlListView_SetImageList($idListview, $hImage, 1)

        ; Add columns
        _GUICtrlListView_AddColumn($idListview, "Column 0", 100)
        _GUICtrlListView_AddColumn($idListview, "Column 1", 100)
        _GUICtrlListView_AddColumn($idListview, "Column 2", 100)

        ; Add items
        _GUICtrlListView_AddItem($idListview, "Row 0: Col 0", 0)
        _GUICtrlListView_AddSubItem($idListview, 0, "Row 0: Col 1", 1)
        _GUICtrlListView_AddSubItem($idListview, 0, "Row 0: Col 2", 2)
        _GUICtrlListView_AddItem($idListview, "Row 1: Col 0", 1)
        _GUICtrlListView_AddSubItem($idListview, 1, "Row 1: Col 1", 1)
        _GUICtrlListView_AddItem($idListview, "Row 2: Col 0", 2)

        ; Build groups
        _GUICtrlListView_EnableGroupView($idListview)
        _GUICtrlListView_InsertGroup($idListview, -1, 1, "Group 1", 1)
        _GUICtrlListView_InsertGroup($idListview, -1, 2, "Group 2")
        _GUICtrlListView_SetItemGroupID($idListview, 0, 1)
        _GUICtrlListView_SetItemGroupID($idListview, 1, 2)
        _GUICtrlListView_SetItemGroupID($idListview, 2, 2)

        ; Change group information
        Local $aInfo = _GUICtrlListView_GetGroupInfo($idListview, 1)
        MsgBox($MB_SYSTEMMODAL, "Information", "Group 1 Text: " & $aInfo[0])
        _GUICtrlListView_SetGroupInfo($idListview, 1, "New Group 1")

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE

        GUIDelete()
    EndFunc   ;==>Example