# Function Reference

# _GUICtrlRichEdit_GetParaSpacing

Gets the spacing settings of (first) selected paragraph or (if no selection) of the current paragraph

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetParaSpacing ( $hWnd )

## Parameters

$hWnd | Handle to the control

## Return Value

Success: | a string consisting of the settings separated by semicolons (;): value 1 - inter-line spacing: either a number - in space units or " lines" - in lines value 2 - scope of value 1: a - all (or only) selected paragraph(s) have the above setting f - the first selected paragraph has this setting, but other(s) don't c - the current paragraph has this setting value 3 - spacing before paragraphs (in space units) value 4 - scope of value 3 - see above value 5 - spacing after paragraphs (in space units) value 6 - scope of value 5 - see above
Failure: | Empty string and sets the @error flag to non-zero.
@error: | 101 - $hWnd is not a handle

## Related

_GUICtrlRichEdit_SetParaSpacing

## See Also

Search EM_SETPARAFORMAT in MSDN Library.

## Example

    #include <GUIConstantsEx.au3>
    #include <GuiRichEdit.au3>
    #include <WindowsStylesConstants.au3>

    Global $g_idLbl_Msg, $g_hRichEdit

    Example()

    Func Example()
        Local $hGui, $iMsg, $idBtn_Next, $iStep = 0
        $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, StringLen(".exe")) & ")", 320, 350, -1, -1)
        $g_hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
                BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
        $g_idLbl_Msg = GUICtrlCreateLabel("", 10, 235, 300, 60)
        $idBtn_Next = GUICtrlCreateButton("Next", 270, 310, 40, 30)
        GUISetState(@SW_SHOW)

        _GUICtrlRichEdit_SetText($g_hRichEdit, "First paragraph")
        Report("0. Para with default settings")

        While True
            $iMsg = GUIGetMsg()
            Select
                Case $iMsg = $GUI_EVENT_CLOSE
                    _GUICtrlRichEdit_Destroy($g_hRichEdit) ; needed unless script crashes
                    ; GUIDelete()   ; is OK too
                    Exit
                Case $iMsg = $idBtn_Next
                    $iStep += 1
                    Switch $iStep
                        Case 1
                            _GUICtrlRichEdit_AppendText($g_hRichEdit, @CRLF & "Second paragraph")
                            _GUICtrlRichEdit_SetParaSpacing($g_hRichEdit, "2 lines", .2, .25)
                            Report("1. Spacing of second paragraph is ")
                        Case 2
                            _GUICtrlRichEdit_SetSel($g_hRichEdit, 0, 2)
                            Report("2. Settings of first paragraph in the selection are ")
                        Case 3
                            _GUICtrlRichEdit_SetSel($g_hRichEdit, 10, 26)
                            _GUICtrlRichEdit_SetParaSpacing($g_hRichEdit, Default, .1)
                            Report("3. Change spacing of both paragraphs")
                        Case 4
                            ; Stream all text to the Desktop so you can look at Indents settings in Word
                            _GUICtrlRichEdit_Deselect($g_hRichEdit)
                            _GUICtrlRichEdit_StreamToFile($g_hRichEdit, @DesktopDir & "\gcre.rtf")
                            GUICtrlSetState($idBtn_Next, $GUI_DISABLE)
                    EndSwitch
            EndSelect
        WEnd
    EndFunc   ;==>Example

    Func Report($sMsg)
        $sMsg = $sMsg & @CRLF & @CRLF & "Get function returns " & @CRLF & _GUICtrlRichEdit_GetParaSpacing($g_hRichEdit)
        GUICtrlSetData($g_idLbl_Msg, $sMsg)
    EndFunc   ;==>Report