# Function Reference

# _GUICtrlToolbar_SetRows

Sets the number of rows of buttons

#include <GuiToolbar.au3>
_GUICtrlToolbar_SetRows ( $hWnd, $iRows [, $bLarger = True] )

## Parameters

$hWnd | Handle to the control
$iRows | Number of rows requested. The minimum number of rows is one, and the maximum number of rows is equal to the total number of buttons.
$bLarger | [optional] Flag that indicates whether to create more rows than requested when the system can not create the number of rows specified by $iRows. If this parameter is True, the system creates more rows. If it is False, the system creates fewer rows.

## Return Value

Returns an array with the following format:
[0] - X coordinate of the upper left corner of the rectangle
[1] - Y coordinate of the upper left corner of the rectangle
[2] - X coordinate of the lower right corner of the rectangle
[3] - Y coordinate of the lower right corner of the rectangle

## Remarks

Because the system does not break up button groups when setting the number of rows, the resulting number of rows might differ from the number requested.

## Related

_GUICtrlToolbar_GetRows

## Example

    #include "Extras\HelpFileInternals.au3"

    #include <AutoItConstants.au3>
    #include <GUIConstantsEx.au3>
    #include <GuiToolbar.au3>
    #include <WinAPIConstants.au3>
    #include <WindowsStylesConstants.au3>

    Example()

    Func Example()
        Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $e_idHelp

        ; Create GUI
        Local $hGUI = GUICreate("Toolbar Get/Set Rows (v" & @AutoItVersion & ")", 400, 300)
        Local $hToolbar = _GUICtrlToolbar_Create($hGUI)
        _MemoCreate(36, 2, 396, 262, $WS_VSCROLL)
        GUISetState(@SW_SHOW)

        ; Set ANSI format
    ;~     _GUICtrlToolbar_SetUnicodeFormat($hToolbar, False)

        ; Add standard system bitmaps
        Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
            Case 0
                _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
            Case 2
                _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
        EndSwitch

        ; Add buttons
        _GUICtrlToolbar_AddButton($hToolbar, $e_idNew, $STD_FILENEW)
        _GUICtrlToolbar_AddButton($hToolbar, $e_idOpen, $STD_FILEOPEN)
        _GUICtrlToolbar_AddButton($hToolbar, $e_idSave, $STD_FILESAVE)
        _GUICtrlToolbar_AddButtonSep($hToolbar)
        _GUICtrlToolbar_AddButton($hToolbar, $e_idHelp, $STD_HELP)

        ; Create a vertical toolbar
        _GUICtrlToolbar_SetStyle($hToolbar, BitOR($CCS_LEFT, $TBSTYLE_FLAT))
        _GUICtrlToolbar_SetRows($hToolbar, 4)

        ; Show number of rows
        _MemoWrite("Number of rows:" & _GUICtrlToolbar_GetRows($hToolbar))

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
    EndFunc   ;==>Example