# Function Reference

# _GUICtrlRichEdit_GetSel

Gets the low and high inter-character positions of a selection

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetSel ( $hWnd )

## Parameters

$hWnd | Handle to the control

## Return Value

Success: | an array in the format [<low>, <high>].
Failure: | sets the @error flag to non-zero.
@error: | 101 - $hWnd is not a handle

## Remarks

The first character of the text is after inter-character position 0.
If high = low, no text is selected.

## Related

_GUICtrlRichEdit_Deselect, _GUICtrlRichEdit_GetSelAA, _GUICtrlRichEdit_GetSelText, _GUICtrlRichEdit_GetTextInLine, _GUICtrlRichEdit_IsTextSelected, _GUICtrlRichEdit_SetSel

## See Also

Search EM_EXGETSEL in MSDN Library.

## Example

    #include <GUIConstantsEx.au3>
    #include <GuiRichEdit.au3>
    #include <WindowsStylesConstants.au3>

    Global $g_idLbl_Msg, $g_hRichEdit

    Example()

    Func Example()
        Local $hGui = GUICreate("RichEdit Get/Set Sel (v" & @AutoItVersion & ")", 320, 350, -1, -1)
        $g_hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
                BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL, $ES_NOHIDESEL))
        $g_idLbl_Msg = GUICtrlCreateLabel("", 10, 235, 300, 60)
        Local $idBtn_Next = GUICtrlCreateButton("Next", 270, 310, 40, 30)
        GUISetState(@SW_SHOW)

        Local $iMsg, $iStep = 0, $iCp1
        While True
            $iMsg = GUIGetMsg()
            Select
                Case $iMsg = $GUI_EVENT_CLOSE
                    _GUICtrlRichEdit_Destroy($g_hRichEdit) ; needed unless script crashes
                    ; GUIDelete()   ; is OK too
                    Exit
                Case $iMsg = $idBtn_Next
                    $iStep += 1
                    Switch $iStep
                        Case 1
                            _GUICtrlRichEdit_SetSel($g_hRichEdit, 0, 3)
                            Report("1. Initial Character attributes at start of line 1 are")
                        Case 2
                            _GUICtrlRichEdit_AutoDetectURL($g_hRichEdit, True)
                            _GUICtrlRichEdit_AppendText($g_hRichEdit, @CRLF & "http://www.autoitscript.com")
                            $iCp1 = _GUICtrlRichEdit_GetFirstCharPosOnLine($g_hRichEdit, 2)
                            _GUICtrlRichEdit_SetSel($g_hRichEdit, $iCp1, $iCp1 + 3)
                            Report("2. Character attributes at start of line 2 are")
                            GUICtrlSetState($idBtn_Next, $GUI_DISABLE)
                    EndSwitch
            EndSelect
        WEnd
    EndFunc   ;==>Example

    Func Report($sMsg)
        Local $sRet = _GUICtrlRichEdit_GetCharAttributes($g_hRichEdit)
        $sMsg = $sMsg & @CRLF & @CRLF & "Char Attributes=" & $sRet
        GUICtrlSetData($g_idLbl_Msg, $sMsg)
    EndFunc   ;==>Report