# Function Reference

# _GUICtrlHeader_ClearFilterAll

Clears all of the filters

#include <GuiHeader.au3>
_GUICtrlHeader_ClearFilterAll ( $hWnd )

## Parameters

$hWnd | Handle to the control

## Return Value

Success: | True.
Failure: | False.

## Related

_GUICtrlHeader_ClearFilter, _GUICtrlHeader_EditFilter

## Example

    #include "Extras\HelpFileInternals.au3"

    #include <GUIConstantsEx.au3>
    #include <GuiHeader.au3>

    Example()

    Func Example()
        ; Create GUI
        Local $hGUI = GUICreate("Header Clear FilterAll (v" & @AutoItVersion & ")", 450, 300, 100, 100)
        Local $hHeader = _GUICtrlHeader_Create($hGUI, $HDS_FILTERBAR)
        _MemoCreate(2, 52, 444, 220)

    ;~  _GUICtrlHeader_SetUnicodeFormat($hHeader, True)

        GUISetState(@SW_SHOW)

        ; Add columns
        _GUICtrlHeader_AddItem($hHeader, "Column 1", 100)
        _GUICtrlHeader_AddItem($hHeader, "Column 2", 100)
        _GUICtrlHeader_AddItem($hHeader, "Column 3", 100)
        _GUICtrlHeader_AddItem($hHeader, "Column 4", 100)

        ; Set up filters
        _GUICtrlHeader_EditFilter($hHeader, 0)
        ControlSend("[ACTIVE]", "", "", "Filter 0{ENTER}")
        _MemoMsgBox($MB_SYSTEMMODAL, "Information", "Filter 0 Changed")

        _GUICtrlHeader_EditFilter($hHeader, 1)
        ControlSend("[ACTIVE]", "", "", "Filter 1{ENTER}")
        _MemoMsgBox($MB_SYSTEMMODAL, "Information", "Filter 1 Changed")

        ; Clear all filters
        _GUICtrlHeader_ClearFilterAll($hHeader)
        _MemoMsgBox($MB_SYSTEMMODAL, "Information", "All Filters Cleared")

        _MemoMsgBoxStatus("", Default, $hGUI) ; no more action, wait GUI for closing

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
    EndFunc   ;==>Example