# Function Reference

# _GUICtrlRichEdit_SetText

Sets the text of a control

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_SetText ( $hWnd, $sText )

## Parameters

$hWnd | Handle to the control
$sText | Plain or RTF text to put into the control

## Return Value

Succcess: | True.
Failure: | False and sets the @error flag to non-zero.
@error: | 101 - $hWnd is not a handle

## Remarks

Sets all of the text. Text can be plain or RTF text.
Keeps the undo stack.

## Related

_GUICtrlRichEdit_AppendText, _GUICtrlRichEdit_EmptyUndoBuffer, _GUICtrlRichEdit_GetText, _GUICtrlRichEdit_InsertText, _GUICtrlRichEdit_ReplaceText

## Example

    #include <GUIConstantsEx.au3>
    #include <GuiRichEdit.au3>
    #include <WindowsStylesConstants.au3>

    Global $g_idLbl_Msg

    Example()

    Func Example()
        Local $hGui = GUICreate("RichEdit Get/Set Text (v" & @AutoItVersion & ")", 340, 350, -1, -1)
        Local $hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 320, 220, _
                BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
        $g_idLbl_Msg = GUICtrlCreateLabel("", 10, 235, 300, 60)
        GUISetState(@SW_SHOW)

        _GUICtrlRichEdit_SetText($hRichEdit, "This is Set text.")

        Report("Text: " & @CRLF & @CRLF & _GUICtrlRichEdit_GetText($hRichEdit))

        Local $iMsg
        While True
            $iMsg = GUIGetMsg()
            Select
                Case $iMsg = $GUI_EVENT_CLOSE
                    _GUICtrlRichEdit_Destroy($hRichEdit) ; needed unless script crashes
                    ; GUIDelete()   ; is OK too
                    Exit
            EndSelect
        WEnd
    EndFunc   ;==>Example

    Func Report($sMsg)
        GUICtrlSetData($g_idLbl_Msg, $sMsg)
    EndFunc   ;==>Report