# Function Reference

# _GUIScrollBars_ShowScrollBar

Shows or hides the specified scroll bar

#include <GuiScrollBars.au3>
_GUIScrollBars_ShowScrollBar ( $hWnd, $iBar [, $bShow = True] )

## Parameters

$hWnd | Handle to the window
$iBar | Specifies the type of scroll bar. This parameter can be one of the following values: $SB_BOTH - Shows or hides a window's standard horizontal and vertical scroll bars. $SB_CTL - Shows or hides a scroll bar control. The $hWnd parameter must be the handle to the scroll bar control. $SB_HORZ - Shows or hides a window's standard horizontal scroll bars. $SB_VERT - Shows or hides a window's standard vertical scroll bar.
$bShow | [optional] Specifies whether the scroll bar is shown or hidden

## Return Value

Success: | True.
Failure: | False.

## Related

_GUIScrollBars_EnableScrollBar

## See Also

Search ShowScrollBar in MSDN Library.

## Example

    #include <GUIConstantsEx.au3>
    #include <GuiScrollBars.au3>
    #include <WindowsStylesConstants.au3>

    Example()

    Func Example()
        Local $hGUIMsg, $hGUI

        $hGUI = GUICreate("ScrollBar Example", 400, 400, -1, -1, BitOR($WS_MINIMIZEBOX, $WS_CAPTION, $WS_POPUP, $WS_SYSMENU, $WS_SIZEBOX))
        GUISetBkColor(0x88AABB)

        GUISetState(@SW_SHOW)

        _GUIScrollBars_Init($hGUI)

        _GUIScrollBars_ShowScrollBar($hGUI, $SB_HORZ, False)
        Sleep(1000)
        _GUIScrollBars_ShowScrollBar($hGUI, $SB_HORZ)

        Sleep(1000)
        _GUIScrollBars_ShowScrollBar($hGUI, $SB_VERT, False)
        Sleep(1000)
        _GUIScrollBars_ShowScrollBar($hGUI, $SB_VERT)

        While 1
            $hGUIMsg = GUIGetMsg()

            Switch $hGUIMsg
                Case $GUI_EVENT_CLOSE ;, $nExititem
                    ExitLoop
            EndSwitch
        WEnd

        Exit
    EndFunc   ;==>Example