# Function Reference

# _GUICtrlListView_GetToolTips

Retrieves the ToolTip control handle

#include <GuiListView.au3>
_GUICtrlListView_GetToolTips ( $hWnd )

## Parameters

$hWnd | Control ID/Handle to the control

## Return Value

Returns the handle of the ToolTip control.

## Related

_GUICtrlListView_SetToolTips

## Example

    #include <GUIConstantsEx.au3>
    #include <GuiListView.au3>
    #include <MsgBoxConstants.au3>

    Example()

    Func Example()
        Local $hGui = GUICreate("ListView Get ToolTips", 400, 300)
        Local $hListView = _GUICtrlListView_Create($hGui, "", 2, 2, 394, 268)
        GUISetState(@SW_SHOW)

        ; Add columns
        _GUICtrlListView_AddColumn($hListView, "Items", 100)

        ; Add items
        _GUICtrlListView_AddItem($hListView, "Item 0")
        _GUICtrlListView_AddItem($hListView, "Item 1")
        _GUICtrlListView_AddItem($hListView, "Item 2")

        ; Show tooltip handle
        Local $hToolTip = _GUICtrlListView_GetToolTips($hListView)
        MsgBox($MB_SYSTEMMODAL, "Information", "ToolTip Handle: 0x" & Hex($hToolTip) & @CRLF & _
                "IsPtr = " & IsPtr($hToolTip) & " IsHWnd = " & IsHWnd($hToolTip))

        Local $hPrevTooltips = _GUICtrlListView_SetToolTips($hListView, $hToolTip)
        MsgBox($MB_SYSTEMMODAL, "Information", "Previous ToolTip Handle: 0x" & Hex($hPrevTooltips) & @CRLF & _
                "IsPtr = " & IsPtr($hPrevTooltips) & " IsHWnd = " & IsHWnd($hPrevTooltips))

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
        GUIDelete()
    EndFunc   ;==>Example