# Function Reference

# _GUICtrlComboBox_GetListArray

Retrieves all items from the list portion of a ComboBox control

#include <GuiComboBox.au3>
_GUICtrlComboBox_GetListArray ( $hWnd )

## Parameters

$hWnd | Control ID/Handle to the control

## Return Value

Returns an array in the following format:
[0] - Number of items
[1] - Item 1
[2] - Item 2
[n] - Item n

## Related

_GUICtrlComboBox_GetList

## Example

    #include "Extras\HelpFileInternals.au3"

    #include <DirConstants.au3>
    #include <GuiComboBox.au3>
    #include <GUIConstantsEx.au3>

    Example()

    Func Example()
        Local $aList, $idCombo

        ; Create GUI
        GUICreate("ComboBox Get List Array", 400, 296)
        $idCombo = GUICtrlCreateCombo("", 2, 2, 396, 296)
        _MemoCreate(2, 32, 396, 266, 0)
        GUISetState(@SW_SHOW)

        ; Add files
        _GUICtrlComboBox_AddDir($idCombo, "", $DDL_DRIVES, False)

        ; Get List
        $aList = _GUICtrlComboBox_GetListArray($idCombo)
        For $x = 1 To $aList[0]
            _MemoWrite($aList[$x])
        Next

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
        GUIDelete()
    EndFunc   ;==>Example