checkbox color

[gcue]

i am trying to change the color of a checkbox's text with guictrlsetcolor

however i am using the windows xp theme so "Checkbox, Radio or Progress controls cannot be painted if the "Windows XP style" is used." (from help file)

this is the workaround im trying to use:

Func CreatePCOffsiteCheckbox()

    $pc_offsite_checkbox = GUICtrlCreateCheckbox("", 11, 42, 10, 10)
    GUICtrlCreateLabel("PC is Offsite", 21, 42, 70, 10)
    GUICtrlSetOnEvent(-1, "Toggle_PCOffsite")
    GUICtrlSetColor(-1, $font_color)
    GUICtrlSetFont(-1, 6, 600)

EndFunc   ;==>CreatePCOffsiteCheckbox

Func Toggle_PCOffsite()

    If BitAND(GUICtrlRead($pc_offsite_checkbox), $GUI_CHECKED) Then
        GUICtrlSetState($pc_offsite_checkbox, $GUI_UNCHECKED)
    EndIf

    If BitAND(GUICtrlRead($pc_offsite_checkbox), $GUI_UNCHECKED) Then
        GUICtrlSetState($pc_offsite_checkbox, $GUI_CHECKED)
    EndIf

EndFunc   ;==>Toggle_PCOffsite

for some reason, when i click the label the checkbox tick selects when its the checkbox is unchecked it not untick

any ideas?

[Melba23]

gcue,

Just remove the theme from your checkbox like this - then you can change the text colour and it still works normally:

#include <GUIConstantsEx.au3>
#include <ButtonConstants.au3>

$hGUI = GUICreate("Test", 500, 500)

$hCheckbox = GUICtrlCreateCheckbox("Text with colour change", 10, 10, 150, 20)
DllCall("UxTheme.dll", "int", "SetWindowTheme", "hwnd", GUICtrlGetHandle($hCheckbox), "wstr", 0, "wstr", 0)
GUICtrlSetColor($hCheckbox, 0xFF0000)

GUISetState()

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch

WEnd

M23

[gcue]

yippe!!! thanks =)