# Function Reference

# _GUICtrlTreeView_SetState

Set the state of the specified item

#include <GuiTreeView.au3>
_GUICtrlTreeView_SetState ( $hWnd, $hItem [, $iState = 0 [, $bSetState = True]] )

## Parameters

$hWnd | Control ID/Handle to the control
$hItem | Handle to the item
$iState | [optional] The new item state, can be one or more of the following: $TVIS_SELECTED - Set item selected $TVIS_CUT - Set item as part of a cut-and-paste operation $TVIS_DROPHILITED - Set item as a drag-and-drop target $TVIS_BOLD - Set item as bold $TVIS_EXPANDED - Expand item $TVIS_EXPANDEDONCE - Set item's list of child items has been expanded at least once $TVIS_EXPANDPARTIAL - Set item as partially expanded
$bSetState | [optional] True if item state is to be set, False remove item state

## Return Value

Success: | True.
Failure: | False.

## Remarks

State values can BitOR'ed together as for example BitOR($TVIS_SELECTED, $TVIS_BOLD).

## Related

_GUICtrlTreeView_GetState

## Example

    #include <GUIConstantsEx.au3>
    #include <GuiTreeView.au3>
    #include <MsgBoxConstants.au3>
    #include <WindowsStylesConstants.au3>

    Example()

    Func Example()
        GUICreate("TreeView Get/Set State (v" & @AutoItVersion & ")", 400, 300)

        Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)
        Local $idTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
        GUISetState(@SW_SHOW)

        ; Set ANSI format
    ;~     _GUICtrlTreeView_SetUnicodeFormat($idTreeView, False)

        _GUICtrlTreeView_BeginUpdate($idTreeView)
        Local $aidTVi_Item[10]
        For $x = 0 To 9
            $aidTVi_Item[$x] = GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Item", $x), $idTreeView)
            For $y = 1 To Random(2, 10, 1)
                GUICtrlCreateTreeViewItem(StringFormat("[%02d] New Child", $y), $aidTVi_Item[$x])
            Next
        Next
        _GUICtrlTreeView_EndUpdate($idTreeView)

        Local $iRand = Random(0, 9, 1)
        _GUICtrlTreeView_SetSelected($idTreeView, $aidTVi_Item[$iRand])
        MsgBox($MB_SYSTEMMODAL, "Information", StringFormat("State for Index %d: %s", $iRand, _GUICtrlTreeView_GetState($idTreeView, $aidTVi_Item[$iRand])))
        MsgBox($MB_SYSTEMMODAL, "Information", StringFormat("State for Index %d: %s", 0, _GUICtrlTreeView_GetState($idTreeView)))

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
        GUIDelete()
    EndFunc   ;==>Example