Refresh gui after opening files

[peanutym]

So i have a gui setup. On the tab there is a section to open a file. Once that file is opened i would like a spot on the GUI that shows the open file name.

Func loadwp()
    $openwpfile = FileOpenDialog("Please select a Waypoint File", "", "Text File (*.txt)", 1)
    
    ;Did they chose anything or cancel?
    If @error Then
        MsgBox(0, "No File Chosen", "No File chosen")
    EndIf

    GUICtrlCreateLabel($openwpfile, 90,235,200,20, $SS_Center)


EndFunc

This works perfectly fine. My problem is that i have to switch tabs then switch back before it shows up. Right now above happens after i open a file. So i have a button that calls this function you select the file then i want it to say that file on the GUI.

Also how would i trim the variable when it shows it to only show the file name instead of the whole location string? IE: c/test/test.txt it would only show test.txt

Thanks in advance.

[GEOSoft]

Don't put GUICtrlCreateLabel($openwpfile, 90,235,200,20, $SS_Center) inside the function.

Instead place the control inside the rest of your GUI creation code as

$Lbl_Path = GUICtrlCreateLabel("", 90,235,200,20, $SS_Center)

Then change your function to

Func loadwp()
    $openwpfile = FileOpenDialog("Please select a Waypoint File", "", "Text File (*.txt)", 1)
    
    ;Did they chose anything or cancel?
    If @error Then
        MsgBox(0, "No File Chosen", "No File chosen")
    Else
        GUICtrlSetData($Lbl_Path, $openwpfile)
    EndIf

    ;GUICtrlCreateLabel($openwpfile, 90,235,200,20, $SS_Center)


EndFunc

[Melba23]

peanutym,

Create your label with your tab and then just update the content with the file name. Use a simple SRE to get the file name from the full path:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>

$hGUI = GUICreate("Test", 500, 500)

$tab = GUICtrlCreateTab(10, 10, 400, 400)

    $tab0 = GUICtrlCreateTabItem("tab 0")

    $hButton = GUICtrlCreateButton("Select", 20, 50, 80, 30)
    ; Create label here
    $hLabel = GUICtrlCreateLabel("", 20, 100, 200, 40, $SS_Center)

    $tab1 = GUICtrlCreateTabItem("tab 1")

GUICtrlCreateTabItem("")    ; end tabitem definition

GUISetState()

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $hButton
            loadwp()
    EndSwitch

WEnd

Func loadwp()

    $openwpfile = FileOpenDialog("Please select a Waypoint File", "", "Text File (*.txt)", 1)

    ;Did they chose anything or cancel?
    If @error Then
        MsgBox(0, "No File Chosen", "No File chosen")
    EndIf
    ;Update label contents here
    GUICtrlSetData($hLabel, StringRegExpReplace($openwpfile, "^.*\\", ""))

EndFunc

M23

Edit: Great minds eh, George?

Edited December 6, 2009 by Melba23

[peanutym]

ahh ok using setdata command instead.

Also thanks for the code to shorten the path mel.

thanks to you both!

[Fire]

2 hours i search about analog problem in my app and i found it here.

Thank guys for great support in this forum