Array help

[ranhalt]

I have 20 checkboxes that I want to read/print in an efficient manner. Right now, I have a very inefficient 20 section function similar to what I have here, but I want to use an array to replace checkCN1 with checkCN[$var], where $var is 1, 2, 3... 20.

I'd appreciate any help with using arrays so I can cut down length.

$complete = "Complete"
$incomplete = "Incomplete"
$var = 1
While $var <= 20
    If GUICtrlRead($checkCN[$var]) == 1 Then ; If checkbox true, then complete
        $status_CN[$var] = $complete
    Else ; If checkbox false, incomplete
        $status_CN[$var] = $incomplete
    EndIf
WEnd

This gives me the error

C:\Documents and Settings\Administrator\Desktop\gui3a.au3 (1069) : ==> Variable used without being declared.:

If GUICtrlRead($checkCN[$var]) == 1 Then

If GUICtrlRead(^ ERROR

[Melba23]

ranhalt,

Assuming you haave the ControlIDs of the 20 checkbowes in the $checkCN array, you need a For...Next loop:

$complete = "Complete"
$incomplete = "Incomplete"
For $var = 1 To 20
    If GUICtrlRead($checkCN[$var]) = 1 Then ; If checkbox true, then complete
        $status_CN[$var] = $complete
    Else ; If checkbox false, incomplete
        $status_CN[$var] = $incomplete
    EndIf
Next

Note that the == operator is only used for making case-sensitive comparisons between strings - you do not need it here.

And you can set strings directly into an array, you do not need to set them as variables first:

$status_CN[$var] = "Complete"

M23

[ranhalt]

OK, this could involve a lot more change than anticipated. I have no existing array, it really is just 20x of this right now:

If GUICtrlRead($checkCN1) == 1 Then ; If checkbox true, then complete
        $status_CN1 = $complete
    Else ; If checkbox false, incomplete
        $status_CN1 = $incomplete
    EndIf

I'm working on creating an array, which is what I think I need, but not to store the status of the checkboxes, just as an index. I want it to increment + 1 while I read the values of the checkboxes.

and replace this:

If GUICtrlRead($checkCN1) == 1 Then ; If checkbox true, then complete
        $status_CN1 = $complete
    Else ; If checkbox false, incomplete
        $status_CN1 = $incomplete
    EndIf
    
    If GUICtrlRead($checkCN2) == 1 Then ; If checkbox true, then complete
        $status_copy = $complete
    Else ; If checkbox false, incomplete
        $status_copy = $incomplete
    EndIf
    
    If GUICtrlRead($checkCN3) == 1 Then ; If checkbox true, then complete
        $status_CN3 = $complete
    Else ; If checkbox false, incomplete
        $status_CN3 = $incomplete
    EndIf
    
    If GUICtrlRead($checkCN4) == 1 Then ; If checkbox true, then complete
        $status_CN4 = $complete
    Else ; If checkbox false, incomplete
        $status_CN4 = $incomplete
    EndIf

with this (not entirely accurate syntax):

X = 1
while 
    If GUICtrlRead($checkCNX) == 1 Then ; If checkbox true, then complete
        $status_CNX = $complete
    Else ; If checkbox false, incomplete
        $status_CNX = $incomplete
    EndIf
        X += 1
wend

[Melba23]

ranhalt,

This is extremely ugly and, in my opinion, very bad coding practise, but you can get round your wish to avoid arrays like this:

#include <GUIConstantsEx.au3>

Global $statusCN1, $statusCN2

$hGUI = GUICreate("Test", 500, 500)

$checkCN1 = GUICtrlCreateCheckbox("", 10, 10, 20, 20)
GUICtrlSetState(-1, $GUI_CHECKED)
$checkCN2 = GUICtrlCreateCheckbox("", 10, 50, 20, 20)

GUISetState()

For $i = 1 To 2
    If GUICtrlRead(Eval("checkCN" & $i)) = 1 Then ; If checkbox true, then complete
        Assign("statusCN" & $i, "complete")
    Else ; If checkbox false, incomplete
        Assign("statusCN" & $i, "incomplete")
    EndIf
Next

ConsoleWrite("StatusCN1: " & $statusCN1 & @CRLF)
ConsoleWrite("StatusCN2: " & $statusCN2 & @CRLF)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

But I still firmly belive that you should recast the code to use arrays - having to use Eval and Execute like this is usually a sign that you are on the wrong track!

M23

Edit: Left some errorchecking code in and did not want to confuse!

Edited January 8, 2010 by Melba23

[james3mg]

It shouldn't really take a whole lot of changes to put everything in an array, which would really serve you well.

Go to the part of your script where you're defining all the checkboxes. Just above it, add this:

Dim $checkCNX[20]

(this tells AutoIt that $checkCNX is an array, and will have 20 elements in it).

Now, go through your script...wherever you have a line like, $checkCNX1=GUICtrlCreateCheckbox(...), just replace it with

$checkCNX[0]=GUICtrlCreateCheckbox(...)

(note arrays start at 0, not 1, so the first checkbox should be 0, and the 20th should be 19.

Basically the same thing as you've had, but it's a single array now, instead of 20 variables.

Now you need an array to store the results, so add:

Dim $status_CNX[20]

Then use your For...Next loop like:

For $i=0 To 19
    If GUICtrlRead($checkCNX) == 1 Then ; If checkbox true, then complete
        $status_CNX[$i] = $complete
    Else ; If checkbox false, incomplete
        $status_CNX[$i] = $incomplete
    EndIf
Next

That way, it increments itself (saves a line of code, no biggie, just cleaner), and stores all your checkboxes are in one array, and all your results are in another.

Does that make sense?

Edited January 8, 2010 by james3mg