# Function Reference

# _GUICtrlComboBoxEx_ReplaceEditSel

Replace text selected in edit box

#include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_ReplaceEditSel ( $hWnd, $sText )

## Parameters

$hWnd | Handle to the control
$sText | String containing the replacement text

## Return Value

None.

## Remarks

If the message is sent to a ComboBox with the $CBS_DROPDOWN or $CBS_DROPDOWNLIST style the Function will fail.

## Related

_GUICtrlComboBoxEx_SetEditText

## Example

    #include <GuiComboBoxEx.au3>
    #include <GUIConstantsEx.au3>
    #include <GuiImageList.au3>
    #include <WindowsStylesConstants.au3>

    Example()

    Func Example()
        Local $hGUI, $hImage, $hCombo

        ; Create GUI
        $hGUI = GUICreate("ComboBoxEx Replace Edit Sel", 400, 300)
        $hCombo = _GUICtrlComboBoxEx_Create($hGUI, "", 2, 2, 394, 100, BitOR($CBS_SIMPLE, $WS_VSCROLL, $WS_BORDER))
        GUISetState(@SW_SHOW)

        $hImage = _GUIImageList_Create(16, 16, 5, 3)
        _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 110)
        _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 131)
        _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 165)
        _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 168)
        _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 137)
        _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 146)
        _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0xFF0000, 16, 16))
        _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x00FF00, 16, 16))
        _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x0000FF, 16, 16))
        _GUICtrlComboBoxEx_SetImageList($hCombo, $hImage)

        _GUICtrlComboBoxEx_InitStorage($hCombo, 150, 300)

        _GUICtrlComboBoxEx_BeginUpdate($hCombo)
        For $x = 0 To 149
            _GUICtrlComboBoxEx_AddString($hCombo, StringFormat("%03d : Random string", Random(1, 100, 1)), Random(0, 8, 1), Random(0, 8, 1), Random(0, 8, 1))
        Next
        _GUICtrlComboBoxEx_EndUpdate($hCombo)

        ; Set Cur Sel
        _GUICtrlComboBoxEx_SetCurSel($hCombo, Random(0, 149, 1))

        ;Set Edit Sel
        _GUICtrlComboBoxEx_SetEditSel($hCombo, 0, 4)

        Sleep(500)

        ; Replace Edit Sel
        _GUICtrlComboBoxEx_ReplaceEditSel($hCombo, "Replaced")

        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
    EndFunc   ;==>Example