# Function Reference

# _IEPropertyGet

Returns a select property of the Browser or DOM element

#include <IE.au3>
_IEPropertyGet ( ByRef $oObject, $sProperty )

## Parameters

$oObject | Object variable of an InternetExplorer.Application or DOM element
$sProperty | Property selection (see remarks)

## Return Value

Success: | the selected property.
Failure: | 0 and sets the @error flag to non-zero.
@error: | 3 ($_IEStatus_InvalidDataType) - Invalid Data Type 4 ($_IEStatus_InvalidObjectType) - Invalid Object Type 5 ($_IEStatus_InvalidValue) - Invalid Value
@extended: | Contains invalid parameter number

## Remarks

The following tables provide a description of each property available for use.
Some properties to DOM elements, others to the browser.
Browser Properties

Property | Description
"addressbar" | Retrieves a Boolean value indicating whether the browser address bar is visible or hidden.
"browserx" | Retrieves the x-coordinate of the top left corner of a document element, relative to the browser.
"browsery" | Retrieves the y-coordinate of the top left corner of a document element, relative to the browser.
"busy" | Retrieves a Boolean value indicating whether the object is engaged in a navigation or downloading operation.
"contenteditable" | Retrieves a Boolean value that indicates whether the object can be edited with mouse and keyboard.
"fullscreen" | Retrieves a Boolean value that indicates whether the browser is in full-screen or normal window mode.
"height" | Retrieves the height of the browser main window or a document element.
"hwnd" | Retrieves the handle of the Internet Explorer main window. Can be used in most AutoIt Win* functions.
"innerhtml" | Retrieves the rendered HTML of an element excluding the beginning and ending element tags.
"innertext" | Retrieves the rendered Text (but not any tags) of an element. Typically identical to outertext.
"isdisabled" | Retrieves the value indicating whether the user can interact with the object.
"left" | Retrieves the screen coordinate of the left edge of the main window of the object.
"locationname" | Retrieves the name of the resource that Internet Explorer is currently displaying.
"locationurl" | Retrieves the URL of the resource that Internet Explorer is currently displaying.
"menubar" | Retrieves a Boolean value that indicates whether the browser menu bar is visible.
"offline" | Retrieves a Boolean value that indicates whether the browser is currently operating in offline mode.
"outertext" | Retrieves the rendered Text (but not any tags) of an element. Typically identical to innertext.
"outerhtml" | Retrieves the rendered HTML of an element including the beginning and ending element tags.
"readystate" | Retrieves the ready state of the object.
"referrer" | Retrieves a string of the URL of the page from which the current page was accessed (but only if accessed via a link on that page, else the string is null).
"resizable" | Retrieves a value that indicates whether the object can be resized.
"screenx" | Retrieves the x-coordinate of the top left corner of a document object or the browser, relative to the screen.
"screeny" | Retrieves the y-coordinate of the top left corner of a document object or the browser, relative to the screen.
"silent" | Retrieves a value that indicates whether the browser can show dialog boxes.
"statusbar" | Retrieves a value that indicates whether the status bar for the object is visible.
"statustext" | Retrieves the text in the status bar for the object.
"theatermode" | Retrieves a Boolean value indicating whether the browser is in Theater Mode. In theater mode, the browser main window fills the entire screen and displays a toolbar with a minimal set of navigational buttons.
"title" | Retrieves the document title. Note that this is different than the window title which typically starts with the document title, but has additional text specified in the windows registry appended to it.
"toolbar" | Retrieves a Boolean value indicating whether the tool bar of the browser is visible or hidden.
"top" | Retrieves the screen coordinate of the top edge of the main window of the object.
"visible" | Retrieves a value that indicates whether the object is visible or hidden.
"width" | Retrieves the width of the browser main window or a document element.
"uniqueid" | Retrieves an ID assigned by the DOM that is unique among all elements. This can be used in any context that requires an element ID.

Further information for ClientInfo Object can be found at MSDN.
ClientInfo Properties

Property | Description
"appcodename" | Retrieves the code name of the browser (the property has a default value of Mozilla).
"appminorversion" | Retrieves the application's minor version value.
"appname" | Retrieves the name of the browser (the property has a default value of Microsoft Internet Explorer).
"appversion" | Retrieves the platform and version of the browser.
"browserlanguage" | Retrieves the current browser language (the value will be one of these Language Codes).
"cookieenabled" | Retrieves whether client-side persistent cookies are enabled in the browser. Persistent cookies are those that are stored on the client-side computer.
"cpuclass" | Retrieves a string denoting the CPU class (the return values can be found here).
"javaenabled" | Returns whether Java is enabled.
"online" | Retrieves a value indicating whether the system is in global offline mode.
"platform" | Retrieves the name of the user's operating system (the return values can be found here).
"systemlanguage" | Retrieves the default language used by the operating system (the value will be one of these Language Codes).
"useragent" | Retrieves a string equivalent to the HTTP user-agent request header.
"userlanguage" | Retrieves the operating system's natural language setting (the value will be one of these Language Codes).

## Related

_IEBodyReadHTML, _IEBodyReadText, _IEBodyWriteHTML, _IEDocInsertHTML, _IEDocInsertText, _IEHeadInsertEventScript, _IEPropertySet

## Example

### Example 1

    ; Open a browser with the basic example, check to see if the
    ; addressbar is visible, if it is turn it off, if it is not turn it on

    #include <IE.au3>
    #include <MsgBoxConstants.au3>

    Local $oIE = _IE_Example("basic")
    If _IEPropertyGet($oIE, "addressbar") Then
        MsgBox($MB_SYSTEMMODAL, "AddressBar Status", "AddressBar Visible, turning it off")
        _IEPropertySet($oIE, "addressbar", False)
    Else
        MsgBox($MB_SYSTEMMODAL, "AddressBar Status", "AddressBar Invisible, turning it on")
        _IEPropertySet($oIE, "addressbar", True)
    EndIf

### Example 2

    ; Open a browser with the form example and get a reference to the form
    ; textarea element.  Get the coordinates and dimensions of the text area,
    ; outline its shape with the mouse and come to rest in the center

    #include <IE.au3>

    Local $oIE = _IE_Example("form")

    Local $oForm = _IEFormGetObjByName($oIE, "ExampleForm")
    Local $oTextArea = _IEFormElementGetObjByName($oForm, "textareaExample")

    ; Get coordinates and dimensions of the textarea
    Local $iScreenX = _IEPropertyGet($oTextArea, "screenx")
    Local $iScreenY = _IEPropertyGet($oTextArea, "screeny")
    Local $iWidth = _IEPropertyGet($oTextArea, "width")
    Local $iHeight = _IEPropertyGet($oTextArea, "height")

    ; Outline the textarea with the mouse, come to rest in the center
    Local $iMousespeed = 50
    MouseMove($iScreenX, $iScreenY, $iMousespeed)
    MouseMove($iScreenX + $iWidth, $iScreenY, $iMousespeed)
    MouseMove($iScreenX + $iWidth, $iScreenY + $iHeight, $iMousespeed)
    MouseMove($iScreenX, $iScreenY + $iHeight, $iMousespeed)
    MouseMove($iScreenX, $iScreenY, $iMousespeed)
    MouseMove($iScreenX + $iWidth / 2, $iScreenY + $iHeight / 2, $iMousespeed)