# Function Reference

# _GUICtrlToolbar_SetButtonSize

Sets the size of the buttons to be added to a toolbar

#include <GuiToolbar.au3>
_GUICtrlToolbar_SetButtonSize ( $hWnd, $iHeight, $iWidth )

## Parameters

$hWnd | Handle to the control
$iHeight | Height, in pixels, of the buttons
$iWidth | Width, in pixels, of the buttons

## Return Value

Success: | True.
Failure: | False.

## Remarks

The size can be set only before adding any buttons to the toolbar. If an application does not explicitly set the button size, the size defaults to 24 by 22 pixels.

## Related

_GUICtrlToolbar_GetButtonSize

## Example

    #include "Extras\HelpFileInternals.au3"

    #include <GUIConstantsEx.au3>
    #include <GuiToolbar.au3>
    #include <WinAPIConstants.au3>
    #include <WindowsStylesConstants.au3>

    Example()

    Func Example()
        Local $hGUI, $hToolbar, $aSize
        Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $e_idHelp

        ; Create GUI
        $hGUI = GUICreate("Toolbar", 400, 300)
        $hToolbar = _GUICtrlToolbar_Create($hGUI)
        _MemoCreate(2, 36, 396, 262, $WS_VSCROLL)
        GUISetState(@SW_SHOW)

        ; Add standard system bitmaps
        Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
            Case 0
                _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
            Case 2
                _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
        EndSwitch

        ; Add buttons
        _GUICtrlToolbar_AddButton($hToolbar, $e_idNew, $STD_FILENEW)
        _GUICtrlToolbar_AddButton($hToolbar, $e_idOpen, $STD_FILEOPEN)
        _GUICtrlToolbar_AddButton($hToolbar, $e_idSave, $STD_FILESAVE)
        _GUICtrlToolbar_AddButtonSep($hToolbar)
        _GUICtrlToolbar_AddButton($hToolbar, $e_idHelp, $STD_HELP)

        ; Show button size
        $aSize = _GUICtrlToolbar_GetButtonSize($hToolbar)
        _MemoWrite("Button height : " & $aSize[0])
        _MemoWrite("Button width .: " & $aSize[1])
        _GUICtrlToolbar_SetButtonSize($hToolbar, $aSize[0], $aSize[1] + 10)
        $aSize = _GUICtrlToolbar_GetButtonSize($hToolbar)
        _MemoWrite("New Button Size")
        _MemoWrite("Button height : " & $aSize[0])
        _MemoWrite("Button width .: " & $aSize[1])

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
    EndFunc   ;==>Example