# Function Reference

# _GUICtrlRichEdit_SetRECT

Sets the formatting rectangle of a Rich Edit control

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetRECT ( $hWnd [, $iLeft = Default [, $iTop = Default [, $iRight = Default [, $iBottom = Default [, $bRedraw = True]]]]] )

## Parameters

$hWnd | Handle to the control
$iLeft | [optional] Left position in dialog units
$iTop | [optional] Top position in dialog units
$iRight | [optional] Right position in dialog units
$iBottom | [optional] Bottom position in dialog unit
$bRedraw | [optional] True to force redraw

## Return Value

Success: | True.
Failure: | False and sets the @error flag to non-zero.
@error: | 101 - $hWnd is not a handle 1021 - $iLeft is not a positive number 1022 - $iTop is not a positive number 1023 - $iRight is not a positive number 1024 - $iBottom is not a positive number 1025 - $iLeft >= $iRight 1026 - $iTop >= $iBottom

## Remarks

The formatting rectangle is the area in which text is drawn, part of which may not be visible.
Parameters default = no change to previous values.
If only $hWnd defined, formatting is reset as at creation time.

## Related

_GUICtrlRichEdit_GetRECT

## See Also

Search EM_SETMODIFY in MSDN Library.

## Example

    #include <GUIConstantsEx.au3>
    #include <GuiRichEdit.au3>
    #include <WindowsStylesConstants.au3>

    Global $g_idLbl_Msg, $g_hRichEdit

    Example()

    Func Example()
        Local $hGui, $iMsg, $idBtn_Next, $iStep = 0
        $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, StringLen(".exe")) & ")", 320, 350, -1, -1)
        $g_hRichEdit = _GUICtrlRichEdit_Create($hGui, "", 10, 10, 300, 220, _
                BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
        $g_idLbl_Msg = GUICtrlCreateLabel("", 10, 235, 300, 60)
        $idBtn_Next = GUICtrlCreateButton("Next", 270, 310, 40, 30)
        GUISetState(@SW_SHOW)

        _GUICtrlRichEdit_SetText($g_hRichEdit, "First paragraph")
        _GUICtrlRichEdit_AppendText($g_hRichEdit, @CRLF & "Second paragraph")

        While True
            $iMsg = GUIGetMsg()
            Select
                Case $iMsg = $GUI_EVENT_CLOSE
                    _GUICtrlRichEdit_Destroy($g_hRichEdit) ; needed unless script crashes
                    ; GUIDelete()   ; is OK too
                    Exit
                Case $iMsg = $idBtn_Next
                    $iStep += 1
                    Switch $iStep
                        Case 1
                            Report("1. Default settings ")
                        Case 2
                            _GUICtrlRichEdit_SetRECT($g_hRichEdit, 10, 10, 100, 100)
                            Report("2. Settings ")
                        Case 3
                            _GUICtrlRichEdit_SetRECT($g_hRichEdit)
                            Report("3. ReSettings to default")
                            GUICtrlSetState($idBtn_Next, $GUI_DISABLE)
                    EndSwitch
            EndSelect
        WEnd
    EndFunc   ;==>Example

    Func Report($sMsg)
        Local $aRect = _GUICtrlRichEdit_GetRECT($g_hRichEdit)
        $sMsg = $sMsg & @CRLF & @CRLF & "Left=" & $aRect[0] & " Top=" & $aRect[1] & " Right=" & $aRect[2] & " Bottom=" & $aRect[3]
        GUICtrlSetData($g_idLbl_Msg, $sMsg)
    EndFunc   ;==>Report