Store GUI handle in Dictionary

[vsny]

I am trying to add a window handle into a scripting dictionary. I have all my controls stored but I cannot store the window handle. Is there a way to store the handle in some way.

$ctrls = ObjCreate('Scripting.Dictionary')

Func _createWnd()
        Local $wnd = GUICreate("My GUI edit")
    $ctrls.add("wnd", $wnd) ; also have tried Ptr($wnd)
EndFunc

A typical error I get with or without the Ptr() is:

C:\testControls.au3 (151) : ==> The requested action with this object has failed.:

$ctrls.add("wnd", ptr($wnd))

$ctrls.add("wnd", ptr($wnd))^ ERROR

I assume there is a way to do this since it works with controls and almost everything else. Can't I store the pointer to the window? or will I lose the window once it goes out of scope.

In case anyone asks - like any good programming style I'm trying to eliminate global variables and I have to pass all the public window controls between included modules.

[Yoriz]

Global $ctrls = ObjCreate('Scripting.Dictionary')

_createWnd()
MsgBox(0,"Handle",_GetWnd("wnd"))

Func _createWnd()
    Local $wnd = GUICreate("My GUI edit")
    _AddWnd("wnd",$wnd)

EndFunc

Func _AddWnd($sKey, $sItem)
    $ctrls.add($sKey, string($sItem))
EndFunc

Func _GetWnd($sKey)
    Return HWnd($ctrls.item($sKey))
EndFunc

[Melba23]

vsny,

Welcome to the AutoIt forum.

I get it to work if I convert the Hex window handle to either a decimal number or a string first:

$ctrls = ObjCreate('Scripting.Dictionary')

_createWnd()

Func _createWnd()

    Local $wnd = GUICreate("My GUI edit")
    ConsoleWrite($wnd & @CRLF)

    $ctrls.add("Wnd_1", Dec(StringTrimleft($wnd, 2)))
    ConsoleWrite("0x" & Hex($ctrls.item("Wnd_1"), 8) & @CRLF)

    $ctrls.add("Wnd_2", String($wnd))
    ConsoleWrite($ctrls.item("Wnd_2") & @CRLF)

EndFunc

Why, I have no idea - I just thought I would try it!

M23

[ProgAndy]

Same error we discovered when testing AutoItObject, it seems that no dev wants to fix it. #1410

[Melba23]

ProgAndy,

Do not lose hope - the bug is still open and we know that there is a bit of a pause in development at the moment. And even if it does not get fixed, we know the work-around.

M23

[vsny]

Wow, you guys are fast! I went to the backyard for a few minutes and the answer was waiting for me!

I tried Yoriz's String() solution and it seems to work. Thanks!

Are there any drawbacks or dangers to doing this? Is this an unsupported hack that will break in future versions?

Do the dev's have any feedback on this? Maybe there was a reason they didn't implement this?

[wraithdu]

It a better idea to just use Number($wnd) instead of any string conversions. A window handle is just a 32/64-bit number anyway, it's just that AutoIt internally designates it a 'handle' and AutoIt's implementation of objects does not allow it to work with 'handle'. This is also the solution that the AutoItObject examples use.