help with hotkeyset

[123disconnect]

hotkeyset("{LEFT down}","func_call") is not work

anyone . can you say to me why ?

i see on help file V3.3.0.0 and understand hotkeyset is same format as send()

Edited January 25, 2010 by 123disconnect

[Xenobiologist]

Have a look at _isPressed. I guess this is more what you are looking for.

[martin]

hotkeyset("{LEFT down}","func_call") is not work

anyone . can you say to me why ?

i see on help file V3.3.0.0 and understand hotkeyset is same format as send()

Use

HotKeySet("{LEFT}","func_call)

Hotkeys all work on the keydown event. If you want to detect down and up separately you could do something like this-

#include <misc.au3>

hotkeyset("{LEFT}","func_call") 
Global $LeftIsDown=false

while 1
    sleep(50)
    if $LeftIsDown and Not _IsPressed("25") Then
        func_call2()
        EndIf
WEnd


func func_call()
    HotKeySet("{LEFT}");prevent repeated calls while key down
    $LeftIsDown = True
    ConsoleWrite("Left is down" & @CRLF)
EndFunc

func func_call2()
    $LeftIsDown = False
    ConsoleWrite("Left is UP" & @CRLF)
    hotkeyset("{LEFT}","func_call")
EndFunc

or without HotKeys

#include <misc.au3>

Global $LeftIsDown=false

while 1
    sleep(50)
    check()
WEnd

Func check()
    if $LeftIsDown and Not _IsPressed("25") Then
        func_call2()
    EndIf

    If (Not $LeftIsDown) and _IsPressed("25") Then
        func_call()
    EndIf
EndFunc

func func_call()
    $LeftIsDown = True
    ConsoleWrite("Left is down" & @CRLF)
EndFunc

func func_call2()
    $LeftIsDown = False
    ConsoleWrite("Left is UP" & @CRLF)
EndFunc