Notification of clicking on edit

[Inververs]

How to register the event when the Input control is pressed in my GUI?

In EditConstants.aus no such Notifications const

I want to use the input as a hyperlink

label control is not suitable as should be possible to edit the text.

[Melba23]

Odin,

I have never found a way of registering a click on an input control. The best I have come up with is to use "Enter" to indicate that the data entry is complete - as you are probably using the keyboard to enter the data in the first place, it is not too much of a restriction:

#include <GUIConstantsEx.au3>

Main()

Func _Main()

    $hGUI = GUICreate("Test", 500, 500)

    Local $hInput = GUICtrlCreateInput('', 10, 10, 200, 20)

    GUISetState()

    ; Set an accelerator key to mark the end of the data input
    Local $hDum = GUICtrlCreateDummy()
    Local $accels[1][2] = [["{ENTER}", $hDum]]
    GUISetAccelerators($accels)

    While 1
        Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $hDum
            MsgBox(0,"Input Ready", GUICtrlRead($hInput))
        EndSwitch
    WEnd

EndFunc   ;==>_Main

I hope this helps.

M23

[Inververs]

Thank you, Melba23

But this is not what I need, just pressing the mouse button should trigger the event.

[Melba23]

Odin,

I say again:

I have never found a way of registering a click on an input control.

M23

Edit: But someone else might.

Edited February 11, 2010 by Melba23

[wraithdu]

This is actually pretty easy. There's two methods I can think of:

1) Monitor the EN_SETFOCUS notification, which is sent to the parent window via WM_COMMAND. So, GuiRegisterMsg($WM_COMMAND... However this will not work if the input control already has focus (or is the only control in the GUI). If you have more controls and focus is being moved to the input and you really only need this notification one time, then this is certainly viable and would be my first choice.

2) Check for the $GUI_EVENT_PRIMARYDOWN or $GUI_EVENT_PRIMARYUP event using GUIGetMessage in advanced mode or GUIOnEventMode with GUIGetCursorInfo to find out what control the mouse has clicked.

Edited February 11, 2010 by wraithdu

[Melba23]

wraithdu,

I like the second way - but it is a bit roundabout.

Although you seem to be specialising in that sort of code lately!

M23

[Inververs]

All thanks.

I did so:

#include <GUIConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 633, 447, 192, 124)
$Input1 = GUICtrlCreateInput("Input1", 232, 184, 121, 21, BitOR($ES_AUTOHSCROLL,$ES_READONLY))
GUICtrlSetCursor (-1, 0)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $GUI_EVENT_PRIMARYUP
            $aMouse_Info=GUIGetCursorInfo ( $Form1 )
            Switch $aMouse_Info[4]
                Case $Input1
                    MsgBox(0,0,"Click")
                Case Else
            EndSwitch
    EndSwitch
WEnd

Edited February 11, 2010 by Odin

[wraithdu]

Yeppers, that'll do it.

@Melba23

Thanks