# Function Reference

# _GDIPlus_PathBrushSetFocusScales

Sets the focus scales of a path gradient brush

#include <GDIPlus.au3>
_GDIPlus_PathBrushSetFocusScales ( $hPathGradientBrush, $fScaleX, $fScaleY )

## Parameters

$hPathGradientBrush | Pointer to a PathGradientBrush object
$fScaleX | Real number that specifies the X focus scale
$fScaleY | Real number that specifies the Y focus scale

## Return Value

Success: | True.
Failure: | False and sets the @error flag to non-zero, @extended may contain GPSTATUS error code ($GDIP_ERR* see GPIPlusConstants.au3).

## Related

_GDIPlus_PathBrushGetFocusScales

## See Also

Search GdipSetPathGradientFocusScales in MSDN Library.

## Example

    #include <GDIPlus.au3>
    #include <GUIConstantsEx.au3>

    Example()

    Func Example()
        Local $hGUI = GUICreate("GDI+", 200, 180)
        GUISetState(@SW_SHOW)

        _GDIPlus_Startup()
        Local $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGUI)
        _GDIPlus_GraphicsSetSmoothingMode($hGraphics, $GDIP_SMOOTHINGMODE_HIGHQUALITY)
        _GDIPlus_GraphicsClear($hGraphics, 0xFF000000)

        Local $hPath = _GDIPlus_PathCreate()
        _GDIPlus_PathAddEllipse($hPath, 10, 10, 180, 160)

        Local $hBrush = _GDIPlus_PathBrushCreateFromPath($hPath)
        _GDIPlus_PathBrushSetFocusScales($hBrush, 0.25, 0.9)
        _GDIPlus_PathBrushSetCenterColor($hBrush, 0xFFFFFF00)
        _GDIPlus_PathBrushSetCenterPoint($hBrush, 90, 80)
        _GDIPlus_PathBrushSetSurroundColor($hBrush, 0xFF0000FF)
        _GDIPlus_PathBrushSetGammaCorrection($hBrush, True)
        _GDIPlus_GraphicsFillPath($hGraphics, $hPath, $hBrush)

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE

        ; Clean up resources
        _GDIPlus_BrushDispose($hBrush)
        _GDIPlus_PathDispose($hPath)
        _GDIPlus_GraphicsDispose($hGraphics)
        _GDIPlus_Shutdown()
    EndFunc   ;==>Example