# Function Reference

# _GUICtrlRichEdit_GetParaIndents

Gets the border indent settings of (first) selected paragraph or (if no selection) of the current paragraph

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetParaIndents ( $hWnd )

## Parameters

$hWnd | Handle to the control

## Return Value

Success: | settings - a string consisting of values separated by semicolons (:): Value 1 - Left - indentation of left side of the body of the paragraph (of lines after the first) (in space units) Value 2 - Right - indentation of right side of the paragraph (in space units) Value 3 - FirstLine - indentation of the first line relative to other lines (in space units) Value 4 - scope: a - all (or only) selected paragraphs have these settings f - the first selected paragraph has these settings, but other(s) don't c - the current paragraph has these settings
Failure: | Empty string and sets the @error flag to non-zero.
@error: | 101 - $hWnd is not a handle

## Remarks

Postive values of $iLeft, $iRight and $iFirstLine indent towards the center of the paragraph.

## Related

_GUICtrlRichEdit_SetParaIndents

## See Also

Search EM_GETPARAFORMAT in MSDN Library.

## Example

    #include <GUIConstantsEx.au3>
    #include <GuiRichEdit.au3>
    #include <WindowsStylesConstants.au3>

    Global $g_idLbl_Msg, $g_hRichEdit

    Example()

    Func Example()
        Local $hGui, $iMsg, $idBtn_Next, $iStep = 0
        $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, StringLen(".exe")) & ")", 320, 350, -1, -1)
        $g_hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
                BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
        $g_idLbl_Msg = GUICtrlCreateLabel("", 10, 235, 300, 60)
        $idBtn_Next = GUICtrlCreateButton("Next", 270, 310, 40, 30)
        GUISetState(@SW_SHOW)

        _GUICtrlRichEdit_SetText($g_hRichEdit, "First paragraph")
        Report("Para with default indent settings")

        While True
            $iMsg = GUIGetMsg()
            Select
                Case $iMsg = $GUI_EVENT_CLOSE
                    _GUICtrlRichEdit_Destroy($g_hRichEdit) ; needed unless script crashes
                    ; GUIDelete()   ; is OK too
                    Exit
                Case $iMsg = $idBtn_Next
                    $iStep += 1
                    Switch $iStep
                        Case 1
                            _GUICtrlRichEdit_AppendText($g_hRichEdit, @CRLF & "Second paragraph")
                            Report("Added second paragraph")
                        Case 2
                            _GUICtrlRichEdit_SetParaIndents($g_hRichEdit, 0.25, .1)
                            Report("Changed indent settings of second paragraph")
                        Case 3
                            _GUICtrlRichEdit_SetSel($g_hRichEdit, 10, 26)
                            _GUICtrlRichEdit_SetParaIndents($g_hRichEdit, Default, 0, .2)
                            Report("Change settings of both paragraphs")
                        Case 4
                            ; Stream all text to the Desktop so you can look at Indents settings in Word
                            _GUICtrlRichEdit_Deselect($g_hRichEdit)
                            _GUICtrlRichEdit_StreamToFile($g_hRichEdit, @DesktopDir & "\gcre.rtf")
                            GUICtrlSetState($idBtn_Next, $GUI_DISABLE)
                    EndSwitch
            EndSelect
        WEnd
    EndFunc   ;==>Example

    Func Report($sMsg)
        $sMsg = $sMsg & @CRLF & @CRLF & "Get function returns " & @CRLF & _GUICtrlRichEdit_GetParaIndents($g_hRichEdit)
        GUICtrlSetData($g_idLbl_Msg, $sMsg)
    EndFunc   ;==>Report