# Function Reference

# _GUICtrlSlider_ClearTics

Removes the current tick marks from a slider

#include <GuiSlider.au3>
_GUICtrlSlider_ClearTics ( $hWnd )

## Parameters

$hWnd | Control ID/Handle to the control

## Return Value

None.

## Remarks

This does not remove the first and last tick marks, which are created automatically.

## Related

_GUICtrlSlider_SetTic, _GUICtrlSlider_SetTicFreq

## Example

    #include <GUIConstantsEx.au3>
    #include <GuiSlider.au3>
    #include <MsgBoxConstants.au3>

    Example()

    Func Example()
        Local $idSlider

        ; Create GUI
        GUICreate("(Internal) Slider Clear Tics", 400, 296)
        $idSlider = GUICtrlCreateSlider(2, 2, 396, 20, BitOR($TBS_TOOLTIPS, $TBS_AUTOTICKS, $TBS_ENABLESELRANGE))
        GUISetState(@SW_SHOW)

        MsgBox($MB_SYSTEMMODAL, "Information", "Clear Tics")
        ; Clear Tics
        _GUICtrlSlider_ClearTics($idSlider)

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
        GUIDelete()
    EndFunc   ;==>Example