Update status checkmark

[Willow]

I am looking for a way to display an update status similar to the below in a GUI.

Once a step has been completed, a checkmark will be displayed to the left of the step completed.

√ File xx backed up

√ File xx copied

√ Registry updated

Service xx updated

Service xx restarted

etc....

I have already searched the help files and forums already, however I could not find a workable method to accomplish this. If someone can point me in the right direction, it will be appreciated.

Thanks

Willow

[mikjay]

What about using GUICtrlSetState ( controlID, state ), with the handle of the previously created checkbox and $GUI_CHECKED as the state if error level is 0?

[Melba23]

Willow,

Unless you disable it, a checkbox is not really suitable because the user can action it - which rather defeats the object of the exercise.

Here is a script which draws TickBoxes. At the moment it will tick the box when you click on the button, but it would be easy to amend so that you draw the "tick" when your script requires it:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#Include <WinAPI.au3>

Global $iBorder = _WinAPI_GetSystemMetrics($SM_CXDLGFRAME)
Global $iCaption = _WinAPI_GetSystemMetrics($SM_CYCAPTION)

Global $iX = 10, $iY = 10, $iSize = 12
Global $iDraw_X = $iX + $iBorder, $iDraw_Y = $iY + $iBorder + $iCaption

$hGUI = GUICreate("TickBox", 350, 300)

$hButton = GUICtrlCreateButton("Tick", 10, 100, 80, 30)

GUISetState(@SW_SHOW)

; Create our TickBox AFTER we have created the GUI

; Draw a "TickBox" box
$hDC = _WinAPI_GetWindowDC($hGUI)
$hPen = _WinAPI_CreatePen($PS_SOLID, 2, 0)
$obj_orig = _WinAPI_SelectObject($hDC, $hPen)
_WinAPI_DrawLine($hDC, $iDraw_X, $iDraw_Y, $iDraw_X + $iSize, $iDraw_Y)
_WinAPI_DrawLine($hDC, $iDraw_X + $iSize, $iDraw_Y, $iDraw_X + $iSize, $iDraw_Y + $iSize)
_WinAPI_DrawLine($hDC, $iDraw_X + $iSize, $iDraw_Y + $iSize, $iDraw_X, $iDraw_Y + $iSize)
_WinAPI_DrawLine($hDC, $iDraw_X, $iDraw_Y + $iSize, $iDraw_X, $iDraw_Y)

; Create the "TickBox" label - leave space for the Box!
GUICtrlCreateLabel("       File xx Backed Up", $iX, $iY, 200, 20)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            _WinAPI_SelectObject($hDC, $obj_orig)
            _WinAPI_DeleteObject($hPen)
            _WinAPI_ReleaseDC(0, $hDC)
            Exit
        Case $hButton
            ; Draw the "tick"
            _WinAPI_DrawLine($hDC, $iDraw_X + 3, $iDraw_Y + 6, $iDraw_X + 6, $iDraw_Y + 9)
            _WinAPI_DrawLine($hDC, $iDraw_X + 6, $iDraw_Y + 9, $iDraw_X + 9, $iDraw_Y + 2)
            _WinAPI_DeleteObject($hPen)
    EndSwitch
WEnd

I hope this helps. Ask if anything is unclear.

M23

[gcue]

neat - didnt know you could do that...

nice one melba

[AndyG]

GUICreate("")

For $i = 1 To 5
 GUICtrlCreateLabel("Program " & $i, 30, 20 + $i * 30, 100, 20)
Next
GUISetState()

For $i = 1 To 5
 Sleep(1000)
 GUICtrlCreateLabel(Chr(214), 10, 20 + $i * 30, 10, 10) ;the "checkmark"
 GUICtrlSetFont(-1, 9, 600, 4, "Symbol")
Next

Do
Until GUIGetMsg() = -3

[Willow]

Thanks everyone, there are couple of real viable options shown that can be considered to suit the requirements I am looking for.

Willow.

Edited December 1, 2009 by Willow

[Melba23]

AndyG,

Why did I not think of that! - [image]Melba23 hitting forehead with palm of hand[/image]

Actually I had just finished creating a transparent checkbox in response to another topic and had the basic code in SciTE already. But I think you have the better solution.

M23

[pGwtech]

Andy G, appreciate the code contribution.