# Function Reference

# _GUICtrlRichEdit_GetSelAA

Gets the anchor and active inter-character positions of a selection, in that order

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetSelAA ( $hWnd )

## Parameters

$hWnd | Handle to the control

## Return Value

Success: | an array in the format: $aArray[0] = Anchor $aArray[1] = Active
Failure: | sets the @error flag to non-zero.
@error: | -1 - no text is selected 101 - $hWnd is not a handle

## Remarks

The first character of the text is after inter-character position 0.

## Related

_GUICtrlRichEdit_GetScrollPos, _GUICtrlRichEdit_GetSel, _GUICtrlRichEdit_SetSel

## See Also

Search EM_EXGETSEL in MSDN Library.

## Example

    #include <GUIConstantsEx.au3>
    #include <GuiRichEdit.au3>
    #include <WindowsStylesConstants.au3>

    Global $g_idLbl_Msg, $g_hRichEdit

    Example()

    Func Example()
        Local $hGui, $iMsg, $idBtn_Next, $iStep = 0
        $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, StringLen(".exe")) & ")", 320, 350, -1, -1)
        $g_hRichEdit = _GUICtrlRichEdit_Create($hGui, "", 10, 10, 300, 220, _
                BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
        $g_idLbl_Msg = GUICtrlCreateLabel("", 10, 235, 300, 60)
        $idBtn_Next = GUICtrlCreateButton("Next", 270, 310, 40, 30)
        GUISetState(@SW_SHOW)

        _GUICtrlRichEdit_SetText($g_hRichEdit, "Paragraph 1")
        _GUICtrlRichEdit_SetSel($g_hRichEdit, 7, 2)
        While True
            $iMsg = GUIGetMsg()
            Select
                Case $iMsg = $GUI_EVENT_CLOSE
                    _GUICtrlRichEdit_Destroy($g_hRichEdit) ; needed unless script crashes
                    ; GUIDelete()   ; is OK too
                    Exit
                Case $iMsg = $idBtn_Next
                    $iStep += 1
                    Switch $iStep
                        Case 1
                            Report("1. Selection is high to low")
                        Case 2
                            _GUICtrlRichEdit_SetSel($g_hRichEdit, 2, 7)
                            Report("2. Selection is low to high")
                            GUICtrlSetState($idBtn_Next, $GUI_DISABLE)
                    EndSwitch
            EndSelect
        WEnd
    EndFunc   ;==>Example

    Func Report($sMsg)
        Local $aRet = _GUICtrlRichEdit_GetSelAA($g_hRichEdit)
        $sMsg = $sMsg & @CRLF & @CRLF & "Get function returns " & $aRet[0] & "," & $aRet[1]
        GUICtrlSetData($g_idLbl_Msg, $sMsg)
    EndFunc   ;==>Report