# Function Reference

# _GUICtrlRichEdit_SetReadOnly

Sets or removes the read-only state

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetReadOnly ( $hWnd [, $bState = True] )

## Parameters

$hWnd | Handle to the control
$bState | [optional] one of the following values: True - Sets control to read-only (default) False - Sets control to read-write

## Return Value

Success: | True.
Failure: | False and sets the @error flag to non-zero.
@error: | 101 - $hWnd is not a handle 102 - $bState is neither true nor false 700 - operation failed

## See Also

Search EM_SETREADONLY in MSDN Library.

## Example

    #include <GUIConstantsEx.au3>
    #include <GuiRichEdit.au3>
    #include <WindowsStylesConstants.au3>

    Global $g_idLbl_Msg

    Example()

    Func Example()
        Local $hGui, $iMsg, $idBtn_Next, $hRichEdit, $iStep = 0
        $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, StringLen(".exe")) & ")", 320, 350, -1, -1)
        $hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
                BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
        $g_idLbl_Msg = GUICtrlCreateLabel("", 10, 235, 300, 60)
        $idBtn_Next = GUICtrlCreateButton("Next", 270, 310, 40, 30)
        GUISetState(@SW_SHOW)

        For $i = 1 To 5
            _GUICtrlRichEdit_AppendText($hRichEdit, "Line " & $i & @CRLF)
        Next
        _GUICtrlRichEdit_AppendText($hRichEdit, "Line 6")
        Report("Initial state")

        While True
            $iMsg = GUIGetMsg()
            Select
                Case $iMsg = $GUI_EVENT_CLOSE
                    _GUICtrlRichEdit_Destroy($hRichEdit) ; needed unless script crashes
                    ; GUIDelete()   ; is OK too
                    Exit
                Case $iMsg = $idBtn_Next
                    $iStep += 1
                    Switch $iStep
                        Case 1
                            _GUICtrlRichEdit_SetReadOnly($hRichEdit)
                            Report("Set to read-only")
                        Case 2
                            _GUICtrlRichEdit_SetReadOnly($hRichEdit, False)
                            Report("Now read-write")
                            GUICtrlSetState($idBtn_Next, $GUI_DISABLE)
                    EndSwitch
            EndSelect
        WEnd
    EndFunc   ;==>Example

    Func Report($sMsg)
        GUICtrlSetData($g_idLbl_Msg, $sMsg & @CRLF & "Try typing some text")
    EndFunc   ;==>Report