# Function Reference

# GUISetBkColor

Sets the background color of the GUI window.

GUISetBkColor ( background [, winhandle] )

## Parameters

background | Background color of the dialog box, in RGB Hex format.
winhandle | [optional] Windows handle as returned by GUICreate() (default is the previously used window).

## Return Value

Success: | 1.
Failure: | 0.

## Remarks

Constants for colors are defined in "ColorConstants.au3".

## Related

GUICreate

## Example

    #include <ColorConstants.au3>
    #include <GUIConstantsEx.au3>
    #include <WindowsSysColorConstants.au3>

    Example()

    Func Example()
        GUICreate("My GUI") ; will create a dialog box that when displayed is centered

        GUISetBkColor($COLOR_RED) ; will change background color

        GUISetState(@SW_SHOW) ; will display an empty dialog box

        ; Loop until the user exits.
        While 1
            Switch GUIGetMsg()
                Case $GUI_EVENT_CLOSE
                    ExitLoop

            EndSwitch
        WEnd

        GUIDelete()
    EndFunc   ;==>Example