# Function Reference

# _GDIPlus_EffectGetParameters

Returns the parameters for the specified Effect object

#include <GDIPlus.au3>
_GDIPlus_EffectGetParameters ( $hEffect, $tEffectParameters )

## Parameters

$hEffect | Handle to an Effect object.
$tEffectParameters | A DLL structure that receives the effect parameters.

## Return Value

Success: | True.
Failure: | False and sets the @error flag to non-zero, @extended may contain GPSTATUS error code ($GDIP_ERR* see GPIPlusConstants.au3).
@error: | -1 - GDIPlus.dll does not support this function. 10 - Invalid parameters.

## Related

_GDIPlus_EffectCreate, _GDIPlus_EffectSetParameters

## See Also

Search GdipGetEffectParameters in MSDN Library.

## Example

    #include <GDIPlus.au3>
    #include <MsgBoxConstants.au3>

    _Example()

    Func _Example()
        If Not _GDIPlus_Startup() Or @extended < 6 Then
            MsgBox($MB_SYSTEMMODAL, "ERROR", "GDIPlus.dll v1.1 not available")
            Return
        EndIf

        Local $hEffect = _GDIPlus_EffectCreate($GDIP_SharpenEffectGuid)
        Local $tEffectParameters = DllStructCreate($tagGDIP_EFFECTPARAMS_Sharpen)

        _GDIPlus_EffectGetParameters($hEffect, $tEffectParameters)
        ConsoleWrite("> default value of Sharpen_Radius: " & $tEffectParameters.Radius & @CRLF)
        ConsoleWrite("> default value of Sharpen_Amount: " & $tEffectParameters.Amount & @CRLF)

        _GDIPlus_EffectDispose($hEffect)
        _GDIPlus_Shutdown()

    EndFunc   ;==>_Example