Hotkey for key pressed

[frankk]

Hello,

I'm having a problem:

I need a function to run while a key is pressed.

Basically, I tried it with two functions (start and stop) that are bound by HotKeySet to {x down} and {x up}.

But the second Hotkeyset seems to overwrite the first and always match for keypress and release of key x.

Quite unexpected for me, since x down/up works for Send().

I'm sure, there is a way to achieve what I tried, but unfortunately I couldn't find a solution.

I'd be very happy if someone could help me there.

Thanks

[Melba23]

frankk,

Welcome to the AutoIt forum.

It is not surprising at all. Send uses the codes which keys produce as they are pressed and released (different codes for the 2 actions). HoKeySet only fires the associated function as the specified key is operated - there is no separate function for the release.

You need to use _IsPressed to detect the key being pressed. Perhaps something like this:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <Misc.au3>

$hGUI = GUICreate("Test", 500, 500)

$hLabel = GUICtrlCreateLabel("Not running", 10, 10, 150, 20)

$hCounter = GUICtrlCreateLabel("", 10, 50, 30, 30)

GUISetState()

$dll = DllOpen("user32.dll")

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            DllClose($dll)
            Exit
    EndSwitch

    If _IsPressed("58", $dll) Then _RunFunction()

WEnd

Func _RunFunction()

    Local $iCount = 0

    GUICtrlSetData($hLabel, "Running")

    Do
        $iCount += 1
        GUICtrlSetData($hCounter, $iCount)

        Sleep(100) ; Idle a bit so you can see the counter increasing

    Until Not _IsPressed("58", $dll)

    GUICtrlSetData($hLabel, "Not running")
    GUICtrlSetData($hCounter, "")

EndFunc

You do need to keep checking the _IsPressed function to detect the key release in your function - but as it usually contains a loop this is not too much of a problem.

I hope that helps. Ask if anything is unclear.

M23

[frankk]

thank you very much.

looks fine to me. will give it a try.

works fine

Edited February 26, 2010 by frankk