StringsInStr

[Mat]

A simple function that returns all the offsets of $sFind within $sString. It returns an array where the 0th element is the return count.

Func _StringsInStr ($sString, $sFind, $iCase = 0)
    Local $n, $sRet = "", $sRepl = StringRegExpReplace ($sFind, ".", Chr (0))
    While 1
        $n = StringInStr ($sString, $sFind, $iCase)
        If Not $n Then ExitLoop
        $sRet &= $n & "|"
        $sString = StringReplace ($sString, $sFind, $sRepl, 1, $iCase)
    WEnd
    Return StringSplit (StringTrimRight ($sRet, 1), "|")
EndFunc ; ==> _StringsInStr

example:

#Include <Array.au3>

$sString = "this is a string containg this word: ""this""."
$sFind = "this"

$aRet = _StringsInStr ($sString, $sFind)

_ArrayDisplay ($aRet)

Mat

[MrCreatoR]

Good idea, but i would do it like this:

Func _StringsInStr($sString, $sFind, $iCase = 0)
    StringReplace($sString, $sFind, "")
    Local $aRet[@extended+1] = [@extended]
    
    For $i = 1 To $aRet[0]
        $aRet[$i] = StringInStr($sString, $sFind, $iCase, $i)
    Next
    
    If $aRet[0] = 0 Then SetError(1)
    Return $aRet
EndFunc ; ==> _StringsInStr

[Mat]

Do you always have to make it better?

Thats a lot better and easier to understand thank you!

Mat