# Function Reference

# _GUICtrlRichEdit_GetLineLength

Retrieves the length of a line

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetLineLength ( $hWnd, $iLine )

## Parameters

$hWnd | Handle to the control
$iLine | line number Special value: -1 - return number of unselected characters on lines containing selected characters

## Return Value

Success: | Multi-line control - Length of the line (in characters). Single-line control - number of characters in the control.
Failure: | 0 and sets the @error flag to non-zero.
@error: | 101 - $hWnd is not a handle 102 - $iLine is neither positive nor -1 1022 - $iLine is greater than number of characters in the control

## Remarks

A control that contains no text has one line.
The first inter-character position in a control is 0.
The result does not include carriage-return characters at the end of the line.

## See Also

Search EM_GETLINELENGTH in MSDN Library.

## Example

    #include <GUIConstantsEx.au3>
    #include <GuiRichEdit.au3>
    #include <WindowsStylesConstants.au3>

    Global $g_idLbl_Msg

    Example()

    Func Example()
        Local $hGui, $hRichEdit, $iMsg
        $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, StringLen(".exe")) & ")", 320, 350, -1, -1)
        $hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
                BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
        $g_idLbl_Msg = GUICtrlCreateLabel("", 10, 235, 300, 60)
        GUISetState(@SW_SHOW)

        Report("The current line contains " & _GUICtrlRichEdit_GetLineLength($hRichEdit, -1) & " characters")

        While True
            $iMsg = GUIGetMsg()
            Select
                Case $iMsg = $GUI_EVENT_CLOSE
                    _GUICtrlRichEdit_Destroy($hRichEdit) ; needed unless script crashes
                    ; GUIDelete()   ; is OK too
                    Exit
            EndSelect
        WEnd
    EndFunc   ;==>Example

    Func Report($sMsg)
        GUICtrlSetData($g_idLbl_Msg, $sMsg)
    EndFunc   ;==>Report