Getting a link into a popup type window

[JohnOne]

I've been working on this project to get alerted on my desktop when a new news item is posted on verious websites.

Its all fine and works ok except I'd like the notification popup to contain a link in the text.

Seems tooltips and traytips wont accept them, and also splashtext dosent seem to.

Can anyone suggest something that will ?

[Authenticity]

GUI Hyperlink control by GaryFrost.

[bogQ]

GUI Hyperlink control by GaryFrost.

The GUI Hyperlink control is out of date or im using the old autoit version

i used something like this in the past

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
$hGui = GUICreate("Link", 400, 130,"","",$WS_POPUP)
$xy = WinGetPos($hGui)
WinMove($hGui,"",(@DesktopWidth/2)-($xy[2]/2),(@DesktopHeight/2)-($xy[3]/2))
$Label1 = GUICtrlCreateLabel("",10,10,150,20)
GUICtrlSetColor(-1, 0x2200CC)
GUICtrlSetFont($Label1, 8.5)
GUICtrlSetData ($Label1,"www.google.com")
GUISetState()
$pos = ControlGetPos($hGui,"","[CLASS:Static]")
$ld = 0
While 1
    $a = GUIGetCursorInfo ( $hGui )
    $msg = GUIGetMsg()
    Select
        Case  $msg = $GUI_EVENT_CLOSE 
            Exit
        Case $msg = $Label1
            ShellExecute(GUICtrlRead($Label1))
    EndSelect
    If $pos[0] < $a[0] And $pos[2] > $a[0] And  $pos[1] < $a[1] And $pos[3] > $a[1] Then
        If $ld = 1 Then
            GUICtrlSetFont($Label1, 8.5, 400, 4)
            GUICtrlSetData ($Label1,"www.google.com")
            $ld = 0
        EndIf
    Else
        If $ld = 0 Then
            GUICtrlSetFont($Label1, 8.5)
            GUICtrlSetData ($Label1,"www.google.com")
            $ld = 1
        EndIf
    EndIf
WEnd

Well at least i know now that someone already made func for this and i know where to look next time when i need it even if it eventually need some reediting or mu update on autoit to work, ty Authenticity for the link

Edited December 20, 2009 by bogQ

[smashly]

Hi,

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <StaticConstants.au3>

Global $hGui, $Label1, $msg, $aGGCI, $Last = 0

$hGui = GUICreate("", 160, 60, -1, -1, $WS_POPUP)
GUISetBkColor(0xEEEE00)
$Label1 = GUICtrlCreateLabel("www.google.com", 20, 20, 120, 20, $SS_CENTER)
GUICtrlSetColor(-1, 0x2200CC)
GUICtrlSetFont(-1, 8.5)
GUISetState(@SW_SHOW, $hGui)

While 1
    $msg = GUIGetMsg()
    Switch $msg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Label1
            ShellExecute(GUICtrlRead($Label1))
        Case Else
            $aGGCI = GUIGetCursorInfo($hGui)
            If $aGGCI[4] = $Label1 And $Last <> $Label1 Then
                GUICtrlSetFont($Label1, 8.5, 700, 6)
                $Last = $Label1
            ElseIf $aGGCI[4] <> $Label1 And $Last = $Label1 Then
                $Last = 0
                GUICtrlSetFont($Label1, 8.5)
            EndIf
    EndSwitch
WEnd

Cheers

[bogQ]

Hi,

Cheers

nice catch on [4] never seen thatone until now, i will be sure to remember that one for the next time when i use GUIGetCursorInfo()

[JohnOne]

GUI Hyperlink control by GaryFrost.

Thank you.