# Function Reference

# _GUICtrlRichEdit_GetCharColor

Retrieves the color of the selected text or, if none selected, of the character to the right of the insertion point

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetCharColor ( $hWnd )

## Parameters

$hWnd | Handle to the control

## Return Value

Success: | a COLORREF value an @extended set to 1 if the color is the same throught the selection.
Failure: | sets the @error flag to non-zero.
@error: | 101 - $hWnd is not a handle

## Remarks

If you need to create an color array use _ColorGetCOLORREF() not _ColorGetRGB().

## Related

_GUICtrlRichEdit_SetCharColor

## See Also

Search EM_GETCHARFORMAT in MSDN Library.

## Example

    #include <Color.au3>
    #include <GUIConstantsEx.au3>
    #include <GuiRichEdit.au3>
    #include <WindowsStylesConstants.au3>

    Global $g_idLbl_Msg, $g_hRichEdit

    Example()

    Func Example()
        Local $hGui = GUICreate("RichEdit Get/Set CharColor (v" & @AutoItVersion & ")", 320, 350, -1, -1)
        $g_hRichEdit = _GUICtrlRichEdit_Create($hGui, "", 10, 10, 300, 220, _
                BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
        $g_idLbl_Msg = GUICtrlCreateLabel("", 10, 235, 300, 60)
        Local $idBtn_Next = GUICtrlCreateButton("Next", 270, 310, 40, 30)
        GUISetState(@SW_SHOW)

        _GUICtrlRichEdit_SetText($g_hRichEdit, "Paragraph 1")
        Local $iMsg, $iStep = 0
        While True
            $iMsg = GUIGetMsg()
            Select
                Case $iMsg = $GUI_EVENT_CLOSE
                    _GUICtrlRichEdit_Destroy($g_hRichEdit) ; needed unless script crashes
                    ; GUIDelete()   ; is OK too
                    Exit
                Case $iMsg = $idBtn_Next
                    $iStep += 1
                    Switch $iStep
                        Case 1
                            Report("1. Initial setting")
                        Case 2
                            _GUICtrlRichEdit_SetCharColor($g_hRichEdit, "304050")
                            Report("2. Setting is now")
                        Case 3
                            _GUICtrlRichEdit_SetSel($g_hRichEdit, 1, 5)
                            _GUICtrlRichEdit_SetCharColor($g_hRichEdit, "sys")
                            Report("3. Background of a few characters changed")
                        Case 4
                            _GUICtrlRichEdit_Deselect($g_hRichEdit)
                            ; Stream all text to the Desktop so you can look at settings in Word
                            _GUICtrlRichEdit_StreamToFile($g_hRichEdit, @DesktopDir & "\gcre.rtf")
                            Report("4. Written to file")
                            GUICtrlSetState($idBtn_Next, $GUI_DISABLE)
                    EndSwitch
            EndSelect
        WEnd
    EndFunc   ;==>Example

    Func Report($sMsg)
        Local $iColor = _GUICtrlRichEdit_GetCharColor($g_hRichEdit)
        Local $aRet = _ColorGetRGB($iColor)
        $sMsg = $sMsg & @CRLF & @CRLF & $aRet[0] & ";" & $aRet[1] & ";" & $aRet[2] & " Color=0x" & Hex($iColor)
        GUICtrlSetData($g_idLbl_Msg, $sMsg)
    EndFunc   ;==>Report