[Solved] Text of a gui group control

[JohnOne]

I've done some looking around and came upon GUICtrlSetDefColor()

But it dosent change the text color of a group, and I also noticed it wont change radio button text either.

Modified from help file

#include <GUIConstantsEx.au3>

Opt('MustDeclareVars', 1)

Example()

Func Example()
    Local $msg
    GUICreate("test GUISetTextColor", 100,100)  ; will create a dialog box that when displayed is centered
    GUICtrlSetDefColor(0xFF0000)  ; will change text color for all defined controls
    GUICtrlCreateGroup("Test", 60, 55, 35, 40) ;<===wont change color
    GUICtrlCreateLabel("label", 10,5)
    GUICtrlCreateRadio("radio", 10,25,50)
    ;GUICtrlSetColor(-1, 0x0000FF)  ; will change text color for specified control
    GUICtrlCreateButton("button", 10,55)
    GUISetState()       ; will display an empty dialog box
    ; Run the GUI until the dialog is closed
    While 1
        $msg = GUIGetMsg()
        If $msg = $GUI_EVENT_CLOSE Then ExitLoop
    WEnd
EndFunc   ;==>Example

Is there another function to do this ?

Edited January 15, 2010 by JohnOne

[Melba23]

JohnOne,

You need to get rid of any themes first to set the colours of these particular controls:

expandcollapse popup

; Credit to martin for the function code

#include <GUIConstantsEx.au3>

Global $aOld_Theme

Opt('MustDeclareVars', 1)

Example()

Func Example()
    Local $msg

    KillThemes(True)

    GUICreate("test GUISetTextColor", 100,100)  ; will create a dialog box that when displayed is centered
    GUICtrlSetDefColor(0xFF0000)  ; will change text color for all defined controls
    GUICtrlCreateGroup("Test", 60, 55, 35, 40) ;<===wont change color ; <<<<<<<<< Does now!!!!!!!!!!!
    GUICtrlCreateLabel("label", 10,5)
    GUICtrlCreateRadio("radio", 10,25,50) ; <<<<<<< And here too
    ;GUICtrlSetColor(-1, 0x00FF00)  ; This will work now as well if you uncomment it
    GUICtrlCreateButton("button", 10,55)
    GUISetState()       ; will display an empty dialog box
    ; Run the GUI until the dialog is closed
    While 1
        $msg = GUIGetMsg()
        If $msg = $GUI_EVENT_CLOSE Then
            KillThemes(False)
            ExitLoop
        EndIf
    WEnd
EndFunc   ;==>Example

Func KillThemes($fState)

     If Not StringInStr(@OSTYPE, "WIN32_NT") Then Return 0

     If $fState Then
        $aOld_Theme = DllCall("uxtheme.dll", "int", "GetThemeAppProperties")
         DllCall("uxtheme.dll", "none", "SetThemeAppProperties", "int", 0)
         Return 1
     ElseIf IsArray($aOld_Theme) Then
         DllCall("uxtheme.dll", "none", "SetThemeAppProperties", "int", $aOld_Theme[0])
         $aOld_Theme = ""
         Return 1
     EndIf
     Return 0

 EndFunc

Of course you can set the colour of the individual controls with GUICtrlSetColor as well. I hope that helps.

M23

Edit: Wrong button, too soon!

Edited January 15, 2010 by Melba23

[JohnOne]

Superperb M23, I'd have never gotten that in a month of wednsdays.

Thank you.

And thank you Martin.

[jchd]

Thanks to both Martin (again) and Melba23 (again) for this nice trick.