Tab background color

[ranhalt]

I've got my tabbed environment working, but I don't like the white background, since I'm using bottom tabs and it looks weird. GUISetBkColor will change the background color of my GUI, but not the tab area. Any function to change it to anything else, like the standard grey?

[Yashied]

One of the ways...

#Include <WinAPIEx.au3>

Opt('MustDeclareVars', 1)

Global $hForm, $Theme = _WinAPI_GetThemeAppProperties()

$hForm = GUICreate('MyGUI', 310, 360)
GUISetFont(8.5, 400, 0, 'MS Shell Dlg', $hForm)
GUICtrlCreateGroup('Group', 10, 10, 140, 95)
GUICtrlCreateCheckbox('Check1', 22, 26, 120, 23)
GUICtrlCreateCheckbox('Check2', 22, 49, 120, 23)
GUICtrlCreateCheckbox('Check3', 22, 72, 120, 23)
GUICtrlCreateGroup('Group', 160, 10, 140, 95)
GUICtrlCreateRadio('Radio1', 172, 26, 120, 23)
GUICtrlCreateRadio('Radio2', 172, 49, 120, 23)
GUICtrlCreateRadio('Radio3', 172, 72, 120, 23)
GUICtrlCreateButton('OK', 120, 330, 70, 23)
_WinAPI_SetThemeAppProperties($STAP_ALLOW_NONCLIENT)
GUICtrlCreateTab(10, 118, 292, 206)
GUICtrlCreateTabItem('Tab1')
GUICtrlCreateTabItem('Tab2')
GUICtrlCreateTabItem('')
_WinAPI_SetThemeAppProperties($Theme)

GUISetState()

Do
Until GUIGetMsg() = -3

WinAPIEx.au3

[MadMaxx]

I have an additional question.

I have 3 tabs which I would like to make 3 different colours. Is this possible?

M

[Authenticity]

I believe that you can subclass the tab controls and handle their WM_ERASEBKGND event to draw the back ground. Another possibility is to use owner-drawn tab control. You can also use this -inefficient hack- trick:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>
Opt('MustDeclareVars', 1)

Local Const $FLOODFILLBORDER  = 0
Local Const $FLOODFILLSURFACE = 1

Local $hGUI, $hDC, $Tab, $hTab, $Tab1, $Tab2, $Tab3

GUIRegisterMsg($WM_PAINT, "_WM_PAINT")

$hGUI = GUICreate("Test", 300, 300)
$Tab = GUICtrlCreateTab(0, 0, 300, 300)
$hTab = GUICtrlGetHandle($Tab)
$hDC = _WinAPI_GetDC($hTab)

$Tab1 = GUICtrlCreateTabItem("Tab 1")
GUICtrlCreateEdit("", 10, 30, 280, 220)
GUICtrlCreateButton("Button 1", 115, 260, 70, 25)
$Tab2 = GUICtrlCreateTabItem("Tab 2")
GUICtrlCreateEdit("", 10, 30, 280, 220)
GUICtrlCreateButton("Button 2", 115, 260, 70, 25)
$Tab3 = GUICtrlCreateTabItem("Tab 3")
GUICtrlCreateEdit("", 10, 30, 280, 220)
GUICtrlCreateButton("Button 3", 115, 260, 70, 25)

GUICtrlCreateTabItem("")
GUISetState()
_FillTabBackground($hDC, 0xFF0000, 5, 25)

While 1
    Switch GUIGetMsg()
        Case $Tab
            Switch GUICtrlRead($Tab, 1)
                Case $Tab1
                    _WinAPI_RedrawWindow($hGUI)
                    _FillTabBackground($hDC, 0xFF0000, 5, 25)

                Case $Tab2
                    _WinAPI_RedrawWindow($hGUI)
                    _FillTabBackground($hDC, 0x00FF00, 5, 25)

                Case $Tab3
                    _WinAPI_RedrawWindow($hGUI)
                    _FillTabBackground($hDC, 0x0000FF, 5, 25)
            EndSwitch

        Case $GUI_EVENT_CLOSE
            ExitLoop
    EndSwitch
WEnd

_WinAPI_ReleaseDC($hTab, $hDC)
GUIDelete()

Func _WinAPI_ExtFloodFill($hDC, $iX, $iY, $iColor, $iFillType)
    Local $aResult = DllCall("gdi32.dll", "int", "ExtFloodFill", "hwnd", $hDC, "int", $iX, "int", $iY, "uint", _RGB($iColor), "uint", $iFillType)

    If @error Then Return SetError(@error, @extended, 0)
    Return $aResult[0] <> 0
EndFunc

Func _FillTabBackground($hDC, $iColor, $iX, $iY)
    Local $hBrush, $hOldBrush

    $hBrush = _WinAPI_CreateSolidBrush(_RGB($iColor))
    $hOldBrush = _WinAPI_SelectObject($hDC, $hBrush)
    _WinAPI_ExtFloodFill($hDC, $iX, $iY, 0xD4D0C8, $FLOODFILLSURFACE)
    _WinAPI_SelectObject($hDC, $hOldBrush)
    _WinAPI_DeleteObject($hBrush)
EndFunc

Func _WM_PAINT($hWnd, $iMsg, $iwParam, $ilParam)

    Switch GUICtrlRead($Tab, 1)
        Case $Tab1
            _WinAPI_RedrawWindow($hGUI, $RDW_ERASE)
            Sleep(10)
            _FillTabBackground($hDC, 0xFF0000, 5, 25)

        Case $Tab2
            _WinAPI_RedrawWindow($hGUI, $RDW_ERASE)
            Sleep(10)
            _FillTabBackground($hDC, 0x00FF00, 5, 25)

        Case $Tab3
            _WinAPI_RedrawWindow($hGUI, $RDW_ERASE)
            Sleep(10)
            _FillTabBackground($hDC, 0x0000FF, 5, 25)
    EndSwitch

    Return $GUI_RUNDEFMSG
EndFunc

Func _RGB($iColor)
    Return Dec(Hex(BinaryMid($iColor, 1, 3)))
EndFunc

[Melba23]

MadMaxx,

3 tabs which I would like to make 3 different colours

Here is my take on how you might do it:

#include <GUIConstantsEx.au3>
#include <GuiTab.au3>

$hGUI = GUICreate("Test", 500, 500)

$hTab_1 = GUICtrlCreateTab(10, 10, 230, 90)
    $hTab_10 = GUICtrlCreateTabitem("Red")
        _GUICtrlTab_SetBkColor($hGUI, $hTab_1, 0xFFCCCC)
    $hTab_11 = GUICtrlCreateTabitem("Green")
        _GUICtrlTab_SetBkColor($hGUI, $hTab_1, 0xCCFFCC)
    $hTab_12 = GUICtrlCreateTabitem("Blue")
        _GUICtrlTab_SetBkColor($hGUI, $hTab_1, 0xCCCCFF)
GUICtrlCreateTabitem ("")   ; end tabitem definition
GUISetState()

GUISetState()

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch

WEnd

Func _GUICtrlTab_SetBkColor($hWnd, $hSysTab32, $sBkColor)

    Local $aTabPos = ControlGetPos($hWnd, "", $hSysTab32)
    Local $aTab_Rect = _GUICtrlTab_GetItemRect($hSysTab32, -1)

    GUICtrlCreateLabel("", $aTabPos[0]+2, $aTabPos[1]+$aTab_Rect[3]+4, $aTabPos[2]-6, $aTabPos[3]-$aTab_Rect[3]-7)
    GUICtrlSetBkColor(-1, $sBkColor)
    GUICtrlSetState(-1, $GUI_DISABLE)

EndFunc

M23

[MadMaxx]

Thanks M23

[Melba23]

MadMaxx,

My pleasure.

M23

[llewxam]

Just wanted to mention that I was very glad to find this Melba23, I have a nice blue background in my GUI and have never used CreateTab until today, I was SOOOOO upset with how my app looked because the background color was wrong. Thanks for this solution, very simple idea, I appreciate your expertise as always!!

Ian

[Melba23]

llewxam,

Not mine, but I am afraid I have no idea who should really get the credit!

M23