Function Reference

_PPT_HeaderFooterList

Returns a list of Headers and Footers for a Presentation or SlideMaster.

#Include <PowerPoint.au3>
_PPT_HeaderFooterList($oObject)

 

Parameters

$oObject Presentation or SlideMaster object.

 

Return Value

Success: a two-dimensional zero based array with the following information:
    0 - HeadersFooters object
    1 - True if the footer, date and time, and slide number appear on the title slide. Applies to slide masters.
    2 - Header text (if available)
    3 - Footer text (if available)
    4 - DateAndTime Format (if available)
    5 - SlideNumber text (if available)
Failure: 0 and sets @error.
    1 - $oObject has to be a presentation or a SlideMaster object

 

Remarks

None.

 

Related

_PPT_HeaderFooterSet

 

Example


#AutoIt3Wrapper_AU3Check_Parameters= -d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#AutoIt3Wrapper_AU3Check_Stop_OnWarning=N
#include <PowerPoint.au3>
#include <MsgBoxConstants.au3>
#include <Array.au3>

; ***********************
; Create application object
; ***********************
Global $oPPT = _PPT_Open()
If @error Then Exit MsgBox($MB_ICONERROR, "PowerPoint UDF: _PPT_HeaderFooterList Example", "Error creating the PowerPoint application object." & @CRLF & "@error = " & @error & ", @extended = " & @extended)

; ***********************
; Open a presentations
; ***********************
Global $sPresentation = @ScriptDir & "\PresentationHeaderFooter.pptx"
Global $oPresentation = _PPT_PresentationOpen($oPPT, $sPresentation, True)
If @error Then Exit MsgBox($MB_ICONERROR, "PowerPoint UDF: _PPT_HeaderFooterList Example", "Error opening presentation '" & $sPresentation & "'." & @CRLF & "@error = " & @error & ", @extended = " & @extended)

; ****************************************
; Display a list of all used Headers and Footers
; ****************************************
Global $aHeadersFooters = _PPT_HeaderFooterList($oPresentation.Slidemaster)
If @error Then Exit MsgBox($MB_ICONERROR, "PowerPoint UDF: _PPT_HeaderFooterList Example 1", "Error listing Headers/Footers." & @CRLF & "@error = " & @error & ", @extended = " & @extended)
_ArrayDisplay($aHeadersFooters, "PowerPoint UDF: _PPT_HeaderFooterList Example 1 - List of used Headers/Footers")