# Function Reference

# _GUICtrlToolbar_DeleteButton

Deletes a button from the toolbar

#include <GuiToolbar.au3>
_GUICtrlToolbar_DeleteButton ( $hWnd, $iCommandID )

## Parameters

$hWnd | Handle to the control
$iCommandID | Button command ID

## Return Value

Success: | True.
Failure: | False.

## Related

_GUICtrlToolbar_AddButton

## Example

    #include <GUIConstantsEx.au3>
    #include <GuiToolbar.au3>
    #include <MsgBoxConstants.au3>
    #include <WinAPIConstants.au3>

    Example()

    Func Example()
        Local $hGUI, $hToolbar
        Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $e_idHelp

        ; Create GUI
        $hGUI = GUICreate("Toolbar", 400, 300)
        $hToolbar = _GUICtrlToolbar_Create($hGUI)
        GUISetState(@SW_SHOW)

        ; Add standard system bitmaps
        _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)

        ; Add buttons
        _GUICtrlToolbar_AddButton($hToolbar, $e_idNew, $STD_FILENEW)
        _GUICtrlToolbar_AddButton($hToolbar, $e_idOpen, $STD_FILEOPEN)
        _GUICtrlToolbar_AddButton($hToolbar, $e_idSave, $STD_FILESAVE)
        _GUICtrlToolbar_AddButtonSep($hToolbar)
        _GUICtrlToolbar_AddButton($hToolbar, $e_idHelp, $STD_HELP)

        ; Delete Help button
        MsgBox($MB_SYSTEMMODAL, "Information", "Deleting Help button")
        _GUICtrlToolbar_DeleteButton($hToolbar, $e_idHelp)

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
    EndFunc   ;==>Example