Jump to content

Centered popup GUI


 Share

Recommended Posts

Let's say I have a GUI 500x500 pixels and I have a second GUI that pops up 100x100 pixels.

How can I then make the popupGUI always pop "from the center" of my main GUI?

Any help is greatly appreciated - I feel like I've tried everything.

Link to comment
Share on other sites

  • Moderators

Edifice,

Just get your main GUI position and then do a bit of maths: :mellow:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$hPopupGUI = 9999

$hGUI = GUICreate("Test", 500, 500)

$hButton = GUICtrlCreateButton("Popup", 10, 10, 80, 30)

GUISetState()

While 1

    $aMsg = GUIGetMsg(1)
    Switch $aMsg[1]
        Case $hGUI
            Switch $aMsg[0]
                Case $GUI_EVENT_CLOSE
                    Exit
                Case $hButton
                    $apos = WinGetPos($hGUI)
                    $iHpos = ($aPos[2] - 100) / 2 + $aPos[0] - 3
                    $iVPos = ($aPos[3] - 100) / 2 + $aPos[1] - 20

                    $hPopupGUI = GUICreate("Popup", 100, 100, $iHpos, $iVPos)
                    GUISetState()
            EndSwitch
        Case $hPopupGUI
            If $aMsg[0] = $GUI_EVENT_CLOSE Then GUIDelete($hPopupGUI)
    EndSwitch

WEnd

23

Public_Domain.png.2d871819fcb9957cf44f4514551a2935.png Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind

Open spoiler to see my UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Link to comment
Share on other sites

  • Moderators

Edifice,

You can use @SW_HIDE/SHOW if you wish: :mellow:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$hPopupGUI = 9999

$hGUI = GUICreate("Test", 500, 500)

$hButton = GUICtrlCreateButton("Popup", 10, 10, 80, 30)

GUISetState()

$hPopupGUI = GUICreate("Popup", 100, 100)
GUISetState(@SW_HIDE)

While 1

    $aMsg = GUIGetMsg(1)
    Switch $aMsg[1]
        Case $hGUI
            Switch $aMsg[0]
                Case $GUI_EVENT_CLOSE
                    Exit
                Case $hButton
                    $apos = WinGetPos($hGUI)
                    $iHpos = ($aPos[2] - 100) / 2 + $aPos[0] - 3
                    $iVPos = ($aPos[3] - 100) / 2 + $aPos[1] - 20
                    WinMove($hPopupGUI, "", $iHpos, $iVPos)
                    GUISetState(@SW_SHOW, $hPopupGUI)


            EndSwitch
        Case $hPopupGUI
            If $aMsg[0] = $GUI_EVENT_CLOSE Then GUISetState(@SW_HIDE, $hPopupGUI)
    EndSwitch

WEnd

M23

Public_Domain.png.2d871819fcb9957cf44f4514551a2935.png Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind

Open spoiler to see my UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Link to comment
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!

Register a new account

Sign in

Already have an account? Sign in here.

Sign In Now
 Share

  • Recently Browsing   0 members

    • No registered users viewing this page.
×
×
  • Create New...