help with regex

[IchBistTod]

okay i have the following code

if StringRegExp($data[$i], "(?i)(.*?)if(.*?)then(.*?)") Then
     $conditional = StringRegExp($data[$i], "(?i)(.*?)if(.*?)then(.*?)", 1)
     for $x=1 to $conditional[0]
     MsgBox(64, "", $conditional[$x])
     Next
     EndIf

I am trying to extract "$start > 0 and $start < 2" and 'run("calc")' from 'if $start > 0 and $start < 2 then run("calc")'

the condition and action. But the regex returns 0.

Can someone tell me what is wrong? I am fairly new to regex.

[Fulano]

Well, if the string is always going to be "if <something> and <something> then ..." this should work:

Local $conditional =  StringRegExp($data[$i], "(?i)if\s*(.*)\s*then\s*(.*)", 1)
If not @error then
    ; $conditional[0] will hold "$start > 0 and $start < 2" from your example string
    ; $conditional[1] will hold "run("calc")"
EndIf

note: I didn't debug this, so there might be some errors in there, but it should be enough to get you started.

Edited March 23, 2010 by Fulano

[IchBistTod]

It wont if you looked im attempting to capture the condition and action out of a conditional statement.

it will always be "if <something>then<something>"

conditions can contain any boolean operator, not, =, <, >, and, or.

[Fulano]

Sorry about that, I had some trouble reading your post. I'll edit my previous to correct that.

[jchd]

Try this:

Local $str = '  elseif  $start > 0 and $start < 2 then  run("calc")'
$conditional = StringRegExp($str, "(?i)\A\s*(?:else)?if\s+(.+)\s+then\s+(.+)\z", 1)
if Not @error Then
    _ArrayDisplay($conditional)
;~  for $x=1 to $conditional[0]     <<------- Wrong, no count here!
;~  MsgBox(64, "", $conditional[$x])
;~  Next
EndIf

This doesn't deal with possible comments, and isn't fail-proof:

$str = 'if $start > 0 then $string = "So then you believe it works?"'

Oops!

Making the subpattern less greedy won't help much:

$str = 'if $string = "OK. So then you really believe it works?" then call("firemen")'

re-Oops!

Doing the general case, with possible then embedded in strings, comments, can't be done wihthout a lexer, I suppose.

Edited March 24, 2010 by jchd

[Melba23]

IchBistTod,

Does it have to be a RegEx? I ask because this little function seems to do what you want.

It splits the action from the conditon(s) and determines any logical relationship between multiple conditions - all presented in a nice little array with a condition counter at [0][0]:

expandcollapse popup

#include <Array.au3>

$sText = 'if $start > 0 and $start < 2 then run("calc")'

$aArray = _If_Parse($sText)
_ArrayDisplay($aArray)

$sText = 'if $start > 0 then run("calc")'

$aArray = _If_Parse($sText)
_ArrayDisplay($aArray)

$sText = 'if Not($start > 0) and $start < 2 or $fred = 99 then run("calc")'

$aArray = _If_Parse($sText)
_ArrayDisplay($aArray)

Func _If_Parse($sText)

    ; Separate conditions and action
    $aSplit_1 = StringSplit(StringUpper($sText), "THEN", 1)

    ; Split any conditions and remove WS
    $aSplit_2 = StringSplit(StringRegExpReplace(StringStripWS(StringTrimLeft($aSplit_1[1], 2), 3), "AND|OR", "#####"), "#####", 1)
    For $i = 1 To $aSplit_2[0]
        $aSplit_2[$i] = StringStripWS($aSplit_2[$i], 3)
    Next

    ; Declare result array and enter number of conditions and action
    Local $aResult[$aSplit_2[0] + 1][2] = [[$aSplit_2[0], StringStripWS($aSplit_1[2], 3)]]

    ; Detect logical operators and add them and conditions to result array
    For $i = 1 To $aSplit_2[0]
        $aResult[$i][1] = $aSplit_2[$i]
        Switch StringLeft(StringStripWS(StringMid($aSplit_1[1], StringInStr($aSplit_1[1], $aSplit_2[$i]) + StringLen($aSplit_2[$i])), 3), 1)
            Case "A"
                $aResult[$i + 1][0] = "AND"
            Case "O"
                $aResult[$i + 1][0] = "OR"
        EndSwitch
    Next

    Return $aResult

EndFunc   ;==>_If_Parse

As you can see, it works on single, double and triple conditions (including those with NOTs). Perhaps you might find it useful.

M23