# Function Reference

# _GUICtrlRichEdit_FindText

Search for a text starting at insertion point or at anchor point of selection

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_FindText ( $hWnd, $sText [, $bForward = True [, $bMatchCase = False [, $bWholeWord = False [, $iBehavior = 0]]]] )

## Parameters

$hWnd | Handle to the control
$sText | Text to find
$bForward | [optional] Search direction (Win 95: search is always forward)
$bMatchCase | [optional] Search is case-sensitive Default: case-insensitive
$bWholeWord | [optional] Search only for text as a whole word Default: partial or full word
$iBehavior | [optional] Any BitOR combination of $FR_MATCHALEFHAMZA, $FR_MATCHDIAC and $FR_MATCHKASHIDA Default: 0

## Return Value

Success: | the inter-character position before start of matching text if found, else -1.
Failure: | sets the @error flag to non-zero.
@error: | 101 - $hWnd is not a handle 102 - $sText = "" 103 - $bForward is neither True nor False 104 - $bMatchCase is neither True nor False 105 - $bWholeWord is neither True nor False 1061 - $iBehavior is not a number 1062 - $iBehavior is invalid

## Related

_GUICtrlRichEdit_FindTextInRange

## See Also

Search EM_FINDTEXT in MSDN Library.

## Example

### Example 1

    #include <GUIConstantsEx.au3>
    #include <GuiRichEdit.au3>
    #include <WindowsStylesConstants.au3>

    Global $g_idLbl_Msg

    Example()

    Func Example()
        Local $hGui, $iMsg, $idBtn_Next, $hRichEdit, $iStep = 0
        $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, StringLen(".exe")) & ")", 320, 350, -1, -1)
        $hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
                BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
        $g_idLbl_Msg = GUICtrlCreateLabel("", 10, 235, 300, 60)
        $idBtn_Next = GUICtrlCreateButton("Next", 270, 310, 40, 30)
        GUISetState(@SW_SHOW)

        _GUICtrlRichEdit_AppendText($hRichEdit, @CRLF & "This is appended text.")

        While True
            $iMsg = GUIGetMsg()
            Select
                Case $iMsg = $GUI_EVENT_CLOSE
                    _GUICtrlRichEdit_Destroy($hRichEdit) ; needed unless script crashes
                    ; GUIDelete()   ; is OK too
                    Exit
                Case $iMsg = $idBtn_Next
                    $iStep += 1
                    Switch $iStep
                        Case 1
                            _GUICtrlRichEdit_SetSel($hRichEdit, 8, 8)
                            Report("1.set starting position ")
                        Case 2
                            Report('2."appended" found just after inter-character position ' & _
                                    _GUICtrlRichEdit_FindText($hRichEdit, "appended"))
                            GUICtrlSetState($idBtn_Next, $GUI_DISABLE)
                    EndSwitch
            EndSelect
        WEnd
    EndFunc   ;==>Example

    Func Report($sMsg)
        GUICtrlSetData($g_idLbl_Msg, $sMsg)
    EndFunc   ;==>Report

### Example 2

    #include <GuiRichEdit.au3>

    Local $sText = "First line" & @CR & @CR & "Last line" & @CR
    Local $iStart, $iEnd, $sLine, $i
    Local $iTextLen
    Local $iFindTextError, $iGetTextError
    Local $sMsgBuff = ""

    Local $hGUI = GUICreate("Find Text Test", 300, 300)
    Local $hRichEdit = _GUICtrlRichEdit_Create($hGUI, "", 10, 10, 280, 280)
    GUISetState(@SW_SHOW, $hGUI)

    _GUICtrlRichEdit_SetText($hRichEdit, $sText)
    $iStart = 0
    $iTextLen = _GUICtrlRichEdit_GetTextLength($hRichEdit, True, True)
    $sMsgBuff = $iTextLen & " characters in Rich Edit box"

    For $i = 1 To 6
        If Not _GUICtrlRichEdit_GotoCharPos($hRichEdit, $iStart) Then
    ;~      MsgBox(0, "", "False from GotoCharPos")
            ExitLoop
        EndIf
        $iEnd = _GUICtrlRichEdit_FindText($hRichEdit, @CR) ; Find the next CR
        If $iEnd = -1 Then ExitLoop
        $iFindTextError = @error
        If $iEnd = $iStart Then
            $sLine = "" ; end = start just means a blank line
            $iGetTextError = 0
        Else
            $sLine = _GUICtrlRichEdit_GetTextInRange($hRichEdit, $iStart, $iEnd) ; the line is all characters between start and end
            $iGetTextError = @error
        EndIf
        $sMsgBuff &= @CRLF & $i & ": Start = " & $iStart & ", End = " & $iEnd & ": <" & $sLine & ">  (@errors = " & $iFindTextError & ", " & $iGetTextError & ")" ; accumulate results
        $iStart = $iEnd + 1 ; Next search starts one character after the last found CR
    Next
    MsgBox(0, "Test results", $sMsgBuff)
    _GUICtrlRichEdit_Destroy($hRichEdit)
    GUIDelete($hGUI)
    Exit