# Function Reference

# _GUICtrlToolbar_SetButtonBitMap

Sets the index of the bitmap associated with a button

#include <GuiToolbar.au3>
_GUICtrlToolbar_SetButtonBitMap ( $hWnd, $iCommandID, $iIndex )

## Parameters

$hWnd | Handle to the control
$iCommandID | Button command ID
$iIndex | 0-based index of an images image list

## Return Value

Success: | True.
Failure: | False.

## Related

_GUICtrlToolbar_GetButtonBitmap

## Example

    #include <GUIConstantsEx.au3>
    #include <GuiToolbar.au3>
    #include <MsgBoxConstants.au3>
    #include <WinAPIConstants.au3>

    Example()

    Func Example()
        ; Create GUI
        Local $hGUI = GUICreate("Toolbar Get/Set Button Bitmap (v" & @AutoItVersion & ")", 400, 300)
        Local $hToolbar = _GUICtrlToolbar_Create($hGUI)
        GUISetState(@SW_SHOW)

        ; Add standard system bitmaps
        Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
            Case 0
                _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
            Case 2
                _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
        EndSwitch

        ; Add buttons
        Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $e_idHelp
        _GUICtrlToolbar_AddButton($hToolbar, $e_idNew, $STD_FILENEW)
        _GUICtrlToolbar_AddButton($hToolbar, $e_idOpen, $STD_FILEOPEN)
        _GUICtrlToolbar_AddButton($hToolbar, $e_idSave, $STD_FILESAVE)
        _GUICtrlToolbar_AddButtonSep($hToolbar)
        _GUICtrlToolbar_AddButton($hToolbar, $e_idHelp, $STD_HELP)

        ; Show Save button bitmap index
        MsgBox($MB_SYSTEMMODAL, "Information", "Changing Save bitmap to Print bitmap")
        _GUICtrlToolbar_SetButtonBitMap($hToolbar, $e_idSave, $STD_PRINT)
        MsgBox($MB_SYSTEMMODAL, "Information", "Save button bitmap index: " & _GUICtrlToolbar_GetButtonBitmap($hToolbar, $e_idSave))

        ; Loop until the user exits.
        Do
        Until GUIGetMsg() = $GUI_EVENT_CLOSE
    EndFunc   ;==>Example