# Function Reference

# _GUICtrlTreeView_GetItemParam

Retrieves the application specific value of the item

#include <GuiTreeView.au3>
_GUICtrlTreeView_GetItemParam ( $hWnd [, $hItem = Null] )

## Parameters

$hWnd | Control ID/Handle to the control
$hItem | [optional] Item ID

## Return Value

Success: | the item param.
Failure: | 0

## Related

_GUICtrlTreeView_SetItemParam

## Example

### Example 1

    #include <GUIConstantsEx.au3>
    #include <GuiTreeView.au3>
    #include <MsgBoxConstants.au3>
    #include <WindowsStylesConstants.au3>

    Example()

    Func Example()
        Local $hGUI = GUICreate("TreeView Get/Set Item Param (v" & @AutoItVersion & ")", 400, 300)

        Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)
        Local $hTreeView = _GUICtrlTreeView_Create($hGUI, 2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
        GUISetState(@SW_SHOW)

        ; Set ANSI format
    ;~     _GUICtrlTreeView_SetUnicodeFormat($hTreeView, False)

        _GUICtrlTreeView_BeginUpdate($hTreeView)
        Local $ahItem[10], $ahItemChild[30], $iYIndex = 0, $iParam = 1
        For $x = 0 To 9
            $ahItem[$x] = _GUICtrlTreeView_Add($hTreeView, 0, StringFormat("[%02d] New Item", $x))
            _GUICtrlTreeView_SetItemParam($hTreeView, $ahItem[$x], $iParam)
            $iParam += 1
            For $y = $iYIndex To $iYIndex + 2
                $ahItemChild[$y] = _GUICtrlTreeView_AddChild($hTreeView, $ahItem[$x], StringFormat("[%02d] New Item", $y))
                _GUICtrlTreeView_SetItemParam($hTreeView, $ahItemChild[$y], $iParam)
                $iParam += 1
            Next
            $iYIndex += 3
        Next
        _GUICtrlTreeView_EndUpdate($hTreeView)

        Local $iRand = 2 ;Random(0, 9, 1)
        MsgBox($MB_SYSTEMMODAL, "Information", StringFormat("Item Param for index %d: %s", $iRand, _GUICtrlTreeView_GetItemParam($hTreeView, $ahItem[$iRand])))
        $iRand = 12 ;Random(0, 29, 1)
        MsgBox($MB_SYSTEMMODAL, "Information", StringFormat("Item Param for child index %d: %s", $iRand, _GUICtrlTreeView_GetItemParam($hTreeView, $ahItemChild[$iRand])))
        _GUICtrlTreeView_SelectItem($hTreeView, $ahItemChild[$iRand])

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
        GUIDelete()
    EndFunc   ;==>Example

### Example 2

    #include <GUIConstantsEx.au3>
    #include <GuiTreeView.au3>
    #include <MsgBoxConstants.au3>
    #include <WindowsStylesConstants.au3>

    Example_External()

    Func Example_External()
        Local $hGUI = GUICreate("(UDF Created) TreeView Get Item Param (v" & @AutoItVersion & ")", 400, 300)

        Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)
        Local $hTreeView = _GUICtrlTreeView_Create($hGUI, 2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
        GUISetState(@SW_SHOW)

        ; Set ANSI format
    ;~     _GUICtrlTreeView_SetUnicodeFormat($hTreeView, False)

        _GUICtrlTreeView_BeginUpdate($hTreeView)
        Local $ahItem[10], $ahItemChild[30], $iYIndex = 0, $iRand, $iParam = 1
        For $x = 0 To 9
            $ahItem[$x] = _GUICtrlTreeView_Add($hTreeView, 0, StringFormat("[%02d] New Item", $x))
            _GUICtrlTreeView_SetItemParam($hTreeView, $ahItem[$x], $iParam)
            $iParam += 1
            For $y = $iYIndex To $iYIndex + 2
                $ahItemChild[$y] = _GUICtrlTreeView_AddChild($hTreeView, $ahItem[$x], StringFormat("[%02d] New Item", $iParam))
                _GUICtrlTreeView_SetItemParam($hTreeView, $ahItemChild[$y], $iParam)
                $iParam += 1
            Next
            $iYIndex += 3
        Next
        _GUICtrlTreeView_EndUpdate($hTreeView)

        $iRand = 2 ;Random(0, 9, 1)
        MsgBox($MB_SYSTEMMODAL, "Information", StringFormat("Item Param/ID for index %d: %s\r\nIsPtr = %d IsHWnd = %d", $iRand, _GUICtrlTreeView_GetItemParam($hTreeView, $ahItem[$iRand]), _
                IsPtr(_GUICtrlTreeView_GetItemHandle($hTreeView, $ahItem[$iRand])), IsHWnd(_GUICtrlTreeView_GetItemHandle($hTreeView, $ahItem[$iRand]))))
        $iRand = 28 ;Random(0, 29, 1)
        MsgBox($MB_SYSTEMMODAL, "Information", StringFormat("Item Param for child index %d: %s", $iRand, _GUICtrlTreeView_GetItemParam($hTreeView, $ahItemChild[$iRand])))

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
        GUIDelete()
    EndFunc   ;==>Example_External