Top 20px draggable

[FinalVersion]

Lets say I remove the title bar, how can I make the top 20px of the program drag able?

[JRowe]

MouseCoordMode sets whether MouseGetPos() is relative or absolute. In this case, you want relative.

Test MouseGetPos() whether its in the top 20 pixels when a mouse and the $GUI_EVENT_PRIMARYDOWN event on GuiGetMsg. If the two are true, use WinMove() to move your window along with the cursor.

Good luck

[FinalVersion]

Ok I got this far but I'm stuck with the WinMove().

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Opt("MouseCoordMode", 2)

$Form1 = GUICreate("Form1", 501, 344, 192, 124, BitOR($WS_POPUP,$WS_CLIPSIBLINGS))
GUISetState(@SW_SHOW)


While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $GUI_EVENT_PRIMARYDOWN
            $mPos = MouseGetPos()
            If $mPos[1] < 20 Then
                WinMove() ; I'm stuck here
            EndIf
    EndSwitch
WEnd

[Melba23]

Final version,

2 solutions for you:

1. Use $SC_DRAGMOVE on the whole GUI:

#include <GuiconstantsEx.au3>
#include <WindowsConstants.au3>
#include <SendMessage.au3>

Global Const $SC_DRAGMOVE = 0xF012

HotKeySet("{ESC}", "On_Exit")
Func On_Exit()
    Exit
EndFunc

$hGUI = GUICreate("X", 50, 50, -1, -1, BitOR($WS_POPUP,$WS_BORDER), $WS_EX_TOPMOST)
GUISetBkColor(0xFF0000, $hGUI)
GUISetState()

While 1

    $msg = GUIGetMsg()
    Switch $msg
        Case $GUI_EVENT_PRIMARYDOWN
            _SendMessage($hGUI, $WM_SYSCOMMAND, $SC_DRAGMOVE, 0)
    EndSwitch
WEnd

2: Use $GUI_WS_EX_PARENTDRAG on a label:

#include <GuiconstantsEx.au3>
#include <WindowsConstants.au3>

HotKeySet("{ESC}", "On_Exit")
Func On_Exit()
    Exit
EndFunc

$hGUI = GUICreate("X", 50, 50, -1, -1, BitOR($WS_POPUP,$WS_BORDER), $WS_EX_TOPMOST)
$hLabel = GUICtrlCreateLabel("", 0, 0, 50, 50, -1, $GUI_WS_EX_PARENTDRAG)
GUICtrlSetBkColor(-1, 0x00FF00)
GUISetState()

While 1

    Sleep(10)

WEnd

Personally I prefer the former.

M23

[FinalVersion]

I seen the first example in another post of yours. But it doesn't check to see if the mouse is in the top 20px, and I'd rather not have to make a label to move the GUI, but thanks.

[JRowe]

Your example, combined with his example, makes what you need. It's also better than tracking mousePos and using winMove yourself.

[FinalVersion]

The label example or the $SC_DRAGMOVE?

[JRowe]

$SC_DRAGMOVE.

Sometihng like this:

$mPos = MouseGetPos()
 If $mPos[1] < 20 Then
 _SendMessage($hGUI, $WM_SYSCOMMAND, $SC_DRAGMOVE, 0)
 EndIf

[ProgAndy]

using WM_NCHITTEST you can specify the parts as you want

#include <GuiconstantsEx.au3>
#include <WindowsConstants.au3>
#include <SendMessage.au3>

Global Const $SC_DRAGMOVE = 0xF012

HotKeySet("{ESC}", "On_Exit")
Func On_Exit()
    Exit
EndFunc

$hGUI = GUICreate("X", 300, 100, -1, -1, BitOR($WS_POPUP,$WS_BORDER), $WS_EX_TOPMOST)
GUISetBkColor(0xFF0000, $hGUI)
GUIRegisterMsg($WM_NCHITTEST, "_MY_NCHITTEST")
GUISetState()

While 1

    $msg = GUIGetMsg()
    Switch $msg
        Case -3
            Exit
    EndSwitch
WEnd

Func _MY_NCHITTEST($hWnd, $uMsg, $wParam, $lParam)
    ; Author: Prog@ndy
    Switch $hWnd
        Case $hGUI
            Local $aPos = WinGetPos($hWnd)
            ; BitAnd(BitShift($lParam, 16),0xFFFF) will return HIWORD
            If Abs(BitAND(BitShift($lParam, 16),0xFFFF)- $aPos[1]) < 20 Then Return $HTCAPTION ; the first 20 px from top will be TitleBar
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc

[Melba23]

ProgAndy,

Nice one.

M23