# Function Reference

# _GUICtrlMonthCal_SetCalendarBorder

Sets the size of the border, in pixels

#include <GuiMonthCal.au3>
_GUICtrlMonthCal_SetCalendarBorder ( $hWnd [, $iBorderSize = 4 [, $bSetBorder = True]] )

## Parameters

$hWnd | Control ID/Handle to the control
$iBorderSize | [optional] Number of pixels of the border size
$bSetBorder | [optional] One of the Following: True - The border size is set to the number of pixels that $iBorderSize specifies False - The border size is reset to the default value specified by the theme, or zero if themes are not being used

## Return Value

None.

## Remarks

Windows Vista or later.

## Related

_GUICtrlMonthCal_GetCalendarBorder

## Example

    #include "Extras\HelpFileInternals.au3"

    #include <GUIConstantsEx.au3>
    #include <GuiMonthCal.au3>
    #include <WindowsStylesConstants.au3>

    Example()

    Func Example()
        Local $idMonthCal

        ; Create GUI
        GUICreate("Month Calendar", 400, 300)
        $idMonthCal = GUICtrlCreateMonthCal("", 4, 4, -1, -1, $WS_BORDER, 0x00000000)

        ; Create memo control
        _MemoCreate(4, 168, 392, 128, 0)
        GUISetState(@SW_SHOW)

        ; Get/Set calendar border
        _MemoWrite("Border in pixels: " & _GUICtrlMonthCal_GetCalendarBorder($idMonthCal))
        Sleep(3000)
        GUISetState(@SW_LOCK)
        _GUICtrlMonthCal_SetCalendarBorder($idMonthCal, 2)
        _MemoWrite("Border in pixels: " & _GUICtrlMonthCal_GetCalendarBorder($idMonthCal))
        GUISetState(@SW_UNLOCK)
        Sleep(3000)
        GUISetState(@SW_LOCK)
        _GUICtrlMonthCal_SetCalendarBorder($idMonthCal, 0, False)
        _MemoWrite("Border in pixels: " & _GUICtrlMonthCal_GetCalendarBorder($idMonthCal))
        GUISetState(@SW_UNLOCK)

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
        GUIDelete()
    EndFunc   ;==>Example