Program for disabled son - help please

[Mike0627]

Hi all,

a couple of years ago I used AutoIt to write a program to help my son. The laptop it was on has crashed and been wiped etc... so I lost the AutoIT program, and can't remember how to re-do it. I am sure I can figure it out, but I would appreciate any input and a shove in the right direction.

Here's what I want to accomplish

Start the AutoIT script

It asks for the number of second to run a loop

It opens a program (DVD player)

RUns the DVD for the specified number of seconds

pauses the DVD

waits for an "ENTER" key input to restart the DVD again for the specified seconds

loop that until the program is exited.

I seem to remember lines that checked to see if the DVD player was already open, and then making sure that is the active window too.

Thanks to all

Mike

[Melba23]

Mike0627,

Welcome to the AutoIt forum.

This should get you started:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <EditConstants.au3>
#include <Misc.au3>

HotKeySet("{ESC}", "On_Exit") ; Press ESC to exit

$hGUI = GUICreate("Test", 500, 500)

GUICtrlCreateLabel("Set seconds to run", 10, 10, 200, 20)

$hInput = GUICtrlCreateInput("", 10, 30, 200, 20, $ES_NUMBER)

$hButton = GUICtrlCreateButton("Run", 10, 60, 80, 30)

GUISetState()

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $hButton

            ; If a time has been entered
            If GUICtrlRead($hInput) <> "" Then
                
                ; Delete GUI
                GUIDelete($hGUI)
                
                ; Read entered time
                $iTime = GUICtrlRead($hInput)

                ; Open the DVD player
                ;If Not ProcessExists("DVD.exe") Then
                ;   Run("DVD.exe)
                ;   WinWaitActive("DVD")
                ;EndIf

                $dll = DllOpen("user32.dll")

                While 1

                ;   WinActivate("DVD")

                    ; Tricky bit - how to run DVD player
                    ; Would suggest either MouseClick or ControlCommand
                    ConsoleWrite("Running" & @CRLF) ; Simulate running

                    ; Wait the required number of seconds
                    Sleep($iTime * 1000)

                    ; Use a similar command to Pause the DVD player
                    ConsoleWrite("Paused" & @CRLF) ; Simulate pausing

                    ; Idle until ENTER is pressed
                    Do
                        Sleep(10)
                    Until _IsPressed("0D", $dll)

                WEnd
            EndIf
    EndSwitch

WEnd

Func On_Exit()
    DllClose($dll)
    Exit
EndFunc

You will need to fill in the correct values for the DVD player process name, path and window title. I cannot give any real guidance on how to play/pause the DVD player as I have no idea how you can interact with it. i imagine there are controls on the window - you can use the Au3 Window Info tool to get class/instance data for them to use in ControCommand or a position for MouseClick.

If you run into problems, please do come back and ask. Good luck and enjoy relearning AutoIt!

M23