# Function Reference

# _GUICtrlTab_GetItemRectEx

Retrieves the bounding rectangle for a tab

#include <GuiTab.au3>
_GUICtrlTab_GetItemRectEx ( $hWnd, $iIndex )

## Parameters

$hWnd | Control ID/Handle to the control
$iIndex | 0-based item index

## Return Value

Returns a $tagRECT structure that receives the rectangle of the tab, in viewport coordinates.

## Related

$tagRECT, _GUICtrlTab_GetItemRect

## Example

### Example 1

    #include "Extras\HelpFileInternals.au3"

    #include <GUIConstantsEx.au3>
    #include <GuiTab.au3>
    #include <MsgBoxConstants.au3>

    Example()

    Func Example()
        ; Create GUI
        Local $hGUI = GUICreate("Tab Control Get Item RectEx (v" & @AutoItVersion & ")", 450, 300, 100, 100)
        Local $idTab = GUICtrlCreateTab(2, 2, 446, 266)
        _MemoMsgBoxStatus() ; Status creation

        GUISetState(@SW_SHOW)

        ; Add tabs
        _GUICtrlTab_InsertItem($idTab, 0, "Tab 0")
        _GUICtrlTab_InsertItem($idTab, 1, "Tab 1")
        _GUICtrlTab_InsertItem($idTab, 2, "Tab 2")

        ; Get item 0 rectangle
        Local $tRECT = _GUICtrlTab_GetItemRectEx($idTab, 0)
        Local $sRect = StringFormat("[%d, %d, %d, %d]", DllStructGetData($tRECT, "Left"), _
                DllStructGetData($tRECT, "Top"), _
                DllStructGetData($tRECT, "Right"), _
                DllStructGetData($tRECT, "Bottom"))
        _MemoMsgBox($MB_SYSTEMMODAL, "Information", "Display #0 rectangle: " & $sRect)

        _MemoMsgBoxStatus("", -1, $hGUI) ; no more action, wait GUI for closing

    EndFunc   ;==>Example

### Example (OutProcess) : Tab Get Item RectEx to an External process

    #include "Extras\HelpFileInternals.au3"

    #include <GuiTab.au3>
    #include <MsgBoxConstants.au3>

    Example()

    Func Example()
        Local $sFromTo
        Local $hWin = _MemoRunAU3OutProcess($sFromTo, False) ; OK also if running in different mode
        Local $hTabCtrl = _MemoCreateOutProcess($hWin, "SysTabControl32", 1, $sFromTo)

        Local $tRECT = _GUICtrlTab_GetItemRectEx($hTabCtrl, 0)
        Local $sRect = StringFormat("[%d, %d, %d, %d]", DllStructGetData($tRECT, "Left"), _
                DllStructGetData($tRECT, "Top"), _
                DllStructGetData($tRECT, "Right"), _
                DllStructGetData($tRECT, "Bottom"))
        _MemoMsgBox($MB_SYSTEMMODAL, "Info" & $sFromTo, "Display #0 rectangle : " & $sRect)

        _MemoMsgBoxStatus("", -1, $hWin) ; no more action, wait GUI for closing, close also OutProcess GUI

    EndFunc   ;==>Example