_screencapture

[Aceguy]

any ideas what im doing wrong..

#include <ScreenCapture.au3>
#include <WinAPI.au3>

Local $hGUI
$hGUI = GUICreate("Screen Capture", 500, 500)
$pic = _ScreenCapture_Capture("", 0, 0, 100, 100)
$pic1 = _GDIPlus_BitmapCreateFromHBITMAP($pic)
GUICtrlCreatePic($pic1, 0, 0)
GUISetState(@SW_SHOW)
Sleep(2000)
_WinAPI_DeleteObject($pic1)

Edited January 23, 2010 by Aceguy

[Melba23]

aceguy,

I am not an expert in GDI, but I think it is a bit more complicated than that if you want to use the bitmap from memory:

expandcollapse popup

#include <ScreenCapture.au3>

$pic = _ScreenCapture_Capture("", 0, 0, 500, 500)

$hGUI = GUICreate("Screen Capture", 500, 500)

$hPic = GUICtrlCreatePic("", 0, 0)
_SetBitmapToCtrl($hPic, $pic)

GUISetState(@SW_SHOW)

While 1
    If GUIGetMsg() = -3 Then ExitLoop
WEnd

_WinAPI_DeleteObject($pic)

Exit

; Shamelessly lifted from Zednas Resources UDF

Func _SetBitmapToCtrl($CtrlId, $hBitmap)

    Local Const $STM_SETIMAGE = 0x0172
    Local Const $STM_GETIMAGE = 0x0173
    Local Const $IMAGE_BITMAP = 0
    Local Const $SS_BITMAP = 0x0E
    Local Const $GWL_STYLE = -16

    Local $hWnd = GUICtrlGetHandle($CtrlId)
    If $hWnd = 0 Then
        Return SetError(1, 0, 0)
    EndIf
    Local $Style = _WinAPI_GetWindowLong($hWnd, $GWL_STYLE)
    If @error Then
        Return SetError(2, 0, 0)
    EndIf
    _WinAPI_SetWindowLong($hWnd, $GWL_STYLE, BitOR($Style, $IMAGE_BITMAP))
    If @error Then
        Return SetError(3, 0, 0)
    EndIf
    Local $hPrev = _SendMessage($hWnd, $STM_SETIMAGE, $IMAGE_BITMAP, 0)
    If $hPrev Then
        _WinAPI_DeleteObject($hPrev)
    EndIf
    _SendMessage($hWnd, $STM_SETIMAGE, $IMAGE_BITMAP, $hBitmap)
    If @error Then
        Return SetError(4, 0, 0)
    EndIf
    $hPrev = _SendMessage($hWnd, $STM_GETIMAGE, $IMAGE_BITMAP, 0)
    If (@error) Or ($hBitmap = $hPrev) Then
        $hBitmap = 0
    EndIf

EndFunc   ;==>_SetBitmapToCtrl

Moreover, I have always found it gives a better quality image to save the screencapture to a temp file first - it also simplifies the code a lot:

#include <ScreenCapture.au3>

$pic = _ScreenCapture_Capture(@TempDir & "\Pic.bmp", 0, 0, 500, 500)

$hGUI = GUICreate("Screen Capture", 500, 500)

$hPic = GUICtrlCreatePic(@TempDir & "\Pic.bmp", 0, 0, 500, 500)

GUISetState(@SW_SHOW)

While 1
    If GUIGetMsg() = -3 Then
        FileDelete(@TempDir & "\Pic.bmp")
        Exit
    EndIf
WEnd

I hope this helps.

M23

[Aceguy]

great work, both work superbly, thanks very much