# Function Reference

# _GDIPlus_EffectCreateTint

Creates a Tint class effect object

#include <GDIPlus.au3>
_GDIPlus_EffectCreateTint ( [$iHue = 0 [, $iAmount = 0]] )

## Parameters

$iHue | [optional] Integer in the range -180 through 180 that specifies the hue to be strengthened or weakened.
$iAmount | [optional] Integer in the range -100 through 100 that specifies how much the hue (given by the hue parameter) is strengthened or weakened.

## Return Value

Success: | a handle to an Effect object.
Failure: | 0 and sets the @error flag to non-zero, @extended may contain GPSTATUS error code ($GDIP_ERR* see GPIPlusConstants.au3).
@error: | -1 - GDIPlus.dll does not support this function. 10 - Invalid parameters.

## Remarks

When you are done with the Effect object, call _GDIPlus_EffectDispose() to release the resources.

## Related

_GDIPlus_EffectCreate, _GDIPlus_EffectDispose

## Example

    #include <GDIPlus.au3>
    #include <GUIConstantsEx.au3>
    #include <MsgBoxConstants.au3>

    _Example()

    Func _Example()
        If Not _GDIPlus_Startup() Or @extended < 6 Then
            MsgBox($MB_SYSTEMMODAL, "ERROR", "GDIPlus.dll v1.1 not available")
            Return
        EndIf

        Local $sFile = FileOpenDialog("Select an image", "", "Images (*.bmp;*.png;*.jpg;*.gif;*.tif)")
        If @error Or Not FileExists($sFile) Then Return

        Local $hImage = _GDIPlus_ImageLoadFromFile($sFile)

        Local $iWidth = 600
        Local $iHeight = _GDIPlus_ImageGetHeight($hImage) * 600 / _GDIPlus_ImageGetWidth($hImage)

        Local $hGui = GUICreate("GDI+ v1.1 (" & @ScriptName & ")", $iWidth, $iHeight)
        Local $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGui)
        GUISetState(@SW_SHOW)

        Local $hEffect = _GDIPlus_EffectCreateTint(20, 80)
        _GDIPlus_BitmapApplyEffect($hImage, $hEffect)

        _GDIPlus_GraphicsDrawImageRect($hGraphics, $hImage, 0, 0, $iWidth, $iHeight)

        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE

        _GDIPlus_EffectDispose($hEffect)
        _GDIPlus_ImageDispose($hImage)
        _GDIPlus_GraphicsDispose($hGraphics)
        _GDIPlus_Shutdown()
    EndFunc   ;==>_Example