# Function Reference

# _GUICtrlListBox_ReplaceString

Replaces the text of an item

#include <GuiListBox.au3>
_GUICtrlListBox_ReplaceString ( $hWnd, $iIndex, $sText )

## Parameters

$hWnd | Control ID/Handle to the control
$iIndex | Specifies the 0-based index of the item
$sText | String to replace old string

## Return Value

Success: | True.
Failure: | False.

## Example

    #include <GUIConstantsEx.au3>
    #include <GuiListBox.au3>
    #include <MsgBoxConstants.au3>

    Example()

    Func Example()
        Local $sText, $idListBox

        ; Create GUI
        GUICreate("List Box Replace String", 400, 296)
        $idListBox = GUICtrlCreateList("", 2, 2, 396, 296, BitOR($LBS_STANDARD, $LBS_EXTENDEDSEL))
        GUISetState(@SW_SHOW)

        ; Add strings
        _GUICtrlListBox_BeginUpdate($idListBox)
        For $iI = 1 To 9
            $sText = StringFormat("%03d : Random string ", Random(1, 100, 1))
            For $iX = 1 To Random(1, 20, 1)
                $sText &= Chr(Random(65, 90, 1))
            Next
            _GUICtrlListBox_AddString($idListBox, $sText)
        Next
        _GUICtrlListBox_EndUpdate($idListBox)

        ; Replace string
        MsgBox($MB_SYSTEMMODAL, "Information", "Replacing String at Index 3")
        _GUICtrlListBox_ReplaceString($idListBox, 3, "gone")

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
        GUIDelete()
    EndFunc   ;==>Example