# Function Reference

# _GUICtrlComboBoxEx_GetCurSel

Retrieve the index of the currently selected item

#include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_GetCurSel ( $hWnd )

## Parameters

$hWnd | Handle to the control

## Return Value

Success: | the index of the item selected.
Failure: | -1.

## Related

_GUICtrlComboBoxEx_SetCurSel

## Example

    #include <GuiComboBoxEx.au3>
    #include <GUIConstantsEx.au3>
    #include <GuiImageList.au3>
    #include <MsgBoxConstants.au3>
    #include <WindowsStylesConstants.au3>

    Example()

    Func Example()
        ; Create GUI
        Local $hGUI = GUICreate("ComboBoxEx Get/Set Cur Sel (v" & @AutoItVersion & ")", 400, 300)
        Local $hCombo = _GUICtrlComboBoxEx_Create($hGUI, "", 2, 2, 394, 100, BitOR($CBS_SIMPLE, $WS_VSCROLL, $WS_BORDER))
        GUISetState(@SW_SHOW)

        Local $hImage = _GUIImageList_Create(16, 16, 5, 3)
        _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 110)
        _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 131)
        _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 165)
        _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 168)
        _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 137)
        _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 146)
        _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0xFF0000, 16, 16))
        _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x00FF00, 16, 16))
        _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x0000FF, 16, 16))
        _GUICtrlComboBoxEx_SetImageList($hCombo, $hImage)

        _GUICtrlComboBoxEx_InitStorage($hCombo, 100, 320)

        _GUICtrlComboBoxEx_BeginUpdate($hCombo)
        For $x = 0 To 99
            _GUICtrlComboBoxEx_AddString($hCombo, StringFormat("%03d : string", $x), Random(0, 8, 1), Random(0, 8, 1), Random(0, 8, 1))
        Next
        _GUICtrlComboBoxEx_EndUpdate($hCombo)

        ; Set Cur Sel
        _GUICtrlComboBoxEx_SetCurSel($hCombo, Random(0, 99, 1))

        ; Get Cur Sel
        MsgBox($MB_SYSTEMMODAL, "Information", "Current Sel: " & _GUICtrlComboBoxEx_GetCurSel($hCombo))

        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
    EndFunc   ;==>Example