Assigning Images to Buttons..

[damien89x]

Hi,

In my little GUI launcher program, everything is working.

Except.. I can't work out how to assign an image to a button. Would anyone be able to point me in the right direction?

[Mat]

#include <GUIButton.au3>
#include <GUIImageList.au3>

$hGUI = GUICreate("Button!", 400, 400)

$hBtn = _GUICtrlButton_Create($hGUI, "Button", 2, 2, 100, 30)
$hImg = _GUIImageList_Create(16, 16, 5, 0)

_GUIImageList_AddIcon($hImg, @AutoItExe, 0)

_GUICtrlButton_SetImageList($hBtn, $hImg)

GUISetState()

While 1
    Switch GUIGetMsg()
        Case -3
            Exit
    EndSwitch
WEnd

Thats the proper way to do it

Heres a slightly shorter version:

#include <GUIButton.au3>

$hGUI = GUICreate("Button!", 400, 400)

$hBtn = _GUICtrlButton_Create($hGUI, "Button", 2, 2, 100, 30)
_GUICtrlButton_SetImage($hBtn, @AutoItExe, 0)

GUISetState()

While 1
    Switch GUIGetMsg()
        Case -3
            Exit
    EndSwitch
WEnd

Edited January 13, 2010 by Mat

[Melba23]

damien89x,

Or you can do it with the built-in functions like this:

#include <GUIConstantsEx.au3>
#include <ButtonConstants.au3>

$hGUI = GUICreate("Test", 500, 500)

$hButton1 = GUICtrlCreateButton("", 10, 10, 80, 40, $BS_BITMAP)
GUICtrlSetImage($hButton1, "C:\Program Files\AutoIt3\Examples\GUI\Advanced\Images\Red.bmp")

$hButton1 = GUICtrlCreateButton("", 10, 100, 80, 40, $BS_ICON)
GUICtrlSetImage($hButton1,@AutoItExe, 0)

GUISetState()

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch

WEnd

M23

[damien89x]

Thanks guys, is there a way to embed the objects into the exe when you compile it?

Or will I need to copy the BMP files separately and keep them in the folder of the executable and have it point to them

[picea892]

Yes you can add images to the exe using "Fileinstall".

I would suggest if you are making a launcher you might investigate extracting icons from the appropriate exe instead of using fileinstall.

Edited January 13, 2010 by picea892