# Function Reference

# InetClose

Closes a handle returned from InetGet().

InetClose ( handle )

## Parameters

handle | A handle return from InetGet().

## Return Value

True: | if the handle was found and closed.
False: | if not.

## Remarks

InetGet() handles must be closed or resources will leak.
Closing the handle to a download still in progress will cancel the download.

## Related

InetGet

## Example

    #include <InetConstants.au3>
    #include <MsgBoxConstants.au3>
    #include <WinAPIFiles.au3>

    Example()

    Func Example()
        ; Save the downloaded file to the temporary folder.
        Local $sFilePath = _WinAPI_GetTempFileName(@TempDir)

        ; Download the file in the background with the selected option of 'force a reload from the remote site.'
        Local $hDownload = InetGet("http://www.autoitscript.com/autoit3/files/beta/update.dat", $sFilePath, $INET_FORCERELOAD, $INET_DOWNLOADBACKGROUND)

        ; Wait for the download to complete by monitoring when the 2nd index value of InetGetInfo returns True.
        Do
            Sleep(250)
        Until InetGetInfo($hDownload, $INET_DOWNLOADCOMPLETE)

        ; Retrieve the number of total bytes received and the filesize.
        Local $iBytesSize = InetGetInfo($hDownload, $INET_DOWNLOADREAD)
        Local $iFileSize = FileGetSize($sFilePath)

        ; Close the handle returned by InetGet.
        InetClose($hDownload)

        ; Display details about the total number of bytes read and the filesize.
        MsgBox($MB_SYSTEMMODAL, "", "The total download size: " & $iBytesSize & @CRLF & _
                "The total filesize: " & $iFileSize)

        ; Delete the file.
        FileDelete($sFilePath)
    EndFunc   ;==>Example