how do i split a file name?

[vladedoty]

How would i split the file name C:\Outlook2\Outlook2.exe

to just Outlook2.exe

so I would use 2 variables

$path = C:\Outlook2\Outlook2.exe

$program = ???? (I want this take the Outlook2.exe out of the path)

Edited August 28, 2009 by vladedoty

[playlet]

---

Edited August 18, 2016 by playlet

[bogQ]

Safer way to get last split

;~ #include <Array.au3>

$path = "C:\Outlook2\Outlook2.exe"
$Splited = StringSplit($path,"\")

;~ _ArrayDisplay($Splited)

MsgBox(0,"",$Splited[$Splited[0]])

Edited August 28, 2009 by bogQ

[Info]

Mine's cuter.

$path = "C:\Outlook2\Outlook2.exe"

MsgBox(0,"",StringTrimLeft($path,StringInStr($path,"\",0,-1)))

[Melba23]

Hi all,

These come courtesy of Malkey (I am not smart enough to do this on my own )

expandcollapse popup

; Credit: Malkey
;
Local $sFile = "C:\Program Files\Another Dir\AutoIt3\AutoIt3.chm"

; Drive letter -                                     Example returns     "C"
Local $sDrive = StringRegExpReplace($sFile, ":.*$", "")

; Full Path with backslash -                         Example returns     "C:\Program Files\Another Dir\AutoIt3\"
Local $sPath = StringRegExpReplace($sFile, "(^.*\\)(.*)", "\1")

; Full Path without backslash -                     Example returns     "C:\Program Files\Another Dir\AutoIt3"
Local $sPathExDr = StringRegExpReplace($sFile, "(^.:)(\\.*\\)(.*$)", "\2")

; Full Path w/0 backslashes, nor drive letter -     Example returns     "\Program Files\Another Dir\AutoIt3\"
Local $sPathExDrBSs = StringRegExpReplace($sFile, "(^.:\\)(.*)(\\.*$)", "\2")

; Path w/o backslash, not drive letter: -             Example returns     "Program Files\Another Dir\AutoIt3"
Local $sPathExBS = StringRegExpReplace($sFile, "(^.*)\\(.*)", "\1")

; File name with ext -                                 Example returns     "AutoIt3.chm"
Local $sFilName = StringRegExpReplace($sFile, "^.*\\", "")

; File name w/0 ext -                                 Example returns     "AutoIt3"
Local $sFilenameExExt = StringRegExpReplace($sFile, "^.*\\|\..*$", "")

; Dot Extenstion -                                     Example returns     ".chm"
Local $sDotExt = StringRegExpReplace($sFile, "^.*\.", ".$1")

; Extenstion -                                         Example returns     "chm"
Local $sExt = StringRegExpReplace($sFile, "^.*\.", "")

MsgBox(0, "Path File Name Parts", _
        "Drive             " & @TAB & $sDrive & @CRLF & _
        "Path              " & @TAB & $sPath & @CRLF & _
        "Path w/o backslash" & @TAB & $sPathExBS & @CRLF & _
        "Path w/o Drv:     " & @TAB & $sPathExDr & @CRLF & _
        "Path w/o Drv or \'s" & @TAB & $sPathExDrBSs & @CRLF & _
        "File Name         " & @TAB & $sFilName & @CRLF & _
        "File Name w/o Ext " & @TAB & $sFilenameExExt & @CRLF & _
        "Dot Extension     " & @TAB & $sDotExt & @CRLF & _
        "Extension         " & @TAB & $sExt & @CRLF)

Best path splitting tools I have ever seen - I use them all the time.

M23

[somdcomputerguy]

I have used the _PathSplit UDF, this example from manual

#include <file.au3>
#include <array.au3>
Dim $szDrive, $szDir, $szFName, $szExt
$TestPath = _PathSplit(@ScriptFullPath,  $szDrive,  $szDir,  $szFName,  $szExt)
_ArrayDisplay($TestPath,"Demo  _PathSplit()")

[WolfWorld]

I have used the _PathSplit UDF, this example from manual

#include <file.au3>
#include <array.au3>
Dim $szDrive, $szDir, $szFName, $szExt
$TestPath = _PathSplit(@ScriptFullPath,  $szDrive,  $szDir,  $szFName,  $szExt)
_ArrayDisplay($TestPath,"Demo  _PathSplit()")

+1 Safes way.