How do I put a web link in my GUI

[quick_sliver007]

How do I put a internet link in my GUI?

[GaryFrost]

here's an example of an email link, your link can be anything you want.

expandcollapse popup

#include <GUIConstants.au3>
#include <Inet.au3>

   GUICreate("Create a link", 500, 250)
   #Region --- CFCCodeWizard generated code Start ---
   Dim $CADET_BLUE_3 = 0x7AC5CD
   GUISetBkColor($CADET_BLUE_3)
   #EndRegion --- CFCCodeWizard generated code End ---
   $LABEL = _GuiCtrlCreateHyperlink("Email me if you can", 27, 130, 443, 20, 0x0000ff, 'E-Mail ' & "your email.com" & " (comments/questions)")
   $CLOSE = GUICtrlCreateButton("Close", 200, 190, 85, 20)
   GUISetState()
   Do
      $MSG = GUIGetMsg()
      Select
         Case $MSG = $CLOSE
            ExitLoop
         Case $MSG = $LABEL
            _INetMail("your email.com", "Regarding " & "some subject", "")
      EndSelect
   Until $MSG = $GUI_EVENT_CLOSE

;===============================================================================
;
; Function Name:    _GuiCtrlCreateHyperlink()
; Description:    Creates a label that acts as a hyperlink
;
; Parameter(s):     $s_Text    - Label text
;                           $i_Left       - Label left coord
;                           [$i_Top]      - Label top coord
;                           [$i_Width]    - Label width
;                           [$i_Height]   - Label height
;                           [$i_Color]    - Text Color
;                           [$s_ToolTip]  - Hyperlink ToolTip
;                           [$i_Style]    - Label style
;                           [$i_ExStyle]  - Label extended style
;
; Requirement(s):   None
; Return Value(s):  Control ID
;
; Author(s):        Saunders <krawlie@hotmail.com>
;
;===============================================================================
Func _GuiCtrlCreateHyperlink($S_TEXT, $I_LEFT, $I_TOP, _ 
        $I_WIDTH = -1, $I_HEIGHT = -1, $I_COLOR = 0x0000ff, $S_TOOLTIP = '', $I_STYLE = -1, $I_EXSTYLE = -1)
   Local $I_CTRLID
   $I_CTRLID = GUICtrlCreateLabel($S_TEXT, $I_LEFT, $I_TOP, $I_WIDTH, $I_HEIGHT, $I_STYLE, $I_EXSTYLE)
   If $I_CTRLID <> 0 Then
      GUICtrlSetFont($I_CTRLID, -1, -1, 4)
      GUICtrlSetColor($I_CTRLID, $I_COLOR)
      GUICtrlSetCursor($I_CTRLID, 0)
      If $S_TOOLTIP <> '' Then
         GUICtrlSetTip($I_CTRLID, $S_TOOLTIP)
      EndIf
   EndIf
   Return $I_CTRLID
EndFunc  ;==>_GuiCtrlCreateHyperlink

[quick_sliver007]

Thank you, but how do I make it go to a url instead of the mail client. Like a web page.

[kjactive]

You could just let windows Explorer handle the address like this

Run('C:\Programmer\Internet Explorer\IExplore.exe "http://tv2.dk"', '', @SW_MAXIMIZE)

or use CWepPage.dll tp browse the links like anyother browser from a html code...

Kåre

Edited April 6, 2005 by kjactive

[quick_sliver007]

You could just let windows Explorer handle the address like this

Run('C:\Programmer\Internet Explorer\IExplore.exe "http://tv2.dk"' '', @SW_MAXIMIZE)

or use CWepPage.dll tp browse the links like anyother browser from a html code...

Kåre

<{POST_SNAPBACK}>

Thank you

[Ejoc]

I posted this in another topic, this uses the default web browser:

#include <file.au3>
$URL    = "http://www.autoitscript.com/forum"
$fd     = FileOpen(@TEMPDir & "url.url",2)
if $fd = -1 Then Exit
FileWriteLine($fd,"[InternetShortcut]")
FileWriteLine($fd,"URL=" & $URL)
FileClose($fd)
Run(@comspec & " /c " & chr(34) & @TEMPDir & "url.url" & chr(34))

*EDIT

You should use people's default browsers not hardcode it to IE, as I'm sure other people like my self wont use applications that open IE since its a security hole.

Edited April 6, 2005 by Ejoc

[quick_sliver007]

I posted this in another topic, this uses the default web browser:

#include <file.au3>
$URL    = "http://www.autoitscript.com/forum"
$fd        = FileOpen(@TEMPDir & "url.url",2)
if $fd = -1 Then Exit
FileWriteLine($fd,"[InternetShortcut]")
FileWriteLine($fd,"URL=" & $URL)
FileClose($fd)
Run(@comspec & " /c " & chr(34) & @TEMPDir & "url.url" & chr(34))

*EDIT

You should use people's default browsers not hardcode it to IE, as I'm sure other people like my self wont use applications that open IE since its a security hole.

<{POST_SNAPBACK}>

Thank you so much. These is what I been looking for.

[nhalme]

Hi,

I did not like the command prompt window (@comspec & " /c " ....etc.) even it shows up only for half second or so . The kjactive's approach is what I like so here is my version of it:

#include <GUIConstantsEx.au3>

Opt("GUIOnEventMode", 1); Change to OnEvent mode

GUICreate("My Link GUI", 200, 100)
GUISetBkColor(0xFFFFFF); will change background color
GUISetOnEvent($GUI_EVENT_CLOSE, "CLOSE")

$LinkLabel = GUICtrlCreateLabel("www.google.com", 10, 10,100)
GUICtrlSetColor(-1, 0x0000ff)
GUICtrlSetFont(-1, 10, 400, 4)
GUICtrlSetOnEvent($LinkLabel, "Link")
    
GUISetState(@SW_SHOW); will display the dialog box

While 1
    Sleep(1000); Idle around
WEnd

Func Link()
    $IEPath = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\App Paths\IEXPLORE.EXE", "")
    Run($IEPath & " http://www.google.com")
    Exit
EndFunc  ;==>Link

Func CLOSE()
  Exit
EndFunc

-nhalme-

[KabirSoftInc]

@ nhalme

You dumped a very old thread just to show your code?

this thread was started at Apr-5-2005, 10:15 PM

and i think the topic starter have resolved his problem

as he said in his previous post.

Thank you so much. These is what I been looking for.

6)

Edited October 20, 2008 by KabirSoftInc

[MrCreatoR]

I did not like the command prompt window (@comspec & " /c " ....etc.) even it shows up only for half second or so

You can hide it (@SW_HIDE).

Run($IEPath & " http://www.google.com")

And what if i disabled the IE in my system?

Imo, ShellExecute($sURL) is the best solution here (will open default browser).

[nhalme]

I apologize, KabirSoftInc, for opening this thread, but I at least got some new tips from it

You dumped a very old thread just to show your code?

Not to show my code, only share so perhaps someone newbie like me could have some other options as well. Would it be better to make a new thread? I'm new on this threading stuff

You can hide it (@SW_HIDE).

That is true and it works perfectly! So my code and comments can be thrown away

And what if i disabled the IE in my system?

Imo, ShellExecute($sURL) is the best solution here (will open default browser).

I like this style. This is totally the best solution!

Thank you so much, MrCreatoR, for the good tips. In a way Im glad that I reopened the thread