GUI Tab Order/Index

[rotamo]

There's probably a real easy answer to this, but I can't seem to find it in the forums or help pages. I'm looking for a way to specify the tab order for for my GUI control inputs. Similar to setting the tab index in VB. Essentially, I've got several input boxes for entry followed by several sets of radio buttons, followed by a few more input boxes. When tabbing from input to input, the radios take stops as well but I want to skip past them when tabbing to the next set of inputs. Thank you in advance for any help on this.

[Authenticity]

You can design your form using Koda Form Designer (ALT+M from SciTE) and then set each control's tab index by right clicking the Object TreeView pane and selecting Tab Order (or pressing CTRL+T) and move the control up/downward. When you save the form and choose generate form code (F9) you'll get the correct order. If you'll look what the generated code is you'll see it's just replacing the call order but the coordinates remain the same. For example:

$Button2 = GUICtrlCreateButton("Button2", 112, 152, 97, 57, 0)
$Button3 = GUICtrlCreateButton("Button3", 304, 256, 65, 81, 0)
$Button1 = GUICtrlCreateButton("Button1", 96, 56, 49, 49, 0)

Edited October 28, 2009 by Authenticity

[rotamo]

Thought there might be an easy answer. Thank you very much - what a novel concept to change the call order. Duh!

[Melba23]

rotamo,

If you want to get some specific controls out of the TAB cycle, just run this small function after the control is created:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>
#include <WinAPI.au3>

$hGUI = GUICreate("Test", 500, 500)

$hButton1 = GUICtrlCreateButton("1", 10, 10, 80, 30)
$hButton2 = GUICtrlCreateButton("2", 10, 50, 80, 30)
$hButton3 = GUICtrlCreateButton("3", 10, 90, 80, 30)
_No_TabStop($hButton2)

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

; Credit picea892
Func _No_TabStop($hWnd)
    _WinAPI_SetWindowLong(GUICtrlGetHandle($hWnd), $GWL_STYLE, _
    BitAND(_WinAPI_GetWindowLong(GUICtrlGetHandle($hWnd), $GWL_STYLE), BitNOT($WS_TABSTOP)))
EndFunc

If you want to get a specific TAB order, but do not want to use Koda, just create the controls in your script in the order you require - I have found this works without problem.

M23

[rotamo]

Excellent - thank you both very much. This is just what I was looking for - much appreciated!