# Function Reference

# _GUICtrlRichEdit_SetParaTabStops

Sets tab stops of paragraphs having selected text or, if none selected, sets it for text inserted at the insertion point

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetParaTabStops ( $hWnd, $sTabStops )

## Parameters

$hWnd | Handle to the control
$sTabStops | A string consisting of groups separated by ; (semicolon). Format of a group: absolute position of a tab stop (in space units) kind of tab l - left tab c - center tab r - decimal tab b - bar tab kind of dot leader . - dotted leader - - dashed leader _ - underline leader = - double line leader t - thick-line leader a space - no leader

## Return Value

Success: | True.
Failure: | False and sets the @error flag to non-zero.
@error: | 101 - $hWnd is not a handle 1021 - absolute position of a tab stop missing or invalid 1022 - kind of tab missing or invalid 1023 - kind of tab leader missing or invalid 1024 - attempt to set too many tab stops @extended contains the tab number (ref 1) in $sTabStops where the error occurred.

## Remarks

To reset the tab stops, do _GUICtrlRichEdit_SetParaTabStops($hWnd, "").
To set "space units", call _GUICtrlRichEdit_SetSpaceUnit(), initially inches.
To enter a tab into a control, press Ctrl_Tab.

## Related

_GUICtrlRichEdit_GetParaTabStops, _GUICtrlRichEdit_SetSpaceUnit, _GUICtrlRichEdit_SetTabStops

## See Also

Search EM_SETCHARFORMAT in MSDN Library.

## Example

    #include <GUIConstantsEx.au3>
    #include <GuiRichEdit.au3>
    #include <WindowsStylesConstants.au3>

    Global $g_idLbl_Msg, $g_hRichEdit

    Example()

    Func Example()
        Local $hGui, $iMsg, $idBtn_Next, $iStep = 0
        $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, StringLen(".exe")) & ")", 320, 350, -1, -1)
        $g_hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
                BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
        $g_idLbl_Msg = GUICtrlCreateLabel("", 10, 235, 300, 60)
        $idBtn_Next = GUICtrlCreateButton("Next", 270, 310, 40, 30)
        GUISetState(@SW_SHOW)

        _GUICtrlRichEdit_SetText($g_hRichEdit, "First paragraph")
        Report("0. Para with default settings")

        While True
            $iMsg = GUIGetMsg()
            Select
                Case $iMsg = $GUI_EVENT_CLOSE
                    _GUICtrlRichEdit_Destroy($g_hRichEdit) ; needed unless script crashes
                    ; GUIDelete()   ; is OK too
                    Exit
                Case $iMsg = $idBtn_Next
                    $iStep += 1
                    Switch $iStep
                        Case 1
                            _GUICtrlRichEdit_AppendText($g_hRichEdit, @CRLF & "Second paragraph")
                            _GUICtrlRichEdit_SetParaTabStops($g_hRichEdit, ".3l ;1c ;2.5r.")
                            Report("1. TabStops of second paragraph")
                        Case 2
                            _GUICtrlRichEdit_SetSel($g_hRichEdit, 0, 2)
                            Report("2. Tabstops of first paragraph")
                        Case 3
                            _GUICtrlRichEdit_SetSel($g_hRichEdit, 10, 26)
                            Report("Tabstops of first paragraph in selection")
                        Case 4
                            _GUICtrlRichEdit_SetParaTabStops($g_hRichEdit, "2.3r=")
                            Report("3. Change tabstops of both paragraphs")
                        Case 5
                            ; Stream all text to the Desktop so you can look at settings in Word
                            _GUICtrlRichEdit_Deselect($g_hRichEdit)
                            _GUICtrlRichEdit_StreamToFile($g_hRichEdit, @DesktopDir & "\gcre.rtf")
                            GUICtrlSetState($idBtn_Next, $GUI_DISABLE)
                    EndSwitch
            EndSelect
        WEnd
    EndFunc   ;==>Example

    Func Report($sMsg)
        $sMsg = $sMsg & @CRLF & @CRLF & "Get function returns " & @CRLF & _GUICtrlRichEdit_GetParaTabStops($g_hRichEdit)
        GUICtrlSetData($g_idLbl_Msg, $sMsg)
    EndFunc   ;==>Report