# Function Reference

# _GUICtrlRichEdit_ScrollLines

Scrolls the text down or up a number of lines

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_ScrollLines ( $hWnd, $iQlines )

## Parameters

$hWnd | Handle to the control
$iQlines | number of lines to scroll

## Return Value

Success: | True.
Failure: | False and sets the @error flag to non-zero.
@error: | 101 - $hWnd is not a handle 102 - $iQlines is not numeric 700 - attempt to scroll a single-line control

## Remarks

To scroll down, set $iQlines to a positive value; to scroll up, a negative value.
_GUICtrlRichEdit_ScrollLines() is well behaved:
if $iQlines is more than the number of lines below the current line, it scrolls to show only the last line;
if $iQlines is negative and specifies a line before the first one, it scrolls to show the first line at the top of the control window.

## Related

_GUICtrlRichEdit_ScrollLineOrPage, _GUICtrlRichEdit_ScrollToCaret

## See Also

Search EM_LINESCROLL in MSDN Library.

## Example

    #include <GUIConstantsEx.au3>
    #include <GuiRichEdit.au3>
    #include <WindowsStylesConstants.au3>

    Global $g_idLbl_Msg

    Example()

    Func Example()
        Local $hGui, $iMsg, $idBtn_Next, $hRichEdit, $iStep = 0
        $hGui = GUICreate("Example (" & StringTrimRight(@ScriptName, StringLen(".exe")) & ")", 320, 350, -1, -1)
        $hRichEdit = _GUICtrlRichEdit_Create($hGui, "This is a test.", 10, 10, 300, 220, _
                BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
        $g_idLbl_Msg = GUICtrlCreateLabel("", 10, 235, 300, 60)
        $idBtn_Next = GUICtrlCreateButton("Next", 270, 310, 40, 30)
        GUISetState(@SW_SHOW)

        For $i = 1 To 20
            _GUICtrlRichEdit_AppendText($hRichEdit, "Line " & $i & @CRLF)
        Next
        _GUICtrlRichEdit_AppendText($hRichEdit, "Line 21")

        While True
            $iMsg = GUIGetMsg()
            Select
                Case $iMsg = $GUI_EVENT_CLOSE
                    _GUICtrlRichEdit_Destroy($hRichEdit) ; needed unless script crashes
                    ; GUIDelete()   ; is OK too
                    Exit
                Case $iMsg = $idBtn_Next
                    $iStep += 1
                    Switch $iStep
                        Case 1
                            _GUICtrlRichEdit_ScrollLines($hRichEdit, -10.2)
                            Report("Scrolled up")
                        Case 2
                            _GUICtrlRichEdit_ScrollLines($hRichEdit, +100)
                            Report("Scrolled down so only last line shows")
                        Case 3
                            _GUICtrlRichEdit_ScrollLines($hRichEdit, -200)
                            Report("Scrolled up all the way")
                            GUICtrlSetState($idBtn_Next, $GUI_DISABLE)
                    EndSwitch
            EndSelect
        WEnd
    EndFunc   ;==>Example

    Func Report($sMsg)
        GUICtrlSetData($g_idLbl_Msg, $sMsg)
    EndFunc   ;==>Report