# Function Reference

# _SQLite_Display2DResult

Returns or prints to Console a formated display of a 2Dimensional array

#include <SQLite.au3>
_SQLite_Display2DResult ( $aResult [, $iCellWidth = 0 [, $bReturn = False [, $sDelim_Col = "" [, $sDelim_Row = @CRLF]]]] )

## Parameters

$aResult | The array to be displayed
$iCellWidth | [optional] specifies the size of a data field
$bReturn | [optional] if True the formated string is returned, not displayed If False the formatted string is send to StdOut
$sDelim_Col | [optional] specifies the column delimiter (default = "")
$sDelim_Row | [optional] specifies the row delimiter (default = @CRLF)

## Return Value

Success: | none or formated string.
Failure: | sets the @error flag to non-zero.
@error: | 1 - $aResult is no array or has wrong dimension

## Related

_SQLite_GetTable2D

## Example

    #include <MsgBoxConstants.au3>
    #include <SQLite.au3>
    #include <SQLite.dll.au3>

    Local $aResult, $iRows, $iColumns, $iRval

    _SQLite_Startup()
    If @error Then
        MsgBox($MB_SYSTEMMODAL, "SQLite Error", "SQLite3.dll Can't be Loaded!")
        Exit -1
    EndIf
    ConsoleWrite("_SQLite_LibVersion=" & _SQLite_LibVersion() & @CRLF)
    _SQLite_Open() ; Open a :memory: database
    If @error Then
        MsgBox($MB_SYSTEMMODAL, "SQLite Error", "Can't Load Database!")
        Exit -1
    EndIf

    ; Example Table
    ; Name        | Age
    ; -----------------------
    ; Alice       | 43
    ; Bob         | 28
    ; Cindy       | 21

    If Not _SQLite_Exec(-1, "CREATE TEMP TABLE persons (Name, Age);") = $SQLITE_OK Then _
            MsgBox($MB_SYSTEMMODAL, "SQLite Error", _SQLite_ErrMsg())
    If Not _SQLite_Exec(-1, "INSERT INTO persons VALUES ('Alice','43');") = $SQLITE_OK Then _
            MsgBox($MB_SYSTEMMODAL, "SQLite Error", _SQLite_ErrMsg())
    If Not _SQLite_Exec(-1, "INSERT INTO persons VALUES ('Bob','28');") = $SQLITE_OK Then _
            MsgBox($MB_SYSTEMMODAL, "SQLite Error", _SQLite_ErrMsg())
    If Not _SQLite_Exec(-1, "INSERT INTO persons VALUES ('Cindy','21');") = $SQLITE_OK Then _
            MsgBox($MB_SYSTEMMODAL, "SQLite Error", _SQLite_ErrMsg())

    ; Query
    $iRval = _SQLite_GetTable2D(-1, "SELECT * FROM persons;", $aResult, $iRows, $iColumns)
    If $iRval = $SQLITE_OK Then
        _SQLite_Display2DResult($aResult)

        ; $aResult looks like this:
        ; Name   Age
        ; Alice  43
        ; Bob    28
        ; Cindy  21
        ; If the dimensions would be switched in _SQLite_GetTable2D the result would look like this:
        ; Name  Alice  Bob  Cindy
        ; Age   43     28   21

    Else
        MsgBox($MB_SYSTEMMODAL, "SQLite Error: " & $iRval, _SQLite_ErrMsg())
    EndIf

    _SQLite_Close()
    _SQLite_Shutdown()