# Function Reference

# _GUICtrlListView_GetSelectedCount

Determines the number of selected items

#include <GuiListView.au3>
_GUICtrlListView_GetSelectedCount ( $hWnd )

## Parameters

$hWnd | Control ID/Handle to the control

## Return Value

Returns the number of selected items.

## Example

    #include <GUIConstantsEx.au3>
    #include <GuiListView.au3>
    #include <MsgBoxConstants.au3>

    Example()

    Func Example()
        Local $idListview

        GUICreate("ListView Get Selected Count", 400, 300)
        $idListview = GUICtrlCreateListView("", 2, 2, 394, 268, BitOR($LVS_SHOWSELALWAYS, $LVS_REPORT))
        GUISetState(@SW_SHOW)

        ; Add columns
        _GUICtrlListView_AddColumn($idListview, "Column 1", 100)

        ; Add items
        _GUICtrlListView_AddItem($idListview, "Item 1")
        _GUICtrlListView_AddItem($idListview, "Item 2")
        _GUICtrlListView_AddItem($idListview, "Item 3")

        ; Select multiple items
        _GUICtrlListView_SetItemSelected($idListview, 1)
        _GUICtrlListView_SetItemSelected($idListview, 2)
        MsgBox($MB_SYSTEMMODAL, "Information", "Selected Count: " & _GUICtrlListView_GetSelectedCount($idListview))

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
        GUIDelete()
    EndFunc   ;==>Example