GUICtrlCreateIcon Size

[regi]

Hi,

I'm including an icon in in my build, but when showing it in a gui instead of being 48 x 48, it defaults to 32 x 32, is this a bug? Or am I missing something here?

Demo script and attached icon file below...

#Region
#AutoIt3Wrapper_Res_Icon_Add=I:\numbers.ico
#EndRegion
#include <GUIConstants.au3>
GUICreate(" My GUI Icons")
$icon = GUICtrlCreateIcon (@ScriptFullPath, -5, 20, 20, 48, 48)
GUISetState()
While 1
    $msg = GUIGetMsg()

    If $msg = $GUI_EVENT_CLOSE Then ExitLoop
Wend

This however, works fine:

#include <GUIConstants.au3>
GUICreate(" My GUI Icons")
$icon = GUICtrlCreateIcon ("numbers.ico",-1, 20, 20, 48, 48)
GUISetState()
While 1
    $msg = GUIGetMsg()
    
    If $msg = $GUI_EVENT_CLOSE Then ExitLoop
Wend

Source: http://www.autoitscript.com/forum/index.php?showtopic=14606

numbers.ico

[GEOSoft]

I believe that the next beta versiuon will support larger icons. Until then 32x32 is as large as you can use.

[regi]

Oh, that's a shame. Thanks for the prompt reply though!

[AdmiralAlkex]

Oh, that's a shame. Thanks for the prompt reply though!

An icon bug was fixed in the latest beta, did you try that?

[Yashied]

You can also use Icons.au3. In it, the problem was solved long ago.

Edited December 4, 2009 by Yashied

[regi]

An icon bug was fixed in the latest beta, did you try that?

Just tried 3.3.1.6, same result.

You can also use Icons.au3. In it, the problem was solved long ago.

Thanks, I'll look into it

[Zedna]

AutoIt Changelog

3.3.1.6 (XX November, 2009) (Beta)

AutoIt:

- Added #1270: GuiSetIcon() now finds suitable large and small icons.

Here is link to its Bug trac ticket

http://www.autoitscript.com/trac/autoit/ticket/1270#comment:5

Edited December 4, 2009 by Zedna

[trancexx]

GUICtrlCreateIcon() is one function and GuiSetIcon() is another.

regi is asking about former.

[FuryCell]

I am having the same problem with the newest version of Au3. When using the included icon I only get 32x32 however if the icon is out of the exe then it gets 48x48 fine. Have we had a regression in the latest version?

Included Icon

External Icon

Edited January 29, 2010 by P5ych0Gigabyte

[trancexx]

I am having the same problem with the newest version of Au3. When using the included icon I only get 32x32 however if the icon is out of the exe then it gets 48x48 fine. Have we had a regression in the latest version?

Included Icon

External Icon

Regression would imply some sort of previously done progression.

[FuryCell]

Regression would imply some sort of previously done progression.

After looking at the exe in reshacker I can see that the icons included are 48x48 and did not get scaled down. So I am pretty sure this is a bug. I am going to file a report on trac. Submitted:Trac

Edited January 29, 2010 by P5ych0Gigabyte

[trancexx]

After looking at the exe in reshacker I can see that the icons included are 48x48 and did not get scaled down. So I am pretty sure this is a bug. I am going to file a report on trac. Submitted:Trac

I just said that there has been no regression since there was no progression.

When specifying icon file as icon to use there are two modes that AutoIt works in. First one is (will split in two sub modes):

GUICtrlSetImage($ButtonTest, ".\Icon.ico", 0, 0) ; get small icon (16x16)

GUICtrlSetImage($ButtonTest, ".\Icon.ico", 0, 1) ; get normal icon (32x32)

The other is:

GUICtrlSetImage($ButtonTest, ".\Icon.ico") ; get first icon found in icon file

First mode uses ExtractIconExW to get icons and other LoadImageW.

When doing the same thing but now specifying resource as icon to use, there is only one mode. The first one; ExtractIconExW. Third case would be just repeating second one.

Why is this so I have no idea. Actually I don't know why is ExtractIconExW used at all. Probably some smart reason though. Maybe for simplicity (small/normal).

Edited January 29, 2010 by trancexx

[picea892]

Anyways...getting back to the question...Here is a way.

expandcollapse popup

#include <GUIConstantsEx.au3>
#Include <Constants.au3>
#include <GDIPlus.au3>
#include <WinAPI.au3>
    $Gui = GUICreate("",200,200,-1,-1)
    $gradie = GUICtrlCreatePic("", 0, 0,48, 48)
    iconbutton_1(-1, "numbers.ico", -1)

GUISetState()

While 1
sleep(20)
$msg=GUIGetMsg()
if $msg=$GUI_EVENT_CLOSE then Exit
WEnd

Func iconbutton_1($control, $sIcon = "", $iIndex = "", $size=32)
    If Not $sIcon = "" Then
        _GDIPlus_Startup()
        $hwd = GUICtrlGetHandle($control)
        $width = _WinAPI_GetClientWidth($hwd)
        $height = _WinAPI_GetClientHeight($hwd)
        $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hwd)
        $hBitmap1 = _GDIPlus_BitmapCreateFromGraphics($width, $height, $hGraphic)
        $hBitmap1 = _drawicon($hBitmap1, $width, $height, $sIcon, $iIndex,0,0)
        $hImage1 = _GDIPlus_ImageGetGraphicsContext($hBitmap1)
        $hBMP1 = _GDIPlus_BitmapCreateHBITMAPFromBitmap($hBitmap1)
        _WinAPI_DeleteObject(GUICtrlSendMsg($control, 0x0172, 0, $hBMP1))
        _GDIPlus_GraphicsDispose($hImage1)
        _WinAPI_DeleteObject($hBMP1)
        _GDIPlus_BitmapDispose($hBitmap1)
        _GDIPlus_GraphicsDispose($hGraphic)
        _GDIPlus_Shutdown()
    EndIf
EndFunc ;==>iconbutton_1

Func _drawicon($bitmap, $width, $height, $ico, $ind,$hpos,$hvpos)
    $hbmp = _GDIPlus_BitmapCreateHBITMAPFromBitmap($bitmap)
    $hIcon = _WinAPI_SHExtractIcons($ico, $ind, 48, 48)
    $hDC = _WinAPI_GetDC(0)
    $hBackDC = _WinAPI_CreateCompatibleDC($hDC)
    $hBackSv = _WinAPI_SelectObject($hBackDC, $hbmp)
    If $hIcon <> 0 Then _WinAPI_DrawIconEx($hBackDC,$hpos, $hvpos, $hIcon, 0, 0, 0, 0, $DI_NORMAL)
    $bitmap = _GDIPlus_BitmapCreateFromHBITMAP($hbmp)
    _WinAPI_DeleteObject($hbmp)
    _WinAPI_SelectObject($hBackDC, $hBackSv)
    _WinAPI_DeleteDC($hBackDC)
    _WinAPI_ReleaseDC(0, $hDC)
    _WinAPI_DestroyIcon($hIcon)
    Return $bitmap
    Return
EndFunc ;==>_drawicon

Func _WinAPI_SHExtractIcons($sIcon, $iIndex, $iWidth, $iHeight)
    Local $Ret = DllCall('shell32.dll', 'int', 'SHExtractIconsW', 'wstr', $sIcon, 'int', $iIndex, 'int', $iWidth, 'int', $iHeight, 'ptr*', 0, 'ptr*', 0, 'int', 1, 'int', 0)
    If (@error) Or ($Ret[0] = 0) Or ($Ret[5] = Ptr(0)) Then
        Return SetError(1, 0, 0)
    EndIf
    Return $Ret[5]
EndFunc ;==>_WinAPI_SHExtractIcons

[FuryCell]

Anyways...getting back to the question...Here is a way.

Thanks for the workaround. I'm gonna give that a try and see how it turns out. The thing is its for a gpl project. Are you OK with me using that code?

[picea892]

of course....

[FuryCell]

of course....

So how would I get this to draw on a button. Something like the following.

expandcollapse popup

#include <GUIConstantsEx.au3>
#Include <Constants.au3>
#include <GDIPlus.au3>
#include <WinAPI.au3>

    $Gui = GUICreate("",200,200,-1,-1)
    $gradie = GUICtrlCreateButton("", 0, 0,48, 48)
    iconbutton_1(-1, "go.ico", -1)

GUISetState()

While 1
sleep(20)
$msg=GUIGetMsg()
if $msg=$GUI_EVENT_CLOSE then Exit
WEnd

Func iconbutton_1($control, $sIcon = "", $iIndex = "", $size=32)
    If Not $sIcon = "" Then
        _GDIPlus_Startup()
        $hwd = GUICtrlGetHandle($control)
        $width = _WinAPI_GetClientWidth($hwd)
        $height = _WinAPI_GetClientHeight($hwd)
        $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hwd)
        $hBitmap1 = _GDIPlus_BitmapCreateFromGraphics($width, $height, $hGraphic)
        $hBitmap1 = _drawicon($hBitmap1, $width, $height, $sIcon, $iIndex,0,0)
        $hImage1 = _GDIPlus_ImageGetGraphicsContext($hBitmap1)
        $hBMP1 = _GDIPlus_BitmapCreateHBITMAPFromBitmap($hBitmap1)
        _WinAPI_DeleteObject(GUICtrlSendMsg($control, 0x0172, 0, $hBMP1))
        _GDIPlus_GraphicsDispose($hImage1)
        _WinAPI_DeleteObject($hBMP1)
        _GDIPlus_BitmapDispose($hBitmap1)
        _GDIPlus_GraphicsDispose($hGraphic)
        _GDIPlus_Shutdown()
    EndIf
EndFunc ;==>iconbutton_1

Func _drawicon($bitmap, $width, $height, $ico, $ind,$hpos,$hvpos)
    $hbmp = _GDIPlus_BitmapCreateHBITMAPFromBitmap($bitmap)
    $hIcon = _WinAPI_SHExtractIcons($ico, $ind, 48, 48)
    $hDC = _WinAPI_GetDC(0)
    $hBackDC = _WinAPI_CreateCompatibleDC($hDC)
    $hBackSv = _WinAPI_SelectObject($hBackDC, $hbmp)
    If $hIcon <> 0 Then _WinAPI_DrawIconEx($hBackDC,$hpos, $hvpos, $hIcon, 0, 0, 0, 0, $DI_NORMAL)
    $bitmap = _GDIPlus_BitmapCreateFromHBITMAP($hbmp)
    _WinAPI_DeleteObject($hbmp)
    _WinAPI_SelectObject($hBackDC, $hBackSv)
    _WinAPI_DeleteDC($hBackDC)
    _WinAPI_ReleaseDC(0, $hDC)
    _WinAPI_DestroyIcon($hIcon)
    Return $bitmap
    Return
EndFunc ;==>_drawicon

Func _WinAPI_SHExtractIcons($sIcon, $iIndex, $iWidth, $iHeight)
    Local $Ret = DllCall('shell32.dll', 'int', 'SHExtractIconsW', 'wstr', $sIcon, 'int', $iIndex, 'int', $iWidth, 'int', $iHeight, 'ptr*', 0, 'ptr*', 0, 'int', 1, 'int', 0)
    If (@error) Or ($Ret[0] = 0) Or ($Ret[5] = Ptr(0)) Then
        Return SetError(1, 0, 0)
    EndIf
    Return $Ret[5]
EndFunc ;==>_WinAPI_SHExtractIcons

Edited January 30, 2010 by P5ych0Gigabyte

[picea892]

Okay...different example

#include <GDIPlus.au3>
#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#include <WINAPI.au3>
_GDIPlus_Startup()
Global $Image1 = _GDIPlus_ImageLoadFromFile("sb.png")
   $width=_GDIPlus_ImageGetWidth($Image1)
   $height=_GDIPlus_ImageGetHeight($Image1)
Global Const $AC_SRC_ALPHA = 1
$GUI = GUICreate("Example",$width,$height,-1,-1,$WS_POPUP)
$pic=GUICtrlCreateButton("",0,0,$width,$height)
GUISetState()
Global $Graphic = _GDIPlus_GraphicsCreateFromHWND(GUICtrlGetHandle($pic))
_GDIPlus_GraphicsDrawImageRect($Graphic, $Image1,0,0,$width,$height)
    
While 1
    $MSG = GUIGetMsg()
    Switch $MSG
        Case -3
            Quit()
    EndSwitch
WEnd

Func Quit()
    _GDIPlus_ImageDispose($Image1)
    _GDIPlus_GraphicsDispose($Graphic)
    _GDIPlus_Shutdown()
    Exit
EndFunc