# Function Reference

# _GUICtrlTreeView_SetSelectedImageIndex

Sets the selected image index

#include <GuiTreeView.au3>
_GUICtrlTreeView_SetSelectedImageIndex ( $hWnd, $hItem, $iIndex )

## Parameters

$hWnd | Control ID/Handle to the control
$hItem | Handle to the item
$iIndex | Image list index

## Return Value

Success: | True.
Failure: | False.

## Related

_GUICtrlTreeView_GetSelectedImageIndex

## Example

    #include <GUIConstantsEx.au3>
    #include <GuiImageList.au3>
    #include <GuiTreeView.au3>
    #include <MsgBoxConstants.au3>
    #include <WindowsStylesConstants.au3>

    Example()

    Func Example()
        GUICreate("TreeView Get/Set Selected Image Index (v" & @AutoItVersion & ")", 440, 300)

        Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)
        Local $idTreeView = GUICtrlCreateTreeView(2, 2, 436, 268, $iStyle, $WS_EX_CLIENTEDGE)
        GUISetState(@SW_SHOW)

        Local $hImage = _GUIImageList_Create(16, 16, 5, 3)
        _GUIImageList_AddIcon($hImage, "shell32.dll", 110)
        _GUIImageList_AddIcon($hImage, "shell32.dll", 131)
        _GUIImageList_AddIcon($hImage, "shell32.dll", 165)
        _GUIImageList_AddIcon($hImage, "shell32.dll", 168)
        _GUIImageList_AddIcon($hImage, "shell32.dll", 137)
        _GUIImageList_AddIcon($hImage, "shell32.dll", 146)
        _GUICtrlTreeView_SetNormalImageList($idTreeView, $hImage)

        _GUICtrlTreeView_BeginUpdate($idTreeView)
        Local $ahItem[10], $iImage, $iSImage
        For $x = 0 To 5
            $ahItem[$x] = _GUICtrlTreeView_Add($idTreeView, 0, StringFormat("[%02d] New Item", $x), $x, $x)
            For $y = 1 To Random(2, 10, 1)
                $iImage = Random(0, 5, 1)
                $iSImage = Random(0, 5, 1)
                _GUICtrlTreeView_AddChild($idTreeView, $ahItem[$x], StringFormat("[%02d] New Child", $y), $iImage, $iSImage)
            Next
        Next
        _GUICtrlTreeView_EndUpdate($idTreeView)

        _GUICtrlTreeView_SelectItem($idTreeView, $ahItem[2])
        MsgBox($MB_SYSTEMMODAL, "Information", StringFormat("Selected Image Index for Item Index 2? %d", _GUICtrlTreeView_GetSelectedImageIndex($idTreeView, $ahItem[2])))
        _GUICtrlTreeView_SetSelectedImageIndex($idTreeView, $ahItem[2], 1)
        MsgBox($MB_SYSTEMMODAL, "Information", StringFormat("Selected Image Index for Item Index 2? %d", _GUICtrlTreeView_GetSelectedImageIndex($idTreeView, $ahItem[2])))
        _GUICtrlTreeView_SelectItem($idTreeView, $ahItem[2])

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
        GUIDelete()
    EndFunc   ;==>Example