# Function Reference

# _GUICtrlRichEdit_ScrollLineOrPage

Scrolls the text down or up a line or a page

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_ScrollLineOrPage ( $hWnd, $sAction )

## Parameters

$hWnd | Handle to the control
$sAction | one of the following: "ld" - line down "lu" - line up "pd" - page down "pu" - page up

## Return Value

Success: | the number of lines actually scrolled (positive if down).
Failure: | 0 and sets the @error flag to non-zero.
@error: | 101 - $hWnd is not a handle 1021 - $sAction is not two characters 1022 - first character must be l or p 1023 - second character must be d or u

## Remarks

This function is well behaved: it never scrolls such that lines beyond the last one are shown.

## Related

_GUICtrlRichEdit_ScrollLines, _GUICtrlRichEdit_ScrollToCaret

## See Also

Search EM_SCROLL in MSDN Library.

## Example

    #include <GUIConstantsEx.au3>
    #include <GuiRichEdit.au3>
    #include <WindowsStylesConstants.au3>

    Global $g_idLbl_Msg, $g_hRichEdit

    Example()

    Func Example()
        Local $hGui, $iMsg, $idBtn_Next, $iStep = 0
        $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, StringLen(".exe")) & ")", 320, 350, -1, -1)
        $g_hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
                BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
        $g_idLbl_Msg = GUICtrlCreateLabel("", 10, 235, 300, 60)
        $idBtn_Next = GUICtrlCreateButton("Next", 270, 310, 40, 30)
        GUISetState(@SW_SHOW)

        For $i = 1 To 20
            _GUICtrlRichEdit_AppendText($g_hRichEdit, "Line " & $i & @CRLF)
        Next
        _GUICtrlRichEdit_AppendText($g_hRichEdit, "Line 21")

        While True
            $iMsg = GUIGetMsg()
            Select
                Case $iMsg = $GUI_EVENT_CLOSE
                    _GUICtrlRichEdit_Destroy($g_hRichEdit) ; needed unless script crashes
                    ; GUIDelete()   ; is OK too
                    Exit
                Case $iMsg = $idBtn_Next
                    $iStep += 1
                    Switch $iStep
                        Case 1
                            DoIt("lu", "Scrolled up a line")
                        Case 2
                            DoIt("pu", "Scrolled up a page")
                        Case 3
                            DoIt("pd", "Scrolled down a page")
                        Case 4
                            DoIt("pd", "Tried to scroll down another page")
                            GUICtrlSetState($idBtn_Next, $GUI_DISABLE)
                    EndSwitch
            EndSelect
        WEnd
    EndFunc   ;==>Example

    Func DoIt($sAction, $sMsg)
        Local $iQlines
        $iQlines = _GUICtrlRichEdit_ScrollLineOrPage($g_hRichEdit, $sAction)
        GUICtrlSetData($g_idLbl_Msg, $sMsg & @CRLF & @CRLF & "Actually scrolled " & @CRLF & $iQlines & " lines")
    EndFunc   ;==>DoIt