# Function Reference

# _GUICtrlRichEdit_GetSpaceUnit

Gets the unit of measure of horizontal and vertical space used in parameters of various _GUICtrlRichEdit functions

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetSpaceUnit ( )

## Return Value

Returns "in", "cm", "mm", "pt" (points), or "tw" (twips, 1/1440 inches, 1/567 centimetres).

## Remarks

Initially, space is measured in inches.

## Related

_GUICtrlRichEdit_SetSpaceUnit

## Example

    #include <GUIConstantsEx.au3>
    #include <GuiRichEdit.au3>
    #include <WindowsStylesConstants.au3>

    Global $g_idLbl_Msg

    Example()

    Func Example()
        Local $hGui = GUICreate("RichEdit Get/Set SpaceUnit (v" & @AutoItVersion & ")", 360, 350, -1, -1)
        Local $hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 340, 220, _
                BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
        $g_idLbl_Msg = GUICtrlCreateLabel("", 10, 235, 300, 60)
        Local $idBtn_Next = GUICtrlCreateButton("Next", 270, 310, 40, 30)
        GUISetState(@SW_SHOW)

        _GUICtrlRichEdit_SetText($hRichEdit, "Paragraph 1")
        Local $iMsg, $iStep = 0
        While True
            $iMsg = GUIGetMsg()
            Select
                Case $iMsg = $GUI_EVENT_CLOSE
                    _GUICtrlRichEdit_Destroy($hRichEdit) ; needed unless script crashes
                    ; GUIDelete()   ; is OK too
                    Exit
                Case $iMsg = $idBtn_Next
                    $iStep += 1
                    Switch $iStep
                        Case 1
                            Report("1. Initial setting")
                        Case 2
                            _GUICtrlRichEdit_SetSpaceUnit("cm")
                            Report("2. Setting is now")
                            GUICtrlSetState($idBtn_Next, $GUI_DISABLE)
                    EndSwitch
            EndSelect
        WEnd
    EndFunc   ;==>Example

    Func Report($sMsg)
        $sMsg = $sMsg & @CRLF & _GUICtrlRichEdit_GetSpaceUnit()
        GUICtrlSetData($g_idLbl_Msg, $sMsg)
    EndFunc   ;==>Report