Is it possible to use a varible as a property or method?

[spudw2k]

Is it possible to use a variable in place of property or method of an object?

example. I want to do a WMI query and pull variable results.

$host = "localhost"

$strWMIQuery = "SELECT * FROM Win32_ComputerSystem"

$objWMIService = ObjGet("winmgmts:{impersonationLevel=impersonate}!\\" & $host & "\root\cimv2")

$colItems = $objWMIService.ExecQuery ($strWMIQuery)

For $objItem in $colItems

msgbox(0,"Hostname",$objItem.Name) ;<--- .Name is what I'd like to be able replace with a variable

Next

[PsaltyDS]

Is it possible to use a variable in place of property or method of an object?

example. I want to do a WMI query and pull variable results.

$host = "localhost"

$strWMIQuery = "SELECT * FROM Win32_ComputerSystem"

$objWMIService = ObjGet("winmgmts:{impersonationLevel=impersonate}!\\" & $host & "\root\cimv2")

$colItems = $objWMIService.ExecQuery ($strWMIQuery)

For $objItem in $colItems

msgbox(0,"Hostname",$objItem.Name) ;<--- .Name is what I'd like to be able replace with a variable

Next

This is kind of a silly question... what happens when you run it...?

And silly questions do not become less silly by liberal application of color tags...

Edited August 16, 2007 by PsaltyDS

[spudw2k]

A message box with your hostname in it

[lordofthestrings]

in short No, it's not possible to do this..

plus I would really disadvice this practise .. (not good coding and allow me to explain)

a method (.Name) is allready the easiest discription of the action you want to perform with this object.

the only thing you could achieve is add unnecessary code (meaning: complications) to your script.

allow me to demonstrate using the Speech api.

speak("this is steven hawkins, wazaaaaaaap")
speak2("this is steven hawkins, wazaaaaaaap")

Func speak($Text)
$spApi = ObjCreate("SAPI.SpVoice")
$spApi.Speak($Text)
EndFunc ;speak($Text)



Func speak2($Text)
$x = "Speak"
$spApi = ObjCreate("SAPI.SpVoice")
$spApi.$x($Text)
EndFunc ;speak($Text)

if you remove the line that calls speak2() and remove the function (speak2)

then the script works.. plus read the errormessage you get when you try running this code..

==> Expected a "=" operator in assignment statement.:

Edited August 17, 2007 by lordofthestrings

[PsaltyDS]

A message box with your hostname in it

Well, what I meant was: what happens when you replace .Name with a variable. I was only pointing out that it would be a very easy experiment to conduct and see the results. Looks like lordofthestrings did that for you already, though.

EDIT: This works:

$host = "localhost"
$strWMIQuery = "SELECT * FROM Win32_ComputerSystem"

$objWMIService = ObjGet("winmgmts:{impersonationLevel=impersonate}!\\" & $host & "\root\cimv2")
$colItems = $objWMIService.ExecQuery ($strWMIQuery)
$Property = 'Name'
For $objItem In $colItems
    MsgBox(0, "Hostname", Execute('$objItem.' & $Property))
Next

Edited August 17, 2007 by PsaltyDS

[lordofthestrings]

ok, that makes me shut up (for a short while again)

[weaponx]

This works for for me:

speak("hello")
speak2("hello")

Func speak($Text)
    $spApi = ObjCreate("SAPI.SpVoice")
    $spApi.Speak($Text)
EndFunc ;speak($Text)



Func speak2($Text)
    $x = "Speak"
    $spApi = ObjCreate("SAPI.SpVoice")
    ;$spApi.$x($Text)
    Execute("$spApi." & $x & "($Text)")
EndFunc ;speak($Text)

[NELyon]

Does this work for you?

$method = "Name"
$host = "localhost"
$strWMIQuery = "SELECT * FROM Win32_ComputerSystem"

$objWMIService = ObjGet("winmgmts:{impersonationLevel=impersonate}!\\" & $host & "\root\cimv2")
$colItems = $objWMIService.ExecQuery ($strWMIQuery)

For $objItem in $colItems
msgbox(0,"Hostname",Execute("$objItem." & $method))
Next

Not Tested, but should work in theory

EDIT: Whoops, didn't see PsaltyDS' post...

Edited August 17, 2007 by Senton-Bomb

[weaponx]

I don't really see a usefullness for this considering that an object has a static set of member functions. They are not dynamic.

[spudw2k]

Well the only reason i was hoping to do this was to be able to call a function and dynamically request particular data, which happens to be returned from a property. I think the main issue is i'm passing a string to the object. Thanks for the answer though. At least I didn't waste to much time trying to find the answer. Maybe I'll just have the function grab all the data I would need and just pick and choose what I need at the time. Thanks again.

[DaleHohm]

It sounds like you are giving up... did you misunderstand? An answer was provided... the key is the Execute function:

$Name = "whatever-you-want"
msgbox(0, "Hostname", Execute("$objItem." & $Name))

Dale

[spudw2k]

Holy crap, that works! Thanks That makes things easier.

[spudw2k]

Here's what I needed it for btw.

expandcollapse popup

#include <Array.au3>

Local $oWMIService = _WMIService()  ;Instantiate WMIService Object - Establish Connection
If $oWMIService = 0 Then Exit   ;If WMI Object failed to instantiate, Abort Script

Local $sWMIQueryClass = "Win32_ComputerSystem"  ;Declare WMI Class to Query
Local $aWMIQueryFields[]= ["Name","Manufacturer","Model","Domain"]  ;Declare Fields to Retrieve From WMI Class

$aResults = _WMIQuery($oWMIService,$sWMIQueryClass,$aWMIQueryFields)  ;Run WMI Query against WMIService Object
$oWMIService = 0  ;Termninate WMIService Object

_ArrayDisplay($aResults)    ;Display Results Array
Exit

Func _WMIService($sHost = @ComputerName) ;Connect to WMI Service
    $oWMIService = ObjGet("winmgmts:{impersonationLevel=impersonate}!\\" & $sHost & "\root\cimv2")  ;Create WMI Service Object
    If Not IsObj($oWMIService) Then Return SetError(1,0,0)  ;If Obj Instantiation Failed, Error Out
    Return $oWMIService ;Return WMI Service Object
EndFunc

Func _WMIQuery($oWMIService,$sWMIQueryClass,$aWMIQueryFields) ;Perform WMI Query with Query String and Data Return Parameters
    If Not IsObj($oWMIService) Then Return SetError(1,0,0)  ;If oWMIService is not a valid Object, Error Out
    If Not IsArray($aWMIQueryFields) Then Return SetError(2,0,0)    ;If Query Fields is not a valid array, Error Out

    Local $aResults = $aWMIQueryFields  ;Create Results Array
    _ArrayColInsert($aResults, 1)   ;Add Dimension to Results Array to Hold Query Return Values

    Local $sWMIQuery = "SELECT " & _ArrayToString($aWMIQueryFields,",") & " FROM " & $sWMIQueryClass    ;Create WMI Query String
    $oItems = $oWMIService.ExecQuery ($sWMIQuery)  ;Execute query using WMI Service Object

    For $i = 0 to UBound($aWMIQueryFields) - 1  ;Loop through WMI Query Results
        For $oItem In $oItems
            $aResults[$i][1] = Execute("$oItem." & $aWMIQueryFields[$i])  ;Result
        Next
    Next

    Return $aResults  ;Return Result Array
EndFunc

edit: optimized example

Edited December 14, 2018 by spudw2k