# Function Reference

# _GUICtrlComboBoxEx_GetComboBoxInfo

Gets information about the specified ComboBox

#include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_GetComboBoxInfo ( $hWnd, ByRef $tInfo )

## Parameters

$hWnd | Handle to the control
$tInfo | The information about the ComboBox.

## Return Value

Success: | True.
Failure: | False.

## Example

    #include <DirConstants.au3>
    #include <GuiComboBoxEx.au3>
    #include <GUIConstantsEx.au3>
    #include <MsgBoxConstants.au3>

    Example()

    Func Example()
        Local $hGUI, $tInfo, $hCombo

        ; Create GUI
        $hGUI = GUICreate("ComboBoxEx Get ComboBox Info", 400, 300)
        $hCombo = _GUICtrlComboBoxEx_Create($hGUI, "", 2, 2, 394, 100)
        GUISetState(@SW_SHOW)

        ; Add files
        _GUICtrlComboBoxEx_AddDir($hCombo, "", $DDL_DRIVES, False)
        _GUICtrlComboBoxEx_AddDir($hCombo, "", $DDL_DRIVES)
        _GUICtrlComboBoxEx_BeginUpdate($hCombo)
        _GUICtrlComboBoxEx_AddDir($hCombo, @WindowsDir & "\*.exe")
        _GUICtrlComboBoxEx_EndUpdate($hCombo)

        If _GUICtrlComboBoxEx_GetComboBoxInfo($hCombo, $tInfo) Then _
                MsgBox($MB_SYSTEMMODAL, "Information", StringFormat("Edit Rect [%d][%d][%d][%d]", _
                DllStructGetData($tInfo, "EditLeft"), DllStructGetData($tInfo, "EditTop"), _
                DllStructGetData($tInfo, "EditRight"), DllStructGetData($tInfo, "EditBottom")))

        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
    EndFunc   ;==>Example