# Function Reference

# _GUICtrlAVI_OpenEx

Opens an AVI clip and displays its first frame in an animation control

#include <GuiAVI.au3>
_GUICtrlAVI_OpenEx ( $hWnd, $sFileName, $iResourceID )

## Parameters

$hWnd | Control ID/Handle to the control
$sFileName | Fully qualified path to resource file
$iResourceID | AVI resource identifier

## Return Value

Success: | True.
Failure: | False.

## Remarks

You can only open silent AVI clips.

## Related

_GUICtrlAVI_Open

## Example

    #include <GuiAVI.au3>
    #include <GUIConstantsEx.au3>

    Example()

    Func Example()
        Local $hGUI, $hAVI

        ; Create GUI
        $hGUI = GUICreate("(External) AVI OpenEx", 300, 100)
        $hAVI = _GUICtrlAVI_Create($hGUI, "", -1, 10, 10)
        GUISetState(@SW_SHOW)

        ; Play the sample AutoIt AVI
        _GUICtrlAVI_OpenEx($hAVI, @SystemDir & "\Shell32.dll", 150)

        ; Play the sample AutoIt AVI
        _GUICtrlAVI_Play($hAVI)

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE

        ; Close AVI clip
        _GUICtrlAVI_Close($hAVI)

        GUIDelete()
    EndFunc   ;==>Example