# Function Reference

# _GUICtrlRichEdit_GetFirstCharPosOnLine

Retrieves the inter-character position preceding the first character of a line

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetFirstCharPosOnLine ( $hWnd [, $iLine = -1] )

## Parameters

$hWnd | Handle to the control
$iLine | [optional] Line number Default: current line

## Return Value

Success: | the character position of the first character of the line.
Failure: | 0 and sets the @error flag to non-zero.
@error: | 101 - $hWnd is not a handle 1021 - $iLine is neither positive nor -1 1022 - $iLine greater than number of lines of text

## Remarks

A control that contains no text has one line.
The first line is line 1. The first character position in the client area is 0.

## See Also

Search EM_GETLINEINDEX in MSDN Library.

## Example

    #include <GUIConstantsEx.au3>
    #include <GuiRichEdit.au3>
    #include <WindowsStylesConstants.au3>

    Global $g_idLbl_Msg
    Example()

    Func Example()
        Local $hGui, $hRichEdit, $iLastLineNumber, $iCharPosition, $iMsg
        $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, StringLen(".exe")) & ")", 520, 350, -1, -1)
        $hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 500, 220, _
                BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
        $g_idLbl_Msg = GUICtrlCreateLabel("", 10, 235, 300, 60)
        GUISetState(@SW_SHOW)

        _GUICtrlRichEdit_AutoDetectURL($hRichEdit, True)
        _GUICtrlRichEdit_AppendText($hRichEdit, @CRLF & "http://www.autoitscript.com")

        $iLastLineNumber = _GUICtrlRichEdit_GetLineCount($hRichEdit)

        ; get first char position of last line
        $iCharPosition = _GUICtrlRichEdit_GetFirstCharPosOnLine($hRichEdit, $iLastLineNumber)

        ; select 4 chars - should be "http" word
        _GUICtrlRichEdit_SetSel($hRichEdit, $iCharPosition, $iCharPosition + 4)
        Report("Character attributes at start of line " & $iLastLineNumber & " are " & _
                _GUICtrlRichEdit_GetCharAttributes($hRichEdit))

        While True
            $iMsg = GUIGetMsg()
            Select
                Case $iMsg = $GUI_EVENT_CLOSE
                    _GUICtrlRichEdit_Destroy($hRichEdit) ; needed unless script crashes
                    ; GUIDelete()   ; is OK too
                    Exit
            EndSelect
        WEnd
    EndFunc   ;==>Example

    Func Report($sMsg)
        GUICtrlSetData($g_idLbl_Msg, $sMsg)
    EndFunc   ;==>Report