# Function Reference

# _GUICtrlTab_DeselectAll

Resets tabs, clearing any that were set to the pressed state

#include <GuiTab.au3>
_GUICtrlTab_DeselectAll ( $hWnd [, $bExclude = True] )

## Parameters

$hWnd | Control ID/Handle to the control
$bExclude | [optional] Exclusion flag: True - All tabs except for the one currently selected will be reset False - All tab items will be reset

## Return Value

None.

## Remarks

This only works if $TCS_BUTTONS style flag has been set.

## Related

_GUICtrlTab_SetCurSel

## Example

    #include "Extras\HelpFileInternals.au3"

    #include <GUIConstantsEx.au3>
    #include <GuiTab.au3>
    #include <MsgBoxConstants.au3>
    #include <TabConstants.au3>

    Example()

    Func Example()
        ; Create GUI
        Local $hGUI = GUICreate("Tab Deselect All - v(" & @AutoItVersion & ")", 450, 300, 100, 100)
        Local $idTab = GUICtrlCreateTab(2, 2, 446, 266, $TCS_BUTTONS)
        _MemoMsgBoxStatus() ; Status creation

        GUISetState(@SW_SHOW)

        ; Add tabs
        _GUICtrlTab_InsertItem($idTab, 0, "Tab 0")
        _GUICtrlTab_InsertItem($idTab, 1, "Tab 1")
        _GUICtrlTab_InsertItem($idTab, 2, "Tab 2")

        ; Select 2nd Tab Item
        _GUICtrlTab_SetCurSel($idTab, 1)

        ; Reset tab selection
        _MemoMsgBox($MB_SYSTEMMODAL, "Information", "Resetting tab selection")
        _GUICtrlTab_DeselectAll($idTab, False)

        _MemoMsgBoxStatus("", -1, $hGUI) ; no more action, wait GUI for closing

    EndFunc   ;==>Example