# Keyword Reference

# ContinueCase

Abort the code in the current Case block and continue with the code in the next Case block when in a Select or Switch structure.

ContinueCase

## Remarks

Normally in a Select or Switch structure, the code within each Case block ends when the next Case statement is encountered. Executing ContinueCase tells AutoIt to stop executing the code within the current Case block and start executing the code within the next Case block. AutoIt does not evaluate the next Case comparison statement - only the code inside the block is run.
Trying to execute ContinueCase outside of a Select or Switch will cause a fatal error.

## Related

Select...EndSelect, Switch...EndSwitch

## Example

    #include <MsgBoxConstants.au3>

    Example()

    Func Example()
        Local $sName = InputBox("", "Please enter a word.", "", " M", Default, Default, Default, Default, 10)
        Local $sMsg = ""

        Switch @error
            Case 2
                $sMsg = "Timeout "
                ContinueCase
            Case 1 ; Continuing previous case
                $sMsg &= "Cancellation"
            Case 0
                Switch $sName
                    Case "a", "e", "i", "o", "u"
                        $sMsg = "Vowel"
                    Case "QP"
                        $sMsg = "Mathematics"
                    Case "Q" To "QZ"
                        $sMsg = "Science"
                    Case Else
                        $sMsg = "Others"
                EndSwitch
            Case Else
                $sMsg = "Something went horribly wrong."
        EndSwitch

        MsgBox($MB_SYSTEMMODAL, "", $sMsg)
    EndFunc   ;==>Example