# Function Reference

# _GUICtrlRichEdit_GetTextInLine

Gets a line of text

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetTextInLine ( $hWnd, $iLine )

## Parameters

$hWnd | Handle to the control
$iLine | Line number

## Return Value

Success: | the text.
Failure: | sets the @error flag to non-zero.
@error: | 101 - $hWnd is not a handle 1021 - $iLine is not a positive number 1022 - $iLine exceeds number of lines in control 700 - internal error

## Remarks

The first line in a control is 1.

## Related

_GUICtrlRichEdit_GetSel, _GUICtrlRichEdit_GetTextInRange

## See Also

Search EM_GETLINE in MSDN Library.

## Example

    #include <GUIConstantsEx.au3>
    #include <GuiRichEdit.au3>
    #include <WindowsStylesConstants.au3>

    Global $g_idLbl_Msg

    Example()

    Func Example()
        Local $hGui, $iMsg, $hRichEdit
        $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, StringLen(".exe")) & ")", 320, 350, -1, -1)
        $hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
                BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
        $g_idLbl_Msg = GUICtrlCreateLabel("", 10, 235, 300, 60)
        GUISetState(@SW_SHOW)

        _GUICtrlRichEdit_SetText($hRichEdit, "This is a test." & @CRLF & "More text in another line")
        Report(_GUICtrlRichEdit_GetTextInLine($hRichEdit, 1))

        While True
            $iMsg = GUIGetMsg()
            Select
                Case $iMsg = $GUI_EVENT_CLOSE
                    _GUICtrlRichEdit_Destroy($hRichEdit) ; needed unless script crashes
                    ; GUIDelete()   ; is OK too
                    Exit
            EndSelect
        WEnd
    EndFunc   ;==>Example

    Func Report($sMsg)
        GUICtrlSetData($g_idLbl_Msg, $sMsg)
    EndFunc   ;==>Report