# Function Reference

# _GUICtrlRichEdit_SetLimitOnText

Change number of characters that can be typed, pasted or streamed in as Rich Text Format

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetLimitOnText ( $hWnd, $iNewLimit )

## Parameters

$hWnd | Handle to the control
$iNewLimit | new limit

## Return Value

Success: | True.
Failure: | False and sets the @error flag to non-zero.
@error: | 101 - $hWnd is not a handle 102 - $iNewLimit is neither a positive number nor zero

## Remarks

This function sets the limit on the number of characters a user can type in or paste into a control.
It also limits the number of characters of RTF text that can be streamed in using
_GUICtrlRichEdit_StreamFromFile() and _GUICtrlRichEdit_StreamFromVar().
It does not limit the amount of plain text that can be streamed in.
The initial limit is 32,767 characters.

## Related

_GUICtrlRichEdit_StreamFromFile, _GUICtrlRichEdit_StreamFromVar, _GUICtrlRichEdit_StreamToFile, _GUICtrlRichEdit_StreamToVar

## See Also

Search EM_EXLIMITTEXT in MSDN Library.

## Example

    #include <GUIConstantsEx.au3>
    #include <GuiRichEdit.au3>
    #include <WindowsStylesConstants.au3>

    Example()

    Func Example()
        Local $hGui, $iMsg, $idBtn_Next, $iStep = 0
        Local $idLbl_Msg, $hRichEdit
        $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, StringLen(".exe")) & ")", 320, 350, -1, -1)
        $hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
                BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
        $idLbl_Msg = GUICtrlCreateLabel("", 10, 235, 300, 60)
        $idBtn_Next = GUICtrlCreateButton("Next", 270, 310, 40, 30)
        GUISetState(@SW_SHOW)

        _GUICtrlRichEdit_SetText($hRichEdit, "Paragraph 1")
        While True
            $iMsg = GUIGetMsg()
            Select
                Case $iMsg = $GUI_EVENT_CLOSE
                    _GUICtrlRichEdit_Destroy($hRichEdit) ; needed unless script crashes
                    ; GUIDelete()   ; is OK too
                    Exit
                Case $iMsg = $idBtn_Next
                    $iStep += 1
                    Switch $iStep
                        Case 1
                            _GUICtrlRichEdit_SetLimitOnText($hRichEdit, 0)
                            GUICtrlSetData($idLbl_Msg, "1. Limit set to 65,536 characters")
                        Case 2
                            _GUICtrlRichEdit_SetLimitOnText($hRichEdit, 100000)
                            GUICtrlSetData($idLbl_Msg, "2. Limit set to 100,000 characters")
                            GUICtrlSetState($idBtn_Next, $GUI_DISABLE)
                    EndSwitch
            EndSelect
        WEnd
    EndFunc   ;==>Example