# Function Reference

# _GUICtrlTreeView_AddFirst

Adds a new item

#include <GuiTreeView.au3>
_GUICtrlTreeView_AddFirst ( $hWnd, $hSibling, $sText [, $iImage = -1 [, $iSelImage = -1]] )

## Parameters

$hWnd | Control ID/Handle to the control
$hSibling | Sibling item
$sText | Text of the item
$iImage | [optional] 0-based index of the item's icon in the control's image list
$iSelImage | [optional] 0-based index of the item's icon in the control's image list

## Return Value

Success: | the handle to the new item.
Failure: | 0.

## Remarks

The item is added as the first sibling of $hSibling. Items that appear after the added item are moved down.

## Related

_GUICtrlTreeView_Add

## Example

    #include <GUIConstantsEx.au3>
    #include <GuiTreeView.au3>
    #include <WindowsStylesConstants.au3>

    Example()

    Func Example()
        GUICreate("TreeView Add First (v" & @AutoItVersion & ")", 400, 300)

        Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)
        Local $idTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
        GUISetState(@SW_SHOW)

        _GUICtrlTreeView_BeginUpdate($idTreeView)
        Local $hItem
        For $x = 1 To Random(2, 10, 1)
            $hItem = _GUICtrlTreeView_Add($idTreeView, 0, StringFormat("[%02d] New Item", $x))
            For $y = 1 To Random(2, 10, 1)
                _GUICtrlTreeView_AddChild($idTreeView, $hItem, StringFormat("[%02d] New Child", $y))
            Next
        Next
        _GUICtrlTreeView_AddFirst($idTreeView, $hItem, "[00] New First Item")
        _GUICtrlTreeView_EndUpdate($idTreeView)

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
        GUIDelete()
    EndFunc   ;==>Example