# Function Reference

# _GUICtrlRebar_SetBandStyleFixedSize

Set whether the band can't be sized. With this style, the sizing grip is not displayed on the band

#include <GuiReBar.au3>
_GUICtrlRebar_SetBandStyleFixedSize ( $hWnd, $iIndex [, $bEnabled = True] )

## Parameters

$hWnd | Handle to the rebar control
$iIndex | 0-based index of the band
$bEnabled | [optional] If True the item state is set, otherwise it is not set

## Return Value

Success: | True.
Failure: | False.

## Related

_GUICtrlRebar_GetBandStyleFixedSize, _GUICtrlRebar_SetBandStyle

## Example

    #include "Extras\HelpFileInternals.au3"

    #include <AutoItConstants.au3>
    #include <GUIConstantsEx.au3>
    #include <GuiReBar.au3>
    #include <GuiToolbar.au3>
    #include <MsgBoxConstants.au3>
    #include <WinAPIConstants.au3>
    #include <WindowsStylesConstants.au3>

    Example()

    Func Example()
        Local $hGui = GUICreate("Rebar Get/Set Band Style Fixed Size (v" & @AutoItVersion & ")", 420, 396, -1, -1, BitOR($WS_MINIMIZEBOX, $WS_CAPTION, $WS_POPUP, $WS_SYSMENU, $WS_MAXIMIZEBOX))

        ; create the rebar control
        Local $hReBar = _GUICtrlRebar_Create($hGui, BitOR($CCS_TOP, $WS_BORDER, $RBS_VARHEIGHT, $RBS_AUTOSIZE, $RBS_BANDBORDERS))

        _MemoCreate(2, 100, 416, 250, $WS_VSCROLL)

        ; create a toolbar to put in the rebar
        Local $hToolbar = _GUICtrlToolbar_Create($hGui, BitOR($TBSTYLE_FLAT, $CCS_NORESIZE, $CCS_NOPARENTALIGN))

        ; Add standard system bitmaps
        Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
            Case 0
                _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
            Case 2
                _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
        EndSwitch

        ; Add buttons
        Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $e_idHelp
        _GUICtrlToolbar_AddButton($hToolbar, $e_idNew, $STD_FILENEW)
        _GUICtrlToolbar_AddButton($hToolbar, $e_idOpen, $STD_FILEOPEN)
        _GUICtrlToolbar_AddButton($hToolbar, $e_idSave, $STD_FILESAVE)
        _GUICtrlToolbar_AddButtonSep($hToolbar)
        _GUICtrlToolbar_AddButton($hToolbar, $e_idHelp, $STD_HELP)

        ; create a input box to put in the rebar
        Local $idInput = GUICtrlCreateInput("Input control", 0, 0, 120, 20)

        ;add band containing the control
        _GUICtrlRebar_AddBand($hReBar, GUICtrlGetHandle($idInput), 120, 200, "Name:")

        ; add band containing the control to the beginning of rebar
        _GUICtrlRebar_AddToolBarBand($hReBar, $hToolbar, "", 0)

        Local $idBtn_Exit = GUICtrlCreateButton("Exit", 150, 360, 100, 25)
        GUICtrlSetState($idBtn_Exit, $GUI_DEFBUTTON)
        GUICtrlSetState($idBtn_Exit, $GUI_FOCUS)

        GUISetState(@SW_SHOW)

        MsgBox($MB_SYSTEMMODAL, "Information", "Setting Fixed Size Style")
        _GUICtrlRebar_SetBandStyleFixedSize($hReBar, 1)

        For $x = 0 To _GUICtrlRebar_GetBandCount($hReBar) - 1
            _MemoWrite("Band Index " & $x & @TAB & "$RBBS_FIXEDSIZE.....: " & _GUICtrlRebar_GetBandStyleFixedSize($hReBar, $x))
            _MemoWrite("============================================")
        Next

        MsgBox($MB_SYSTEMMODAL, "Information", "Setting Fixed Size Style")
        _GUICtrlRebar_SetBandStyleFixedSize($hReBar, 1, False)

        For $x = 0 To _GUICtrlRebar_GetBandCount($hReBar) - 1
            _MemoWrite("Band Index " & $x & @TAB & "$RBBS_FIXEDSIZE.....: " & _GUICtrlRebar_GetBandStyleFixedSize($hReBar, $x))
            _MemoWrite("============================================")
        Next

        While 1
            Switch GUIGetMsg()
                Case $GUI_EVENT_CLOSE, $idBtn_Exit
                    Exit
            EndSwitch
        WEnd
    EndFunc   ;==>Example