# Function Reference

# _GUICtrlAVI_Open

Opens an AVI clip and displays its first frame in an animation control

#include <GuiAVI.au3>
_GUICtrlAVI_Open ( $hWnd, $sFileName )

## Parameters

$hWnd | Control ID/Handle to the control
$sFileName | Fully qualified path to the AVI file

## Return Value

Success: | True.
Failure: | False.

## Remarks

You can only open silent AVI clips.

## Related

_GUICtrlAVI_Close, _GUICtrlAVI_OpenEx

## Example

    #include <GuiAVI.au3>
    #include <GUIConstantsEx.au3>

    Example()

    Func Example()
        Local $sWow64 = ""
        If @AutoItX64 Then $sWow64 = "\Wow6432Node"
        Local $sFile = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE" & $sWow64 & "\AutoIt v3\AutoIt", "InstallDir") & "\Examples\GUI\SampleAVI.avi"

        ; Create GUI
        Local $hGUI = GUICreate("(External) AVI Open (v" & @AutoItVersion & ")", 325, 100)
        Local $hAVI = _GUICtrlAVI_Create($hGUI, "", -1, 10, 10)
        GUISetState(@SW_SHOW)

        ; Play the sample AutoIt AVI
        _GUICtrlAVI_Open($hAVI, $sFile)

        ; Play the sample AutoIt AVI
        _GUICtrlAVI_Play($hAVI)

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE

        ; Close AVI clip
        _GUICtrlAVI_Close($hAVI)

        GUIDelete()
    EndFunc   ;==>Example