# Function Reference

# _GUICtrlTreeView_SelectItemByIndex

Selects the item based on it's index in the parent list

#include <GuiTreeView.au3>
_GUICtrlTreeView_SelectItemByIndex ( $hWnd, $hItem, $iIndex )

## Parameters

$hWnd | Control ID/Handle to the control
$hItem | Handle to the item
$iIndex | 0-based index of item in the parent list

## Return Value

Success: | True.
Failure: | False.

## Example

    #include <GUIConstantsEx.au3>
    #include <GuiTreeView.au3>
    #include <WindowsStylesConstants.au3>

    Example()

    Func Example()
        GUICreate("TreeView Select Item By Index (v" & @AutoItVersion & ")", 400, 300)

        Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS)
        Local $idTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
        GUISetState(@SW_SHOW)

        _GUICtrlTreeView_BeginUpdate($idTreeView)
        Local $aidTVi_Item[10]
        For $x = 0 To 9
            $aidTVi_Item[$x] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Item", $x), $idTreeView)
            For $y = 1 To 3
                GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Child", $y), $aidTVi_Item[$x])
            Next
        Next
        _GUICtrlTreeView_EndUpdate($idTreeView)

        Local $iRand = Random(0, 9, 1)
        _GUICtrlTreeView_SelectItemByIndex($idTreeView, $aidTVi_Item[$iRand], 1)

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
        GUIDelete()
    EndFunc   ;==>Example