I just dont understand why...

[Sobiech]

Hi again >_<

i rlly dont understand why i cant use buttons just if i click on button i dont see any move, any action :|

Here is my code

this DOESNT work

#include <ButtonConstants.au3>

#include <ComboConstants.au3>

#include <GUIConstantsEx.au3>

#include <StaticConstants.au3>

#include <WindowsConstants.au3>

#Region ### START Koda GUI section ### Form=

$Form2 = GUICreate("Form2", 496, 382, 191, 120)

$Pic1 = GUICtrlCreatePic("C:\Documents and Settings\Admin\Moje dokumenty\Moje obrazy\Satan\BotScreen.jpg", 0, 0, 495, 381, BitOR($SS_NOTIFY,$WS_GROUP,$WS_CLIPSIBLINGS))

$Button1 = GUICtrlCreateButton("Here is your mp3", 320, 184, 145, 25, $WS_GROUP)

$Button2 = GUICtrlCreateButton("Start", 32, 312, 147, 41, $WS_GROUP)

$Button3 = GUICtrlCreateButton("Exit", 312, 312, 147, 41, $WS_GROUP)

$Combo1 = GUICtrlCreateCombo("Set numnber of bws", 320, 216, 145, 25)

Opt("GUIOnEventMode", 1) ; Change to OnEvent mode

GUICtrlSetOnEvent($button1, "ExitButton") ; You must have this

GUISetOnEvent($GUI_EVENT_CLOSE, "ExitButton")

GUISetState(@SW_SHOW)

#EndRegion ### END Koda GUI section ###

While 1

$nMsg = GUIGetMsg()

Switch $nMsg

Case $GUI_EVENT_CLOSE

Exit

EndSwitch

WEnd

Func ExitButton()

MsgBox (0, "Exit", "You clicked EXIT! Exiting...")

Exit

EndFunc

This WORK

#include <ButtonConstants.au3>

#include <EditConstants.au3>

#include <GUIConstantsEx.au3>

#include <WindowsConstants.au3>

#Region ### START Koda GUI section ### Form=C:\Documents and Settings\Admin\Pulpit\GUI\Forms\First GUI.kxf

$Form1 = GUICreate("Form1", 524, 347, 198, 129)

$Button1 = GUICtrlCreateButton("Exit", 320, 296, 161, 33, $WS_GROUP)

$Button2 = GUICtrlCreateButton("Start", 40, 296, 161, 33, $WS_GROUP)

$Edit1 = GUICtrlCreateEdit("", 48, 96, 185, 89)

GUISetState(@SW_SHOW)

Opt("GUIOnEventMode", 1) ; Change to OnEvent mode

GUISetOnEvent($GUI_EVENT_CLOSE, "ExitButton")

GUICtrlSetOnEvent($button1, "ExitButton") ; You must have this

#EndRegion ### END Koda GUI section ###

While 1

$nMsg = GUIGetMsg()

Switch $nMsg

Case $GUI_EVENT_CLOSE

Exit

EndSwitch

WEnd

Func ExitButton()

MsgBox (0, "Exit", "You clicked EXIT! Exiting...")

Exit

EndFunc

I have this problem in many projects

Few days ago i dont have this problem.

Ofcourse i reinstall AutoIT and again download Koda GUI (non beta) so only you can help me :|

Edited August 14, 2009 by Sobiech

[Melba23]

Sobiech,

How about if you changed this:

GUICtrlSetOnEvent($button1, "ExitButton")

to this:

GUICtrlSetOnEvent($button3, "ExitButton")

M23

[Sobiech]

Sobiech,

How about if you changed this:

GUICtrlSetOnEvent($button1, "ExitButton")

to this:

GUICtrlSetOnEvent($button3, "ExitButton")

M23

Doesnt work >_<

my all buttons doesnt work but i changed this

If any button dont have any code then when we click on him we can see "push animation". I dont have animations of buttons

Edited August 14, 2009 by Sobiech

[Melba23]

Sobiech,

This is from your code:

$Button1 = GUICtrlCreateButton("Here is your mp3", 320, 184, 145, 25, $WS_GROUP)
$Button2 = GUICtrlCreateButton("Start", 32, 312, 147, 41, $WS_GROUP)
$Button3 = GUICtrlCreateButton("Exit", 312, 312, 147, 41, $WS_GROUP)
$Combo1 = GUICtrlCreateCombo("Set numnber of bws", 320, 216, 145, 25)
Opt("GUIOnEventMode", 1) ; Change to OnEvent mode 
GUICtrlSetOnEvent($button1, "ExitButton") ; You must have this

If you are in OnEvent mode, you need to define an action for each event/control. All you have at the moment is an action for button1 which is your "Here is your mp3" button. You have no events defined for the other buttons, so how do you expect them to react when pressed? Look at this:

expandcollapse popup

#include <ButtonConstants.au3>
#include <ComboConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>

Opt("GUIOnEventMode", 1) ; Change to OnEvent mode

#Region ### START Koda GUI section ### Form=
$Form2 = GUICreate("Form2", 496, 382, 191, 120)
GUISetOnEvent($GUI_EVENT_CLOSE, "ExitButton")
$Pic1 = GUICtrlCreatePic("C:\Documents and Settings\Admin\Moje dokumenty\Moje obrazy\Satan\BotScreen.jpg", 0, 0, 495, 381, BitOR($SS_NOTIFY,$WS_GROUP,$WS_CLIPSIBLINGS))
$Button1 = GUICtrlCreateButton("Here is your mp3", 320, 184, 145, 25, $WS_GROUP)
GUICtrlSetOnEvent($Button1, "mp3")
$Button2 = GUICtrlCreateButton("Start", 32, 312, 147, 41, $WS_GROUP)
GUICtrlSetOnEvent($Button2, "Start")
$Button3 = GUICtrlCreateButton("Exit", 312, 312, 147, 41, $WS_GROUP)
GUICtrlSetOnEvent($Button3, "ExitButton") ; You must have this

$Combo1 = GUICtrlCreateCombo("Set numnber of bws", 320, 216, 145, 25)

GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
    Sleep(100)
WEnd

Func ExitButton()
MsgBox (0, "Exit", "You clicked EXIT! Exiting...")
Exit
EndFunc

Func Start()
    MsgBox(0, "Start", "You pressed Start")
EndFunc

Func mp3()
    MsgBox(0, "mp3", "You pressed mp3")
EndFunc

M23

[Yashied]

If any button dont have any code then when we click on him we can see "push animation". I dont have animations of buttons >_<

I think that you are confused in your code, or showed us it does not fully.

[Sobiech]

I think that you are confused in your code, or showed us it does not fully.

It is Fully >_<

i had working projects with GUI, but now any projects doesnt work

This is impossible to block buttons? maybe program settings have errors :|

To melba23:

If any button dont have any code then when we click on him we can see "push animation". I dont have animations of buttons

And your code dont activate my buttons

Edited August 14, 2009 by Sobiech

[Yashied]

In such a case - this is poltergeist.

>_<

EDIT:

Try to work with Opt("GUIOnEventMode", 0).

Edited August 14, 2009 by Yashied

[Sobiech]

In such a case - this is poltergeist.

>_<

EDIT:

Try to work with Opt("GUIOnEventMode", 0).

Doesnt work

With 0 i closed program with ctrl+alt+del because i cant with click on [X]

[Yashied]

Doesnt work >_<

With 0 i closed program with ctrl+alt+del because i cant with click on [X]

Insert

GUICtrlSetState($Pic1, $GUI_DISABLE)

after

$Pic1 = GUICtrlCreatePic(...)

[Sobiech]

Insert

GUICtrlSetState($Pic1, $GUI_DISABLE)

after

$Pic1 = GUICtrlCreatePic(...)

THX THX THX

Now its work!

Master >_<

[Hawkwing]

In the first code you posted you had guigetmsg inside the while loop, but you had opt("guisetonevent", 1). Thought those didn't work together >_

[Melba23]

Hawkwing,

If you set Opt("GUISetOnEvent", 1) then (from the Help file) "the return from GUIGetMsg is always 0 and the @error is set to 1". So the function will not give you an error, but will not give you anything useful either! >_<

You can use the 2 modes in the same script without problem as long you are very careful in setting the Opt("GUISetOnEvent", ?) code as you move from one state to another. Here is a script I wrote a long time ago to illustrate how you might do it (not a very interesting script in itself, but it was to make the point about the mode changes):

expandcollapse popup

#include <GUIConstantsEx.au3>

Global $running = False;

Opt("GUIOnEventMode", 1) ; Set OnEvent mode

$GUI = GUICreate("Test", 150, 80)
    GUISetOnEvent($GUI_EVENT_CLOSE, "close")

$label = GUICtrlCreateLabel("OnEvent", 10, 15, 100, 20)
$counter = GUICtrlCreateLabel("", 120, 15, 25, 20)
$start = GUICtrlCreateButton("Start", 20, 44, 60)
    GUICtrlSetOnEvent($start, "start")
$stop = GUICtrlCreateButton("Stop", 80, 44, 60)
    GUICtrlSetState($stop, $GUI_DISABLE)

GUISetState(@SW_SHOW)

While (1)
    Sleep(100)
WEnd

;-------------------------

Func close()
    Exit
EndFunc   ;==>close

Func start()
    $running = True
    $ms = 500
    GUICtrlSetState($start, $GUI_DISABLE)
    GUICtrlSetState($stop, $GUI_ENABLE)

    Opt("GUIOnEventMode", 0) ; Switch to MessageLoop mode
    GUICtrlSetData($label, "MessageLoop")

    $begin = TimerInit()
    $count = 1

    While ($running)

        GUICtrlSetData($counter, $count)

        While TimerDiff($begin) < $ms

            If GUIGetMsg() = $stop Then
                stop()
                GUICtrlSetState($start, $GUI_ENABLE)
                GUICtrlSetData($counter, "")
                ExitLoop 2
            EndIf

        WEnd

        $begin = TimerInit()
        $count += 1

    WEnd
    Opt("GUIOnEventMode", 1) ; Switch to OnEvent mode
    GUICtrlSetData($label, "OnEvent")

    GUICtrlSetState($start, $GUI_ENABLE)
EndFunc   ;==>start

Func stop()
    GUICtrlSetState($stop, $GUI_DISABLE)
    $running = False
EndFunc   ;==>stop

I hope that make it all clear!

M23

[Leonick]

THX THX THX

Now its work!

Master >_<

Why did it solve the problem?

something wrong with the pic?

[BrettF]

Because it disables it, stopping it from receiving any input so to speak.

[Melba23]

Leonick,

This problem comes up every day or so - because people do not use Search or read the Help file. From the Help file remarks for GUICtrlCreatePic:

"If a picture is set as a background picture, as the other controls will overlap, it's important to disable the pic control and create it after the others controls: GuiCtrlSetState(-1,$GUI_DISABLE)".

M23