AutoIt strange behaviour?

[Robjong]

Hi,

If you try to check if a (non empty) string is equal to 0 it won't be ofcourse, but I noticed that when you try to check if a string is not equal 0 it actualy is...

Example:

; This works...
If "AutoIt" == 0 Then
    ConsoleWrite("!> AutoIt is 0" & @CRLF)
Else
    ConsoleWrite("-> AutoIt is not 0" & @CRLF)
EndIf
; the above script outputs: -> AutoIt is not 0

; ...so I would expect this to work the same?
If "AutoIt" <> 0 Then
    ConsoleWrite("-> AutoIt is not 0" & @CRLF)
Else
    ConsoleWrite("!> AutoIt is 0" & @CRLF)
EndIf
; the above script outputs: !> AutoIt is 0

Weird right?

edit: output comments

Edited January 19, 2010 by Robjong

[jvanegmond]

There is no opposite operator to ==. The use of <> opposite to == is invalid. <> operator is opposite to =.

If you change your example, you will find:

If "AutoIt" = 0 Then
    ConsoleWrite("!> AutoIt is 0" & @CRLF)
Else
    ConsoleWrite("-> AutoIt is NOT 0" & @CRLF)
EndIf

If "AutoIt" <> 0 Then
    ConsoleWrite("-> AutoIt is NOT 0" & @CRLF)
Else
    ConsoleWrite("!> AutoIt is 0" & @CRLF)
EndIf

If "AutoIt" == 0 Then
    ConsoleWrite("!> AutoIt is 0" & @CRLF)
Else
    ConsoleWrite("-> AutoIt is NOT 0" & @CRLF)
EndIf

If Not ("AutoIt" == 0) Then
    ConsoleWrite("-> AutoIt is NOT 0" & @CRLF)
Else
    ConsoleWrite("!> AutoIt is 0" & @CRLF)
EndIf

[Robjong]

Thanks Manadar, that explains it.

[jvanegmond]

No problem. I still struggle with this myself on occassion.

[jchd]

Let me add a bit about this. Let's run the following:

ConsoleWrite("Condition 1: ('' = 0 ) is " & Execute(" ('' = 0 )") & @CRLF)
ConsoleWrite("Condition 2: ('' == 0 ) is " & Execute(" ('' == 0 )") & @CRLF)
ConsoleWrite("Condition 3: ('' = '0') is " & Execute(" ('' = '0')") & @CRLF)
ConsoleWrite("Condition 4: ('' == '0') is " & Execute(" ('' == '0')") & @CRLF)
ConsoleWrite("Condition 5: ('123' = 123) is " & Execute(" ('123' = 123)") & @CRLF)
ConsoleWrite("Condition 6: ('123' == 123) is " & Execute(" ('123' == 123)") & @CRLF)
ConsoleWrite("Condition 7: ('abc' = 0 ) is " & Execute(" ('abc' = 0 )") & @CRLF)
ConsoleWrite("Condition 8: ('abc' <> 0 ) is " & Execute(" ('abc' <> 0 )") & @CRLF)
ConsoleWrite("Condition 9: ('abc' == 0 ) is " & Execute(" ('abc' == 0 )") & @CRLF)
ConsoleWrite("Condition 10: Not ('abc' == 0 ) is " & Execute(" Not ('abc' == 0 )") & @CRLF)
ConsoleWrite("Condition 11: ('A' = 'a') is " & Execute(" ('A' = 'a')") & @CRLF)
ConsoleWrite("Condition 12: ('A' == 'a') is " & Execute(" ('A' == 'a')") & @CRLF)

We get:

Condition 1: ('' = 0 ) is True
Condition 2: ('' == 0 ) is False
Condition 3: ('' = '0') is False
Condition 4: ('' == '0') is False
Condition 5: ('123' = 123) is True
Condition 6: ('123' == 123) is True
Condition 7: ('abc' = 0 ) is True
Condition 8: ('abc' <> 0 ) is False
Condition 9: ('abc' == 0 ) is False
Condition 10: Not ('abc' == 0 ) is True
Condition 11: ('A' = 'a') is True
Condition 12: ('A' == 'a') is False

A few comments now.

There are various cases:

Conditions 3, 4: here we're just comparing clearly distinct strings here, so no surprise.

Conditions 8, 10: are obviously the inverse of conditions 7 and 9, resp. (only as reference to the OP)

Conditions 11, 12: == is case sensitive, while = is not, so no surprise either.

Conditions 1, 2, 7, 9: more interesting in that an empty or non-numeric string = 0 but Not == 0

Conditions 5, 6: also interesting in that a numeric string is always (= or ==) the same that its Number()

This is for illustration only, I see nothing buggy here. This behavior is simply a given that need to have in mind while coding.

Edited January 19, 2010 by jchd

[MvGulik]

whatever Edited February 7, 2011 by MvGulik