# Function Reference

# _SoundLength

Returns the length of the soundfile

#include <Sound.au3>
_SoundLength ( $aSndID [, $iMode = 1] )

## Parameters

$aSndID | Sound ID array as returned by _SoundOpen() or a file name
$iMode | [optional] This flag determines the format of the returned sound length 1 = (by default) hh:mm:ss where h = hours, m = minutes and s = seconds (default) 2 = milliseconds

## Return Value

Success: | the sound length.
Failure: | 0 and sets the @error flag to non-zero.
@error: | 1 = $iMode is invalid 3 = Invalid Sound ID. Use return array from _SoundOpen() or valid file name.

## Remarks

This function will return the best available value for the length of the file regardless of encoding method or parameter type.

## Related

_SoundOpen, _SoundPos

## Example

    #include <MsgBoxConstants.au3>
    #include <Sound.au3>

    Local $aSound = _SoundOpen(@WindowsDir & "\media\tada.wav")
    If @error = 2 Then
        MsgBox($MB_SYSTEMMODAL, "Error", "The file does not exist")
        Exit
    ElseIf @extended <> 0 Then
        Local $iExtended = @extended ; Assign because @extended will be set after DllStructCreate().
        Local $tText = DllStructCreate("char[128]")
        DllCall("winmm.dll", "short", "mciGetErrorStringA", "str", $iExtended, "struct*", $tText, "int", 128)
        MsgBox($MB_SYSTEMMODAL, "Error", "The open failed." & @CRLF & "Error Number: " & $iExtended & @CRLF & "Error Description: " & DllStructGetData($tText, 1) & @CRLF & "Please Note: The sound may still play correctly.")
    Else
        MsgBox($MB_SYSTEMMODAL, "Success", "The file opened successfully")
    EndIf

    MsgBox($MB_SYSTEMMODAL, "Sound Length", "The Sound has a length of:" & @CRLF & "hh:mm:ss - " & _
            _SoundLength($aSound, 1) & @CRLF & "Milliseconds - " & _SoundLength($aSound, 2))