[SOLVED] _GUICtrlListView_Create() and WM_DROPFILES

[guinness]

In the example below I am dropping multiple files on a ListView using _GUICtrlListView_Create() but for some reason even though the function WM_DROPFILES responds in the Console, it doesn't add the files to the ListView. But when using the in-built GUICtrlCreateListView, it works as it should. Normally when adding single files I use something like the Melba23 example. Because I like to use the ListView UDF I am hoping there is a work around? Thanks

Example taken and modified from: Here

expandcollapse popup

; *** Start added by AutoIt3Wrapper ***
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
; *** End added by AutoIt3Wrapper ***
#AutoIt3Wrapper_Add_Constants=n
;***************************************************
; by Lazycat
;***************************************************
#include <GUIConstants.au3>
#include <GuiListView.au3>

Global $WM_DROPFILES = 0x233
Global $gaDropFiles[1], $str = ""

$hGUI = GUICreate("Test", 400, 200, 219, 178, -1, BitOR($WS_EX_ACCEPTFILES, $WS_EX_TOPMOST))
;$hEdit = GUICtrlCreateEdit("", 5, 5, 390, 190)
;$hEdit = _GUICtrlListView_Create($hGUI, "", 5, 5, 390, 190) ;UnComment
$hEdit = GUICtrlCreateListView("", 5, 5, 390, 190) ;Comment
GUICtrlSetState(-1, $GUI_DROPACCEPTED)
_GUICtrlListView_InsertColumn($hEdit, 0, "File Name", 120)
GUISetState(@SW_SHOW)

GUIRegisterMsg($WM_DROPFILES, "WM_DROPFILES_FUNC")
_GUICtrlListView_AddItem($hEdit, "First_Line")
While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $GUI_EVENT_DROPPED
            $str = ""
            For $i = 0 To UBound($gaDropFiles) - 1
                _GUICtrlListView_AddItem($hEdit, $gaDropFiles[$i])
            Next
    EndSwitch
WEnd

Func WM_DROPFILES_FUNC($hWnd, $msgID, $wParam, $lParam)
    ConsoleWrite("aaaaaaaaaa" & @CRLF)
    Local $nSize, $pFileName
    Local $nAmt = DllCall("shell32.dll", "int", "DragQueryFile", "hwnd", $wParam, "int", 0xFFFFFFFF, "ptr", 0, "int", 255)
    For $i = 0 To $nAmt[0] - 1
        $nSize = DllCall("shell32.dll", "int", "DragQueryFile", "hwnd", $wParam, "int", $i, "ptr", 0, "int", 0)
        $nSize = $nSize[0] + 1
        $pFileName = DllStructCreate("char[" & $nSize & "]")
        DllCall("shell32.dll", "int", "DragQueryFile", "hwnd", $wParam, "int", $i, "ptr", DllStructGetPtr($pFileName), "int", $nSize)
        ReDim $gaDropFiles[$i + 1]
        $gaDropFiles[$i] = DllStructGetData($pFileName, 1)
        $pFileName = 0
    Next
EndFunc   ;==>WM_DROPFILES_FUNC

Edited April 29, 2010 by guinness

[PsaltyDS]

Learned something useful from this one: MSDN lies!

PostMessage(

(HWND) hWndControl, // handle to destination control

(UINT) WM_DROPFILES, // message ID

(WPARAM) wParam, // = (WPARAM) (HDROP) hDrop;

(LPARAM) lParam // = 0; not used, must be zero

);

The $hWnd parameter in WM_DROPFILES is the handle of the WINDOW, not the CONTROL. To ID the control, you have to get the X/Y coordinates with DragQueryPoint, and then check which control it was by POS. Note this demo has both a native and UDF listview, and they both work:

expandcollapse popup

#include <WindowsConstants.au3>
#include <GUIConstantsEx.au3>
#include <GuiListView.au3>

Global Const $WM_DROPFILES = 0x0233
Global $hGUI, $hLV_1, $hLV_2, $idLV_2

$hGUI = GUICreate("Test", 400, 400, 219, 178, -1, BitOR($WS_EX_ACCEPTFILES, $WS_EX_TOPMOST))
ConsoleWrite("$hGUI = " & $hGUI & @LF)
$hLV_1 = _GUICtrlListView_Create($hGUI, "", 5, 5, 390, 190)
ConsoleWrite("$hLV_1 = " & $hLV_1 & @LF)
_GUICtrlListView_InsertColumn($hLV_1, 0, "LV1: File Name", 120)

$idLV_2 = GUICtrlCreateListView("", 5, 200, 390, 190)
$hLV_2 = ControlGetHandle($hGUI, "", $idLV_2)
ConsoleWrite("$hLV_2 = " & $hLV_2 & @LF)
_GUICtrlListView_InsertColumn($hLV_2, 0, "LV2: File Name", 120)

GUIRegisterMsg($WM_DROPFILES, "WM_DROPFILES_FUNC")
GUISetState(@SW_SHOW)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

Func WM_DROPFILES_FUNC($hWnd, $msgID, $wParam, $lParam)
    ConsoleWrite("WM_DROPFILES_FUNC:  $hWnd = " & $hWnd & @LF)
    Switch $hWnd
        Case $hGUI ; Our GUI
            Local Const $tagPOINT = "int X;int Y"
            Local $tPOINT = DllStructCreate($tagPOINT), $iX, $iY
            Local $aRET, $hCtrl, $nSize, $tFileName

            ; Get X/Y coord dropped to
            $aRET = DllCall("shell32.dll", "int", "DragQueryPoint", "hwnd", $wParam, "ptr", DllStructGetPtr($tPOINT))
            $iX = DllStructGetData($tPOINT, "X")
            $iY = DllStructGetData($tPOINT, "Y")
            $hCtrl = _GetCtrlHandleFromPoint($iX, $iY)
            ConsoleWrite("$iX = " & $iX & "; $iY = " & $iY & "; $hCtrl = " & $hCtrl & @LF)

            Switch $hCtrl
                Case $hLV_1, $hLV_2
                    ; Get count of files dropped
                    $aRET = DllCall("shell32.dll", "int", "DragQueryFile", "hwnd", $wParam, "int", 0xFFFFFFFF, "ptr", 0, "int", 255)
                    For $i = 0 To $aRET[0] - 1
                        $nSize = DllCall("shell32.dll", "int", "DragQueryFile", "hwnd", $wParam, "int", $i, "ptr", 0, "int", 0)
                        $nSize = $nSize[0] + 1
                        $tFileName = DllStructCreate("char[" & $nSize & "]")
                        DllCall("shell32.dll", "int", "DragQueryFile", "hwnd", $wParam, "int", $i, "ptr", DllStructGetPtr($tFileName), "int", $nSize)
                        _GUICtrlListView_AddItem($hCtrl, DllStructGetData($tFileName, 1))
                        $tFileName = 0
                    Next
                    Return 0 ; End processing only for our LVs
            EndSwitch
    EndSwitch
EndFunc   ;==>WM_DROPFILES_FUNC

Func _GetCtrlHandleFromPoint($iX, $iY)
    $aLV_Pos = ControlGetPos($hGUI, "", $hLV_1)
    If ($iX >= $aLV_Pos[0]) And ($iX <= $aLV_Pos[0] + $aLV_Pos[2]) And ($iY >= $aLV_Pos[1]) And ($iY <= $aLV_Pos[1] + $aLV_Pos[3]) Then
        Return $hLV_1
    Else
        $aLV_Pos = ControlGetPos($hGUI, "", $hLV_2)
        If ($iX >= $aLV_Pos[0]) And ($iX <= $aLV_Pos[0] + $aLV_Pos[2]) And ($iY >= $aLV_Pos[1]) And ($iY <= $aLV_Pos[1] + $aLV_Pos[3]) Then
            Return $hLV_2
        Else
            Return 0
        EndIf
    EndIf
EndFunc   ;==>_GetCtrlHandleFromPoint

Edited March 12, 2010 by PsaltyDS

[guinness]

TESTED: Works

Thanks for that. I did search the forum (scouts honour) but couldn't find anything on the subject. Just goes to show you AutoIt MVPs know what you're doing.

I try not to post answers that can easily be found by the search tool.

Edited March 12, 2010 by guinness

[wraithdu]

While this is good information, I think the error in your original code (and your learning opportunity) was not pointed out clearly. When using UDF created controls, internal AutoIt things that you would normally take advantage of (like $GUI_EVENT_DROPPED) do NOT work. The problem with your code was that you didn't have code to add items to your listview in your WM_DROPFILES function. PsaltyDS fixed that, but didn't clearly point out that's WHY your problem was fixed. If you parse the array in your original code you'll see that indeed you do have all the information you require.