# Function Reference

# _GUICtrlRichEdit_SetPasswordChar

Sets the characters to be displayed instead of those typed, or causes typed characters to show

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetPasswordChar ( $hWnd [, $sDisplayChar = "*"] )

## Parameters

$hWnd | Handle to the control
$sDisplayChar | [optional] The character to be displayed in place of the characters typed by the user. Special value: "" - characters typed are displayed

## Return Value

Succcess: | True.
Failure: | False and sets the @error flag to non-zero.
@error: | 101 - $hWnd is not a handle 102 - $sDisplayChar is not a character

## Related

_GUICtrlRichEdit_GetPasswordChar

## See Also

Search EM_SETPASSWORDCHAR in MSDN Library.

## Example

    #include <GUIConstantsEx.au3>
    #include <GuiRichEdit.au3>
    #include <WindowsStylesConstants.au3>

    Global $g_idLbl_Msg, $g_hRichEdit

    Example()

    Func Example()
        Local $hGui, $iMsg, $idBtn_Next, $iStep = 0
        $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, StringLen(".exe")) & ")", 320, 350, -1, -1)
        $g_hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
                BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
        $g_idLbl_Msg = GUICtrlCreateLabel("", 10, 235, 300, 60)
        $idBtn_Next = GUICtrlCreateButton("Next", 270, 310, 40, 30)
        GUISetState(@SW_SHOW)

        Report("Initial state after creation:")

        While True
            $iMsg = GUIGetMsg()
            Select
                Case $iMsg = $GUI_EVENT_CLOSE
                    _GUICtrlRichEdit_Destroy($g_hRichEdit) ; needed unless script crashes
                    ; GUIDelete()   ; is OK too
                    Exit
                Case $iMsg = $idBtn_Next
                    $iStep += 1
                    Switch $iStep
                        Case 1
                            _GUICtrlRichEdit_SetPasswordChar($g_hRichEdit, "*")
                            Report("Changed password character. Type some text")
                        Case 2
                            _GUICtrlRichEdit_SetPasswordChar($g_hRichEdit, "")
                            Report("Changed it back")
                            GUICtrlSetState($idBtn_Next, $GUI_DISABLE)
                    EndSwitch
            EndSelect
        WEnd
    EndFunc   ;==>Example

    Func Report($sMsg)
        Local $sPasswordChar
        $sPasswordChar = _GUICtrlRichEdit_GetPasswordChar($g_hRichEdit)
        If $sPasswordChar = "" Then
            $sMsg &= @CRLF & "Characters appear as typed"
        Else
            $sMsg = $sMsg & @CRLF & "Typed characters appear as " & $sPasswordChar & "s"
        EndIf
        GUICtrlSetData($g_idLbl_Msg, $sMsg)
    EndFunc   ;==>Report