# Function Reference

# _GUICtrlTreeView_SetIcon

Set an item icon

#include <GuiTreeView.au3>
_GUICtrlTreeView_SetIcon ( $hWnd [, $hItem = Null [, $sIconFile = "" [, $iIconID = 0 [, $iImageMode = 6]]]] )

## Parameters

$hWnd | Control ID/Handle to the control
$hItem | [optional] item ID/handle
$sIconFile | [optional] The file to extract the icon of
$iIconID | [optional] The iconID to extract of the file
$iImageMode | [optional] 2=normal image / 4=selected image to set

## Return Value

Success: | True.
Failure: | False.

## Example

    #include <GUIConstantsEx.au3>
    #include <GuiTreeView.au3>
    #include <WindowsStylesConstants.au3>

    Example()

    Func Example()
        GUICreate("TreeView Set Icon (v" & @AutoItVersion & ")", 400, 300)

        Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS)
        Local $idTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
        GUISetState(@SW_SHOW)

        _GUICtrlTreeView_BeginUpdate($idTreeView)
        Local $aidTVi_Item[10]
        For $x = 0 To 9
            $aidTVi_Item[$x] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Item", $x), $idTreeView)
            _GUICtrlTreeView_SetIcon($idTreeView, $aidTVi_Item[$x], "shell32.dll", 137)
            For $y = 1 To 3
                GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Child", $y), $aidTVi_Item[$x])
            Next
        Next
        _GUICtrlTreeView_EndUpdate($idTreeView)

        _GUICtrlTreeView_SetIcon($idTreeView, $aidTVi_Item[0], "shell32.dll", 131)

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
        GUIDelete()
    EndFunc   ;==>Example