# Function Reference

# _Net_Share_SessionEnum

Provides information about sessions established on a server

#include <NetShare.au3>
_Net_Share_SessionEnum ( [$sServer = "" [, $sClientName = "" [, $sUserName = ""]]] )

## Parameters

$sServer | [optional] String that specifies the DNS or NetBIOS name of the remote server on which the function is to execute. If this parameter is blank the local computer is used.
$sClientName | [optional] Specifies the name of the computer session for which information is to be returned. If this parameter is blank, the function returns information for all computer sessions on the server.
$sUserName | [optional] Specifies the name of the user for which information is to be returned. If this parameter is blank, the function returns information for all users.

## Return Value

Success: | an array with the following format: [0][0] - Number of entries in array [1][0] - Name of the computer that established the session [1][1] - Name of the user who established the session [1][2] - Number of files, devices, and pipes opened during the session [1][3] - Number of seconds the session has been active [1][4] - Number of seconds the session has been idle [1][5] - Specifies how the user established the session: 1 - User established session using a guest account 2 - User established session without using password encryption [1][6] - Specifies the type of client that established the session [1][7] - Name of the transport that the client is using
Failure: | sets the @error flag to non-zero.

## Remarks

Only members of the Administrators or Server Operators local group can execute this function.

## Related

_Net_Share_ConnectionEnum, _Net_Share_FileEnum, _Net_Share_ShareEnum

## See Also

Search NetSessionEnum in MSDN Library.

## Example

    #include "Extras\HelpFileInternals.au3"

    #include <GUIConstantsEx.au3>
    #include <NetShare.au3>
    #include <WindowsStylesConstants.au3>

    Example()

    Func Example()
        Local $sServer, $aInfo

        ; Create GUI
        GUICreate("NetShare", 400, 300)

        ; Create memo control
        _MemoCreate(2, 2, 396, 296, $WS_VSCROLL)
        GUISetState(@SW_SHOW)

        ; Get server and share information
        $sServer = InputBox("NetWork Demo", "Enter Server Name:", "\\MyServer", "", 200, 130)
        If @error Then Exit

        ; Enumerate network sessions
        $aInfo = _Net_Share_SessionEnum($sServer, @ComputerName)
        _MemoWrite("Error ..........: " & @error)
        _MemoWrite("Entries read ...: " & $aInfo[0][0])
        For $iI = 1 To $aInfo[0][0]
            _MemoWrite("Computer name ..: " & $aInfo[$iI][0])
            _MemoWrite("User name.......: " & $aInfo[$iI][1])
            _MemoWrite("Resources open .: " & $aInfo[$iI][2])
            _MemoWrite("Seconds active .: " & $aInfo[$iI][3])
            _MemoWrite("Seconds idle ...: " & $aInfo[$iI][4])
            _MemoWrite("Connection type : " & $aInfo[$iI][5])
            _MemoWrite("Client type ....: " & $aInfo[$iI][6])
            _MemoWrite("Transport ......: " & $aInfo[$iI][7])
            _MemoWrite()
        Next

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
    EndFunc   ;==>Example