StdoutRead to Array?

[jfitty]

Hi all,

Is it possible to run a command using StdoutRead to capture the output, then insert that straight into an array? I know I could send the output of the command to a text file and use _FileReadToArray, but I would rather the output go straight to an array

Thanks in advance

[Mat]

What character do you want to split the array on? new line?

$sText = StdoutRead (...)
$aArray = StringSplit ($sText, @CRLF)

Thats a simple way to do it.

Mat

[Codeflakes]

What character do you want to split the array on? new line?

$sText = StdoutRead (...)
$aArray = StringSplit ($sText, @CRLF)

Thats a simple way to do it.

Mat

Only issue is with non-standard characters - any simple fix for this? (I take it that we're talking an ANSI/UNICODE issue?)

#include <Array.au3>
#include <Constants.au3>
Local $result
DirCreate(@DesktopDir & "\Test\Torré")
$pid = Run(@ComSpec & " /c dir /B ", @DesktopDir & "\Test", @SW_HIDE, $STDERR_CHILD + $STDOUT_CHILD)
While 1
    $result &= StdoutRead($pid)
    If @error Then ExitLoop
Wend
$array = StringSplit($result, @CRLF, 1)
_ArrayDisplay($array)

[GEOSoft]

$aArray = _Array_CreateFromString(StdOutRead($Run))
If NOT @Error Then
    ;;Do whatever with the array
EndIf

Func _Array_CreateFromString($sStr)
   If FileExists($sStr) Then $sStr = FileRead($sStr)
   If NOT $sStr Then Return SetError(1);; Empty strings not allowed
   Local $aRtn = StringRegExp($sStr, "(?i)(?m:^)(.*)(?:\v|$)", 3)
   If @Error Then Return SetError(2) ;; RegExp failed
   Return $aRtn
EndFunc    ;<===> _Array_CreateFromString()

[cherdeg]

Just do it like the pros do

Only issue is with non-standard characters - any simple fix for this?

Yep:

#include <Array.au3>
#include <Constants.au3>

Local $result

DirCreate(@DesktopDir & "\Test\Torré")
$pid = Run(@ComSpec & " /c dir /B ", @DesktopDir & "\Test", @SW_HIDE, $STDERR_CHILD + $STDOUT_CHILD)
While 1
    $result &= StdoutRead($pid)
    If @error Then ExitLoop
Wend

$array = StringSplit(StringStripWS($result, 8), @CRLF, 1)
MsgBox("", "String", "Before conversion: " & @CRLF & @CRLF & $array[1])
$output_comspec_oem2ansi = _OEM2ANSI($array[1])
MsgBox("", "String", "After conversion: " & @CRLF & @CRLF & $output_comspec_oem2ansi)


Func _OEM2ANSI($what)
    $ret = DllCall('user32.dll', 'Int', 'OemToChar', 'str', $what, 'str', '')
    Return $ret[2]
EndFunc   ;==>_OEM2ANSI

Edited November 4, 2009 by cherdeg

[Codeflakes]

Just do it like the pros do

Yep:

#include <Array.au3>
#include <Constants.au3>

Local $result

DirCreate(@DesktopDir & "\Test\Torré")
$pid = Run(@ComSpec & " /c dir /B ", @DesktopDir & "\Test", @SW_HIDE, $STDERR_CHILD + $STDOUT_CHILD)
While 1
    $result &= StdoutRead($pid)
    If @error Then ExitLoop
Wend

$array = StringSplit(StringStripWS($result, 8), @CRLF, 1)
MsgBox("", "String", "Before conversion: " & @CRLF & @CRLF & $array[1])
$output_comspec_oem2ansi = _OEM2ANSI($array[1])
MsgBox("", "String", "After conversion: " & @CRLF & @CRLF & $output_comspec_oem2ansi)


Func _OEM2ANSI($what)
    $ret = DllCall('user32.dll', 'Int', 'OemToChar', 'str', $what, 'str', '')
    Return $ret[2]
EndFunc   ;==>_OEM2ANSI

Hey Cherdeg,

Kool - works great thanks

Codeflakes

[cherdeg]

Kool - works great thanks

You're welcome!

If I can help, which happens not to often, I do.