RegExp Hmm Question

[czardas]

I have looked at the help file several times and tried to find something on the forum, but I decided it would be quicker to ask.

I have never used regular expressions and I think it's just what I need. I wish to test if a string qualifies as a word. Why not use StringIsAlpha you might ask? Well that doesn't help with hyphenated words, nor does it help to test for apostrophes. The expression would have to indicate that either a hyphen or an apostrophe was found somewhere within a non-case sensitive alphabetical string. So where's my code? Well hmm? I haven't got a clue where to begin.

Could someone please give me an example of this.

$returnValue = "God only knows?"

Dim $array[10]
$array[0] = 9
$array[1] = "ab-c" ; Should return TRUE because 1 hyphen appears between sets of letters.
$array[2] = "ab'c" ; Should return TRUE because 1 apostrophe  appears between sets of letters.
$array[3] = "-abc" ; Should return FALSE because the hyphen appears first.
$array[4] = "a-b-c" ; Should return FALSE because the hyphen repeats.
$array[5] = "abc-" ; Should return FALSE because the hyphen appears at the end.
$array[6] = "'abc" ; Should return FALSE because the apostrophe appears first.
$array[7] = "abc'" ; Should return FALSE because the apostrophe appears last.
$array[8] = "a''bc" ; Should return FALSE because the apostrophe repeats.
$array[9] = "a-b'c" ; Should return FALSE because it contains both apostrophe and hyphen.

For $i = 1 To $array[0] Step 1
  ;now comes a regular expression testing if each element qualifies as a word.
  MsgBox(0, "Test Result", "I know that this is or isn't a word because of some return value" & @CRLF & $returnValue)
Next

I hope this isn't asking too much. It will save me having to write a lot of unecessary code. Thanks in advance!

Edited November 16, 2009 by czardas

[GEOSoft]

Just winging it here but the first that pops to mind is

(?i)[a-z]+[\-']?[a-z]+

So we have

For $i = 1 To $array[0]
  ;now comes a regular expression testing if each element qualifies as a word.
  MsgBox(0, "Test Result", StringRegExp($array[$i], "(?i)[a-z]+[\-']?[a-z]+"))
Next

[czardas]

Just winging it here but the first that pops to mind is

(?i)[a-z]+[\-']?[a-z]+

So we have

For $i = 1 To $array[0]
  ;now comes a regular expression testing if each element qualifies as a word.
  MsgBox(0, "Test Result", StringRegExp($array[$i], "(?i)[a-z]+[\-']?[a-z]+"))
Next

Thanks! That gives me something to chew on.

Hmm. It seems that I get a return value of 1 for all tests. That's not really working, though I appreciate it. Perhaps I can figure out why it's not working.

Edited November 16, 2009 by czardas

[GEOSoft]

Thanks! That gives me something to chew on.

Hmm. It seems that I get a return value of 1 for all tests. That's not really working, though I appreciate it. Perhaps I can figure out why it's not working.

Well like I said, I was winging it because I'm on the laptop with no developer software installed so lets break it down

(?i)[a-z]+[\-']?[a-z]+

(?i) - case insensitive

[a-z]+ - match alpha characters one or more times

[\-']? match hypen or comma once if it exists

[a-z]+ - match alpha characters one or more times

Now lets look at what I did wrong. I forgot to tell it to match from the beginning to the end of the string.

(?i)^[a-z]+[\-']?[a-z]+$

I've added ^ to match at the beginning of the string and $ to match at te end of the strig so it must start and end with an alpha.

Edit: Something else just occured to me.

Try changing the MsgBox line to This

For $i = 1 To $array[0]
  ;now comes a regular expression testing if each element qualifies as a word.
    If StringRegExp($array[$i], "(?i)^[a-z]+[\-']?[a-z]+$") Then
         MsgBox(0, "Test Result", "True")
    Else
        MsgBox(0, "Test Result", "False")
    EndIf
Next

EDIT 2

Again I forgot to test from beginning to end. This time in the If statement

Edited November 16, 2009 by GEOSoft

[PsaltyDS]

Thanks! That gives me something to chew on.

Hmm. It seems that I get a return value of 1 for all tests. That's not really working, though I appreciate it. Perhaps I can figure out why it's not working.

It returns true because a matching pattern (any two letter with or without the punctuation between them) can be found SOMEWHERE in the string. For example, in "-abc" it can match on "ab" or "bc" or "abc", so it's true. You need to add flags to include the beginning/ending of the string.

Oops. GEOSoft been there, done that already!

Edited November 16, 2009 by PsaltyDS

[czardas]

Yep, That's done it. I have to say thanks. This is a great introduction to the topic of regular expressions. I appreciate all the comments and I now understand more or less what's going on through this. GREAT