# Function Reference

# GUICtrlCreateMonthCal

Creates a month calendar control for the GUI.

GUICtrlCreateMonthCal ( "text", left, top [, width [, height [, style = -1 [, exStyle = -1]]]] )

## Parameters

text | The preselected date (always as "yyyy/mm/dd").
left | The left side of the control. If -1 is used then left will be computed according to GUICoordMode.
top | The top of the control. If -1 is used then top will be computed according to GUICoordMode.
width | [optional] The width of the control (default is the previously used width).
height | [optional] The height of the control (default is the previously used height).
style | [optional] Defines the style of the control. See GUI Control Styles Appendix. default (-1) : none. forced style : $WS_TABSTOP
exStyle | [optional] Defines the extended style of the control. See Extended Style Table. default (-1) : WS_EX_CLIENTEDGE

## Return Value

Success: | the identifier (controlID) of the new control.
Failure: | 0.

## Remarks

To obtain the value of the control see GUICtrlRead().
Default resizing is $GUI_DOCKSIZE.

## Related

GUICoordMode (Option), GUICtrlRead, GUIGetMsg

## Example

    #include <GUIConstantsEx.au3>
    #include <MsgBoxConstants.au3>

    Example()

    Func Example()
        GUICreate("Get date", 210, 190)

        Local $idMC_Date = GUICtrlCreateMonthCal("1953/03/25", 10, 10)
        GUISetState(@SW_SHOW)

        ; Loop until the user exits.
        While 1
            Switch GUIGetMsg()
                Case $GUI_EVENT_CLOSE
                    ExitLoop

                Case $idMC_Date
                    MsgBox($MB_SYSTEMMODAL, "debug", "calendar clicked")

            EndSwitch
        WEnd

        MsgBox($MB_SYSTEMMODAL, "Date", GUICtrlRead($idMC_Date), 2)
    EndFunc   ;==>Example