# Function Reference

# _GUICtrlComboBoxEx_SetImageList

Sets an image list for a ComboBoxEx control

#include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_SetImageList ( $hWnd, $hHandle )

## Parameters

$hWnd | Handle to the control
$hHandle | A handle to the image list to be set for the control

## Return Value

Returns the handle to the image list previously associated with the control, or returns NULL if no image list was previously set.

## Related

_GUICtrlComboBoxEx_GetImageList

## Example

    #include "Extras\HelpFileInternals.au3"

    #include <GuiComboBoxEx.au3>
    #include <GUIConstantsEx.au3>
    #include <GuiImageList.au3>

    Example()

    Func Example()
        ; Create GUI
        Local $hGUI = GUICreate("ComboBoxEx Get/Set Image List (v" & @AutoItVersion & ")", 400, 300)
        Local $hCombo = _GUICtrlComboBoxEx_Create($hGUI, "", 2, 2, 394, 100)
        _MemoCreate(2, 32, 396, 266, 0)
        GUISetState(@SW_SHOW)

        Local $hImage = _GUIImageList_Create(16, 16, 5, 3)
        _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 110)
        _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 131)
        _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 165)
        _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 168)
        _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 137)
        _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 146)
        _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0xFF0000, 16, 16))
        _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x00FF00, 16, 16))
        _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x0000FF, 16, 16))
        ;Set Image List
        Local $hPrevlist = _GUICtrlComboBoxEx_SetImageList($hCombo, $hImage)
        _MemoWrite("Previous ImageList Handle: " & $hPrevlist & _
                " IsPtr = " & IsPtr($hPrevlist) & " IsHWnd = " & IsHWnd($hPrevlist))

        For $x = 0 To 8
            _GUICtrlComboBoxEx_AddString($hCombo, StringFormat("%03d : Random string", Random(1, 100, 1)), $x, $x)
        Next

        ;Get Image List
        _MemoWrite("ImageList Handle: " & _GUICtrlComboBoxEx_GetImageList($hCombo) & _
                " IsPtr = " & IsPtr(_GUICtrlComboBoxEx_GetImageList($hCombo)) & _
                " IsHWnd = " & IsHWnd(_GUICtrlComboBoxEx_GetImageList($hCombo)))

        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
    EndFunc   ;==>Example