# Function Reference

# _GUICtrlTreeView_Sort

Sorts the items

#include <GuiTreeView.au3>
_GUICtrlTreeView_Sort ( $hWnd )

## Parameters

$hWnd | Control ID/Handle to the control

## Return Value

None.

## Example

### Example 1

    #include <GUIConstantsEx.au3>
    #include <GuiTreeView.au3>
    #include <MsgBoxConstants.au3>
    #include <WindowsStylesConstants.au3>

    Example()

    Func Example()
        GUICreate("TreeView Sort", 400, 300)

        Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS)
        Local $idTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
        GUISetState(@SW_SHOW)

        _GUICtrlTreeView_BeginUpdate($idTreeView)
        Local $aidTVi_Item[10], $iX = 9, $iY = 29
        For $x = 0 To 9
            $aidTVi_Item[$x] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Item", $iX), $idTreeView)
            $iX -= 1
            For $y = 1 To 3
                GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Child", $iY), $aidTVi_Item[$x])
                $iY -= 1
            Next
        Next
        _GUICtrlTreeView_Expand($idTreeView)
        _GUICtrlTreeView_EndUpdate($idTreeView)

        MsgBox($MB_SYSTEMMODAL, "Information", "Sort")
        _GUICtrlTreeView_Sort($idTreeView)
        _GUICtrlTreeView_SelectItem($idTreeView, $aidTVi_Item[9])

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
        GUIDelete()
    EndFunc   ;==>Example

### Example 2 for sorting with only level 1

    #include <GUIConstantsEx.au3>
    #include <GuiTreeView.au3>
    #include <MsgBoxConstants.au3>
    #include <WindowsStylesConstants.au3>

    Example()

    Func Example()
        GUICreate("TreeView Sort (v" & @AutoItVersion & ")", 400, 300)

        Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS)
        Local $idTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
        GUISetState(@SW_SHOW)

        _GUICtrlTreeView_BeginUpdate($idTreeView)
        Local $aidTVi_Item[10], $iX = 9
        For $x = 0 To 3
            $aidTVi_Item[$x] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Item", $iX), $idTreeView)
            $iX -= 1
        Next
        _GUICtrlTreeView_Expand($idTreeView)
        _GUICtrlTreeView_EndUpdate($idTreeView)

        MsgBox($MB_SYSTEMMODAL, "Information", "Sort")
        _GUICtrlTreeView_Sort($idTreeView)
        _GUICtrlTreeView_SelectItem($idTreeView, $aidTVi_Item[9])

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
        GUIDelete()
    EndFunc   ;==>Example