# Function Reference

# _GUICtrlTreeView_EndEdit

Ends the editing of the item's text

#include <GuiTreeView.au3>
_GUICtrlTreeView_EndEdit ( $hWnd [, $bCancel = False] )

## Parameters

$hWnd | Control ID/Handle to the control
$bCancel | [optional] Indicates whether the editing is cancelled without being saved to the item. If True, the system cancels editing without saving the changes.

## Return Value

Success: | True.
Failure: | False.

## Related

_GUICtrlTreeView_EditText

## Example

    #include <GUIConstantsEx.au3>
    #include <GuiImageList.au3>
    #include <GuiTreeView.au3>
    #include <WindowsStylesConstants.au3>

    Example()

    Func Example()
        GUICreate("TreeView Edit Text / End Edit (v" & @AutoItVersion & ")", 400, 300)

        Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)
        Local $idTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
        GUISetState(@SW_SHOW)

        ; Set ANSI format
    ;~     _GUICtrlTreeView_SetUnicodeFormat($idTreeView, False)

        Local $hImage = _GUIImageList_Create(16, 16, 5, 3)
        _GUIImageList_AddIcon($hImage, "shell32.dll", 110)
        _GUIImageList_AddIcon($hImage, "shell32.dll", 131)
        _GUIImageList_AddIcon($hImage, "shell32.dll", 165)
        _GUIImageList_AddIcon($hImage, "shell32.dll", 168)
        _GUIImageList_AddIcon($hImage, "shell32.dll", 137)
        _GUIImageList_AddIcon($hImage, "shell32.dll", 146)
        _GUICtrlTreeView_SetNormalImageList($idTreeView, $hImage)

        Local $ahItem[6]
        For $x = 0 To _GUIImageList_GetImageCount($hImage) - 1
            $ahItem[$x] = _GUICtrlTreeView_Add($idTreeView, 0, StringFormat("[%02d] New Item", $x), $x, $x)
        Next

        ; Edit item 0 label
        _GUICtrlTreeView_EditText($idTreeView, $ahItem[0])
        Sleep(500)
        Send("This is a test")
        Sleep(500)
        _GUICtrlTreeView_EndEdit($idTreeView)

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
        GUIDelete()
    EndFunc   ;==>Example